[[20100216065312]]　『集計方法』（麻衣）　ページの最後に飛ぶ

『集計方法』（麻衣）

 下記のような表をつくりました。

 題）棚別NG発生状況

  棚番号　NG数
  1-2     5
  11-1     11
  18-2     8
  5-2     90
  .
  .

 棚番号のハイフンより前の数字（1～18が入ります）それぞれに対して、この表の中に何個あるのかを一覧として表示したいと思っております。
 また、その時、NG数が５以上のもののみカウントして、さらに５未満は背景が黄色、１０以上は赤にしたいです。

 ご指南よろしくお願いします。

WindowsXP、Excel2003です。

 こんな感じでしょうか。
	 [A]	 [B]	 [C]	 [D]	 [E]	 [F]	
 [ 1]	棚番号	NG数			棚番号	NG数	
 [ 2]	1-2	5			1	14	←=SUMPRODUCT(((LEFT($A$2:$A$20,FIND("-",$A$2:$A$20)-1)*1)=E2)*$B$2:$B$20)
 [ 3]	11-1	11			2	42	
 [ 4]	18-2	8			3	15	
 [ 5]	5-2	90			4	5	
 [ 6]	1-5	3			5	95	
 [ 7]	2-6	5			6	0	
 [ 8]	1-14	6			7	0	
 [ 9]	2-5	8			8	5
 [10]	2-6	8			9	5
 [11]	2-7	8			10	0
 [12]	2-8	8			11	11
 [13]	3-6	5			12	0
 [14]	4-14	5			13	0
 [15]	8-6	5			14	0
 [16]	5-5	5			15	0
 [17]	2-8	5			16	0
 [18]	3-4	5			17	0
 [19]	3-7	5			18	8
 [20]	9-5	5

 色を変える分は以下の条件付書式を参考にしてください。
http://www.excel.studio-kazu.jp/lib/e2qw/e2qw.html

 （川野鮎太郎）

 ↑　の表をお借りして

 F2　=SUMIF(A:A,E2&"-*",B:B)　　下にコピー

 （sky）

 > NG数が５以上のもののみカウントして

 何か勘違いしてるような気がしてきました･･･

 NG発生回数　というのはNG数の合計じゃないのかな？
 それぞれの棚番号で　NG数が5以上のもの　が何個あるかってことですか？

 F2　=SUMPRODUCT((LEFT($A$2:$A$100,LEN(E2)+1)=E2&"-")*($B$2:$B$100>=5))

 （sky）

 ↑　の趣旨の質問だとして、もっと簡単な方法

 C2　=IF(B2>=5,1,"")

 F2　=SUMIF(A:A,E2&"-*",C:C)

 どちらも下にコピー

 （sky）

 おっと、＞NG数が５以上のもののみカウントして、
 を見落としてましたね。

 （川野鮎太郎）

川野様、sky様ありがとうございます。

NG発生回数につきましては、sky様のおっしゃるとおり、「それぞれの棚番号で　NG数が5以上のもの　が何個あるか」ということです。

ちなみに、棚番号の列ですが、入力が多いため、－を手入力ではなく「ユーザー設定」で「0"-"0」として、実際には数字のみの入力をしています。

そのせいかもしれませんが、お二方の教えていただいたものを入力してもうまく表示されません。

 > －を手入力ではなく「ユーザー設定」で「0"-"0」として

 ということは枝番は　1桁限定　ということですか？
 枝番が 1桁なら

 F2　=SUMPRODUCT((INT($A$2:$A$100/10)=E2)*($B$2:$B$100>=5))
　
　
 または

 C2　=IF(B2>=5,INT(A2/10),"")

 F2　=COUNTIF(C:C,E2)

 （sky）

コメント返信：

[ 一覧(最新更新順) ]

[[20100216065312]] 『集計方法』（麻衣） ページの最後に飛ぶ

[[20100216065312]]　『集計方法』（麻衣）　ページの最後に飛ぶ