[[20100312112020]] 『決算の計算式』(さくら) >>BOT

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『決算の計算式』(さくら)
 こんにちは
 上半期・下半期の決算を関数で表示したいので、その計算式をつくってみたのですが、
 希望どおりに表示されないので、修正点を伺います。

 希望 コードが異なる内訳を、コードごとに上半期・下半期の合計をそれぞれ1つの式で求めれるようにしたい
 仮に、「10」というコードがあったら、「10」の上半期合計・「10」の下半期合計を求めたい

 現在の式(上半期)
 IF(COUNTIF(範囲1,A1)>0,AND((範囲1,A1,範囲B),SUMIF(範囲2,">=2010/04/01",範囲B)-SUMIF(範囲2,">2010/09/30",範囲B)),0)

   → TRUE と表示

 範囲1…コードが入った列
 範囲2…日付が入った列
 範囲B…金額が入った列
 A1…コード別集計表(同シート)にあるセル

 よろしくお願いします。


 >AND(範囲1,A1,範囲B)
 この部分が意味を為していません。(気持ちは分かりますが。。)

 (1)バージョンが2007よりも前のものですと、通常Sumproductが使われます。
    G1セル =SUMPRODUCT((B2:B6=A1)*("2010/3/31"*1<C2:C6)*(C2:C6<"2010/10/1"*1),D2:D6)

 (2)また、作業列を利用することもあります。
    E2セル =IF(AND("2010/3/31"*1<C2,C2<"2010/10/1"*1),"上"&B2,IF(AND("2010/9/30"*1<C2,C2<"2011/4/1"*1),"下"&B2,""))
    G2セル =SUMIF(E2:E6,"上"&A1,D2:D6)

 (3) バージョンが2007ならSumifsが使えます
   G3セル =SUMIFS(D2:D6,B2:B6,A1,C2:C6,">2010/3/31",C2:C6,"<2010/10/1")

  行  _A_  ___B___  _____C_____  ___D___  ___E___  _F_  __G__
   1   10  範囲1   範囲2       範囲B    作業列        1011 
   2           10   2010/4/5          1   上10          1011 
   3           10   2010/4/6         10   上10          1011 
   4           45   2010/4/7        100   上45               
   5           10   2010/4/8      1,000   上10               
   6           10   2010/10/15   10,000   下10               

 (半平太) 2010/03/12 14:10

 半平太さん、ありがとうございます。
 早速試してみます。

 (さくら)


コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.