[[20100203082100]]　『個人用マクロブックにプログラムを入れたが反応し』（あきぷ）　ページの最後に飛ぶ

『個人用マクロブックにプログラムを入れたが反応しない？』（あきぷ）

WindowsXP環境でExcel2007を使用しております。

 シートの見出しの色が白で見づらいので、作業中のアクティブなシートのみ
 赤色になるようなマクロを下記のように作成してみました。

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

Dim ws As Worksheet
For Each ws In Worksheets
ws.Tab.ColorIndex = xlColorIndexNone
Next ws
With ActiveSheet
.Tab.ColorIndex = 3
End With

End Sub

上記を個々のVBAで個々のブックのThis Workbookに書き込んだ場合は

 機能したのですが、個人用マクロブックに書き込んで、開いた全ての
 ブックに対応させようとしたところ無反応でした。

アドバイスの程よろしくお願いします。

また上記をアドイン化する方法も教えていただければ幸いです。

 ろくに確認をとってないけど。
 細かい調整が必要かと思います。

 ・ThisWorkbook

 Dim APPEXL As Class1

 Private Sub Workbook_Open()
   Set APPEXL = New Class1
   Set APPEXL.App = Application
 End Sub

 Private Sub Workbook_BeforeClose(Cancel As Boolean)
   Set APPEXL = Nothing
 End Sub

 ・クラスモジュール

 Public WithEvents App As Application

 Private Sub App_SheetActivate(ByVal Sh As Object)
 Dim ws As Worksheet
   Sh.Tab.ColorIndex = 3
   For Each ws In ActiveWorkbook.Worksheets
      If Sh.Name <> ws.Name Then
         ws.Tab.ColorIndex = xlColorIndexNone
      End If
   Next ws
 End Sub

 アドインは、ブックを名前をつけて保存時に
 種類をアドインに選ぶのが簡単かな？
 で、保存場所は、ここが無難。
 C:\Program Files\Microsoft Office○○\Library

 尚、Win2000 or WinXP、Excel2003以前として・・・・。
 2007なんて持ってないし。
 BJ

 XL2007のヘルプで、
 『アドインを登録または削除する』をキーに検索しますと
 「Excel アドイン プログラムを登録または削除する」の項に
 登録手順が書かれています。

 (半平太) 2010/02/03 10:57

全てできました(*＾▽＾*)ﾉ

この機会にもっと勉強させていただきます。

 2007は会社の端末に入ってるんですよ。
 自宅のは2004(mac)ですよ。

BJさんありがとうございました。

（あきぷ）

アドインの情報もありがとうございます(*＾▽＾*)ﾉ

 →半平太さん

（あきぷ）

コメント返信：

[ 一覧(最新更新順) ]

[[20100203082100]] 『個人用マクロブックにプログラムを入れたが反応し』（あきぷ） ページの最後に飛ぶ

[[20100203082100]]　『個人用マクロブックにプログラムを入れたが反応し』（あきぷ）　ページの最後に飛ぶ