[[20100206103242]]　『管理簿の作成』（ハマー）　ページの最後に飛ぶ

『管理簿の作成』（ハマー）WindowsXP Excel2003を使用
データーベース（予定表）の作成について教えてください。（出来れば関数で作成したいです）

まず別に日付や工程、内容などを管理している別のファイルがあります。
ここから必要なデーターだけを今回まずsheet1（名前を投入シートに変更する）コピー＆ペーストで行います。

      A     B         C      D
1　 地域　管理番号　目標日　搬入日
2　　北　　A1000     2/1    2/3
3　　南    A1021     1/19   1/19
4　　西    B2103     2/15   2/10
5　　北    A1301     2/15   2/14
6　　南    A1541     2/1    2/2   
7　　西    B2130     2/13   2/10
8　　東    B1891     2/10   2/9
以下データが続く

sheet2（カレンダーに名前を変更する）にカレンダーを作成します。
今日を２／２とします

       C        　D       ←A,Bには他のデータが入っている
1　　日付　　  　一覧
2    昨日まで 北A1000,南A1021,南A1541
3　　2/2
4　　2/3
5    2/4
6    2/5
7    2/6
8    2/7
9    2/8
10    2/9　　　東B1891
11   2/10　　　西B2103,西B2130
12   2/11
13　これ以降　　北B13001

こんな形のものを作成したいです。要は日付を元にして、その日に該当する管理番号を表示させたいと思っています。
ポイントは、日付を絞り込む際に目標日と搬入日のうちで、先に来る方の日付を基準としたい部分と、日付が昨日までの用件や、一定期間以降のようけんは別にまとめたいと考えている部分です。また、日付に該当する用件を地域と管理番号をセットにして、並べて表示させたい点です。（ちなみに地域は１２地域があります）

これだけの事を関数でできるのか分かりませんが、マクロはよく分からないので教えてください。よろしくお願いします。

 投入シートに作業列を作成して
 投入					★	★	★
	[A]	[B]	[C]	[D]	[E]	[F]	[G]
[1]	地域	管理番号	目標日	搬入日	日付	区分	項目
[2]	北	A1000	2月1日	2月3日	2月1日	昨日まで	北A1000,南A1021,南A1541
[3]	南	A1021	1月19日	1月19日	1月19日	昨日まで	南A1021,南A1541
[4]	西	B2103	2月15日	2月10日	2月10日	2月10日	西B2103,西B2130
[5]	北	A1301	2月15日	2月14日	2月14日	これ以降	北A1301
[6]	南	A1541	2月1日	2月2日	2月1日	昨日まで	南A1541
[7]	西	B2130	2月13日	2月10日	2月10日	2月10日	西B2130
[8]	東	B1891	2月10日	2月9日	2月9日	2月9日	東B1891
[9]							
[10]							
 E2
=IF($A2="","",MIN(C2:D2))
 F2
=IF($A2="","",IF(E2<カレンダー!$C$3,"昨日まで",IF(E2>カレンダー!$C$12,"これ以降",E2)))
 G2
=IF(A2="","",A2&B2&IF(COUNTIF(F3:$F$1000,F2),","&VLOOKUP(F2,F3:$G$1000,2,FALSE),""))
 データ量が分かりませんので、数式は1000行までを想定しています。
 状況に合わせて適宜変更して下さい。

 カレンダー		
	[C]	[D]
[1]	日付	一覧
[2]	昨日まで	北A1000,南A1021,南A1541
[3]	2月2日	
[4]	2月3日	
[5]	2月4日	
[6]	2月5日	
[7]	2月6日	
[8]	2月7日	
[9]	2月8日	
[10]	2月9日	東B1891
[11]	2月10日	西B2103,西B2130
[12]	2月11日	
[13]	これ以降	北A1301
 D2セルに
=IF(COUNTIF(投入!$F$2:$F$1000,C2),VLOOKUP(C2,投入!$F$2:$G$1000,2,FALSE),"")
 13行目までフィルドラッグ。

 (HANA)

希望した通りにできました。そこで追加できれば、もう一つ条件が・・・
搬入日に未定が入力されている場合は、カレンダーの最後に未定の欄をもうけて表示をさせられればと考えています。
もし、これも追加可能なようでしたら、方法を教えてください。
（ハマー）

 F2セル用の式を
=IF($A2="","",IF(D2=カレンダー!$C$14,カレンダー!$C$14,IF(E2<カレンダー!$C$3,カレンダー!$C$2,IF(E2>カレンダー!$C$12,カレンダー!$C$13,E2))))
 に変更してみて下さい。

 ついでに「未定」「昨日まで」「これ以降」の文字を
 カレンダーシートから直接参照するように変更しました。

 (HANA)

HANAさんありがとうございました
無事に希望するものを作り上げることができました
(ハマー)

コメント返信：

[ 一覧(最新更新順) ]

[[20100206103242]] 『管理簿の作成』（ハマー） ページの最後に飛ぶ

[[20100206103242]]　『管理簿の作成』（ハマー）　ページの最後に飛ぶ