[[20110209180425]]　『特定のチェック付きを抜かしたリストを関数で』（にしき）　ページの最後に飛ぶ

『特定のチェック付きを抜かしたリストを関数で』（にしき）

あるシートに次のようなリストがあります。

 　　A列  B列 
 1行　○　山田
 2行　○　佐藤
 3行　×　田中
 4行　○　久保
 5行　×　中山

別の場所やシート（たとえばE列）に、A列に○のチェックがついたリストを関数で自動的に表示したいのですが、どのようにすればよろしいでしょうか。（抽出などの機能を使わずに行いたい）

 　　E列 
 1行山田
 2行佐藤
 3行久保

Excelは2002以降です。

 B列の名前に重複がないことが条件ですが、VLOOKUP関数を使用した面白い案を提示してみますｂ
　
    |[A]|[B] |[C]|[D]|[E] 
 [1]|○ |山田|   |   |山田
 [2]|○ |佐藤|   |   |佐藤
 [3]|× |田中|   |   |久保
 [4]|○ |久保|   |   |    
 [5]|× |中山|   |   |    
　
 E1 =IF(COUNTIF(A1:A10,"○")<ROW(A1),"",VLOOKUP("○",A1:B10,2,))
 E2 =IF(COUNTIF($A$1:$A$10,"○")<ROW(A2),"",VLOOKUP("○",INDEX($A$1:$B$10,MATCH(E1,$B$1:$B$10,)+1,):$B$10,2,))
　以下コピー
　
 #ｍｏｍｏさん、さっそく使わせていただきました＾＾
　便利ですよ～♪
　
 （キリキ）（〃⌒o⌒)b

キリキさん、ありがとうございます！
早速試してみます。

教えて頂いた所で重ね重ねで恐縮なのですが、さらに追加してC列（実際には、もっとたくさんの列）の情報も抜き出し、F列に入れたいのですが、F列（実際にはさらにその後）にどのような関数を入れていけばよろしいでしょうか。
お時間がありましたらご教示頂けると幸いです。

    |[A]|[B] |[C]|[D]|[E] |[F] 
 [1]|○ |山田|A県|   |山田|A県
 [2]|○ |佐藤|B県|   |佐藤|B県
 [3]|× |田中|C県|   |久保|B県
 [4]|○ |久保|B県|   |    |
 [5]|× |中山|E県|   |    |

追伸：B列の重複の可能性もあるのですが、その場合はダミー列で適当な数値を付加し、重複しないようにしたいと思っています。

（にしき）

 こんにちは。
キリキさんのご回答を参考にさせていただき、作業列（D列）を使って作ってみました。

  ※「_」セルは未入力または""
  [R/C]  [A]   [B]  [C]  [D]   [E]  [F]
   [1]    ○  山田  A県    1  山田  A県
   [2]    ○  佐藤  B県    2  佐藤  B県
   [3]    ×  田中  C県    2  久保  B県
   [4]    ○  久保  B県    3     _    _
   [5]    ×  中山  E県    3     _    _

  D1 =IF(A1="○",1,0)
  D2 =D1+IF(A2="○",1,0) →D2:D5フィルコピー
  E1 =IF(ROW(E1)>COUNTIF($A$1:$A$10,"○"),"",VLOOKUP(ROW(E1),CHOOSE({1,2},$D$1:$D$10,B$1:B$10),2,))
　 →E1:F5フィルコピー
　
（コタ）
D2:D5の数式を修正しました。（16:50）

 遅くなりましたｂ
　
 元の数式を少しいじりました。

 E1 =IF(COUNTIF($A$1:$A$10,"○")<ROW(A1),"",VLOOKUP("○",$A$1:$C$10,COLUMN(B1),))
　F1までコピー
 E2 =IF(COUNTIF($A$1:$A$10,"○")<ROW(A2),"",VLOOKUP("○",INDEX($A$1:$C$10,MATCH($E1,$B$1:$B$10,)+1,):$C$10,COLUMN(B1),))
　F列の必要範囲まで下にコピー
　
 （キリキ）(〃⌒o⌒)b

 >キリキさん
 >#ｍｏｍｏさん、さっそく使わせていただきました＾＾
 >　便利ですよ～♪

 #ありがとうございます。リンクフリーでどうぞ～^^
 （ｍｏｍｏ）

みなさまありがとうございます！
大変勉強になりました。
（にしき）

コメント返信：

[ 一覧(最新更新順) ]

[[20110209180425]] 『特定のチェック付きを抜かしたリストを関数で』（にしき） ページの最後に飛ぶ

[[20110209180425]]　『特定のチェック付きを抜かしたリストを関数で』（にしき）　ページの最後に飛ぶ