[[20100619154058]]　『データの抽出』（ごん）　ページの最後に飛ぶ

『データの抽出』（ごん）

   (A列)　　(B列)  (C列)   (D列)   (E列)   (E列)   (E列)
　　名前     1日　　2日     3日     4日　　 5日　　 6日
1　　あ　   　A      B       C       A       B       C
2  　い     　B      C       A       B       C       A
3  　う     　C      A       B       C       A       B
4  　え     　B      B       C       A       C       A
5  　お     　A      C       B       C       B       B
6　　か       C      A       A       B       A       C

　上記の様な出勤表があります。A.B.Cの3パターンの勤務パターンがあり1日のAパターンは「あ」と「お」Ｂパターンは「い」と「え」Ｃパターンは「う」と「か」という様に各日にちごとの組み合わせを一覧で表示するにはどうすればよいでしょうか？
　色々試してみたんですが全くだめでした・・・・
　どなたか助けていただけませんでしょうか？

 6日で1セットですか。7日は1日と同じですか。
 (たるむ)

上記の表は例として出させていただいたもので実際は1日に14人勤務しており7パターンの体制です。6日で1セットではなくもっとバラバラなものになります・・・・なんとかなりますでしょうか？

 人を中心に見たときに何パターンありますか。
 何日で1セットですか。
 (たるむ)

 >上記の表は例として出させていただいたもので
 本当の情報を出して下さい。　　でないと
 >なんとかなりますでしょうか？  何ともなりません。　　(NB)

 質問のしかたが分かりづらくてすいません・・・・

 　(A列)　　(B列)  (C列)   (D列)   (E列)   (E列)   (E列)
　　名前     1日　　2日     3日     4日　　 5日　　 6日
1　　あ　   　A      B       C       A       B       C
2  　い     　B      C       A       B       C       A
3  　う     　C      A       B       C       A       B
4  　え     　B      B       C       A       C       A
5  　お     　A      C       B       C       B       B
6　　か       C      A       A       B       A       C

上記の表を別シートに下記の様に表示させたいのですが・・・

 　 　(A列)　　(B列)      (C列)       (D列)       (E列)       (E列)       (E列)
　　パターン    1日　　    2日         3日         4日　　     5日　　     6日
1　　　A　   　あ・お    う・か　　　い・か　　　あ・え　　　う・か　　　い・え   
2  　　B     　い・え　　あ・え　　　う・お　　　い・か　　　あ・お　　　う・お  
3  　　C     　う・か　　い・お　　　あ・え　　　う・お　　　い・え　　　あ・か

 眠くなってきたので、あんまり深く考えてないし
 検証不足です。
 もっと簡潔な式が考えられそうですので、たたき台程度に。。。
　
Sheet1	[A]	[B]	[C]	[D]	[E]	[F]	[G]
[1]	名前	1日	2日	3日	4日	5日	6日
[2]	あ	A	B	C	A	B	C
[3]	い	B	C	A	B	C	A
[4]	う	C	A	B	C	A	B
[5]	え	B	B	C	A	C	A
[6]	お	A	C	B	C	B	B
[7]	か	C	A	A	B	A	C
　
Sheet2	[A]	[B]	[C]	[D]	[E]	[F]	[G]
[1]　　パターン	1日	2日	3日	4日	5日	6日
[2]	A	あ・お	う・か	い・か	あ・え	う・か	い・え
[3]	B	い・え	あ・え	う・お	い・か	あ・お	う・お
[4]	C	う・か	い・お	あ・え	う・お	い・え	あ・か
　
 Sheet2
 B2 =INDEX(Sheet1!$A$2:$A$7,MATCH($A2,Sheet1!B$2:B$7,))&"・"&INDEX(Sheet1!$A$2:$A$7,INDEX(MAX((Sheet1!B$2:B$7=$A2)*ROW($A$1:$A$6)),))
　必要範囲までコピー
　
 （キリキ）（〃⌒o⌒)b

ありがとうございます！！

教えていただいた数式でうまくできました！！

もしお手間でなければ簡潔な式も教えていただけませんでしょうか？？

勝手言いまして申し訳ございません・・・

よろしくお願いいたします。

 作業列を使用することは可能でしょうか？
　
 作業列があるだけでもっと簡単な式になりますよ＾＾
　
 （キリキ）（〃⌒o⌒)b

すいませんわかりません・・・・

作業列とはなんでしょうか？

一度自分でも調べてみます。

 >作業列とはなんでしょうか？
 表のあいているところに、計算に使用する欄（枠）を使用してもいいかってことです＾＾
　
 （キリキ）（〃⌒o⌒)b

 一応、作業列を使用する方法で考えてみましたｂ
　
Sheet1	[A]	[B]	[C]	[D]	[E]	[F]	[G]	[H]	[I]	[J]	[K]	[L]	[M]
[1]	名前	1日	2日	3日	4日	5日	6日						
[2]	あ	A	B	C	A	B	C	A	B	C	A	B	C
[3]	い	B	C	A	B	C	A	B	C	A	B	C	A
[4]	う	C	A	B	C	A	B	C	A	B	C	A	B
[5]	え	B	B	C	A	C	A	BB	BB	CC	AA	CC	AA
[6]	お	A	C	B	C	B	B	AA	CC	BB	CC	BB	BB
[7]	か	C	A	A	B	A	C	CC	AA	AA	BB	AA	CC
　
 H列からM列が作業列です。
 H2 =REPT(B2,COUNTIF(B$2:B2,B2))
 M7までコピー
　
 Sheet2
 B2 =INDEX(Sheet1!$A$2:$A$7,MATCH($A2,Sheet1!H$2:H$7,))&"・"&INDEX(Sheet1!$A$2:$A$7,MATCH(REPT($A2,2),Sheet1!H$2:H$7,))
　必要範囲までコピー
　
 （キリキ）（〃⌒o⌒)b

 =INDEX(Sheet1!$A$2:$A$7,FIND($A2,PHONETIC(Sheet1!B$2:B$7)))&","&INDEX(Sheet1!$A$2:$A$7,FIND($A2,SUBSTITUTE(PHONETIC(Sheet1!B$2:B$7),$A2,"X",1)))
                            (NB)

コメント返信：

[ 一覧(最新更新順) ]

[[20100619154058]] 『データの抽出』（ごん） ページの最後に飛ぶ

[[20100619154058]]　『データの抽出』（ごん）　ページの最後に飛ぶ