[[20100215095426]]　『COUNTIF 関数プラスOR関数』（Mi）　ページの最後に飛ぶ

『COUNTIF 関数プラスOR関数』（Mi）

    A              B 　  C　　     D       
 1 品名   　　   数量
 2 700CTYYDF5      50 SETS.
 3 2265           200 PCS. 
 4 7526DFSP4      100 SETS.

 C2=IF(B2="","",IF(COUNTIF(A2,"7*D")=1,"SETS.","PCS.")) 
以前に7で始まってＤを含んでいれば単位をSETS.表示でその他の場合はPCS.表示を教えてもらいました。
 判断条件に 7で始まって DF or DB or DT を含んでいればSETS.表示に変更したいの
 ですが、COUNTIF 関数の後にOR 関数を入れてみたところ#VALUE!のエラーがでました。
  C2=IF(B2="","",IF(COUNTIF(A2,OR("7*DF*","7*DB*"))=1,"SETS.","PCS."))

 論理値が含まれていない場合に出るエラーのようですが、何かいい方法あれば教えてく
 ださい、よろしくお願いします。

（Mi）

 IF(OR(COUNTIF(),COUNTIF()),"SETS.","PCS.")
と、IF関数のところで使いましょう。
(みやほりん)(-_∂)b

 =IF(B2="","",IF(SUM(COUNTIF(A2,{"7*DF*","7*DB*","7*DT*"})),"SETS.","PCS."))

 （sky）

みやほりんさま、skyさま

 ありがとういます。
 OR関数を入れるところが間違ってました（泣）
 SUM関数は数字を足す時に使う関数としか頭に頭になかったので
 勉強になりました。
 ありがとうございました。

(Mi)

 sky さま

 こんにちは、
 すみませんが、上記の式ついての質問です。
 問題が解決でしましたが、
 上記数式のなかでSUM関数の役割はOR関数と同じでしょうか？

 よろしくお願いします。

 (Mi)

 > 上記数式のなかでSUM関数の役割はOR関数と同じでしょうか？

 いえ、違いますよ。
 前のレスでおっしゃってるように数字（数値）を足してるだけです。

 COUNTIF(A2,{"7*DF*","7*DB*","7*DT*"})　で
 それぞれの条件の個数を配列にしています。

 700CTYYDT5　なら　{0,0,1}　というように。

 {0,0,1}　は左から　"7*DF*"、"7*DB*"、"7*DT*"　の個数です。

 こういうのがあるのかどうか知りませんけど
 700DFDB5　のように DF も DB も含んでいれば　{1,1,0}　です。

 それを SUM で合計しています。　=SUM({0,0,1})

 SUM の結果が　1以上なら（ 0 以外なら） IF 関数では　真（"SETS."）
 0　なら　偽（"PCS."）　になります。

 （sky）

sky さま

ありがとうございます。
勉強になりました。

（Mi）

コメント返信：

[ 一覧(最新更新順) ]

[[20100215095426]] 『COUNTIF 関数プラスOR関数』（Mi） ページの最後に飛ぶ

[[20100215095426]]　『COUNTIF 関数プラスOR関数』（Mi）　ページの最後に飛ぶ