[[20110216114755]]　『条件付書式でセルに色をつける（数が大きい順、数』（さくさく）　ページの最後に飛ぶ

『条件付書式でセルに色をつける（数が大きい順、数が重複しています）』（さくさく）

 こんにちは、
 とっても困っています。

 数字のデータが横に並んでいて（このデータの量は増えたり減ったりします）、
 条件付書式で、数字が大きい順に、
 1位=赤、2位=緑、3位=黄色で、数字が入っているセルに色付けをしたいです。
 たとえば、
 　A　　B　　C　　D　　E　　F　　G　　H　　I　　J　　K　　
1　116　116　118　120　119　118　120　118　118　116　116

 と並んでいるとして、120（D1、G1のセル）を赤、119（E1のセル）を緑、118（C1、F1、H1、I1のセル）を黄色と、
 1位、2位、3位に複数の数があっても色をつけたいのです。
 おひるやすみにすみません。
 よろしくおねがいします。。

Excel2003

 A1:K1を選択して、条件付書式数式がで、
 =LARGE($A1:$K1,1)=A1　パターン赤
 =LARGE($A1:$K1,2)=A1　緑
 =LARGE($A1:$K1,3)=A1　黄

 範囲が変わるなら、K列をもっと左にでもしておいた方が簡単そう。
 BJ

 BJさま、おへんじありがとうございます。

 そのやり方だと、2位以下の色が思ったとおりに変わらないのです
 （なぜなら1位が2つあって、119は3番目になるから？）。

 たとえば違うセルで、
 =LARGE($A1:$K1,1)とすると、120
 =LARGE($A1:$K1,2)とすると、120
 =LARGE($A1:$K1,3)とすると、119
 という値がでてきます。

 すみません。。

（さくさく）

 重複のことをあまり考えてなかった。
 ２位は、
 =LARGE($A1:$K1,COUNTIF($A1:$K1,MAX($A1:$K1))+1)=A1
 ３位以下はまだ考えてません。

 ↑
 ダメですね。
 作業セルを使った方がいいかも。
 BJ

 BJさま、かさねがさねありがとうございます。

 どんな作業セルがふえるのはだいじょうぶです！
 ちんぷんかんぷんです、、
 どうすればよいですか。。

 (さくさく)

 2行目のセル（A2からK2）を作業用セルとして
 A2セルに
  =RANK(A1,$A$1:$K$1,0)
 を入力、K2セルまで横にコピー
 A1セルの条件付き設定で、数式を使用して、書式設定をする方法で
 第1ルールで　数式を　=A$2=SMALL($A$2:$K$2,1) にして、書式を"赤"に設定
 第2ルールで　数式を　=A$2=SMALL($A$2:$K$2,1+COUNTIF($A$2:$K$2,1))にして、書式を"緑"に設定
 第3ルールで　数式を　=A$2=SMALL($A$2:$K$2,1+(1+COUNTIF($A$2:$K$2,1)))にして、書式を"黄"に設定
 A1セルを選択しコピー、B1セルからK1セルまでに書式設定貼り付けをする。

 これで、希望どおりの結果が得られませんか？
 (あらくま)

 こんなのが使えるかもしれません。
 =A1=LARGE(INDEX((MATCH($A1:$K1,$A1:$K1,0)=COLUMN($A1:$K1))*$A1:$K1,),1)
 ↑1位の物です。

 (HANA)

 ベタな方法で。

 作業列を
 　　　Ｏ　　　Ｐ　　　Ｑ　　　Ｒ
 １　１番目　２番目　３番目　４番目
 として、

 Ｏ１
 =MAX(A1:K1)

 Ｏ２
 =COUNTIF($A$1:$K$1,O2)

 Ｐ２
 =LARGE($A$1:$K$1,SUM($O3:O3)+1)
 これを、Ｒ２までフィル。

 Ｐ３
 =COUNTIF($A$1:$K$1,P2)
 これを、Ｒ３までフィル。

 条件付書式で、
 セルの値が、次の値に等しいで、
 １番目 =$O$2
 ２番目 =$P$2
 ３番目 =$Q$2
 BJ

 HANAさん、作業行を使わないでできるのですね。
 質問者ではないのですが、勉強になりました。
 (あらくま)

 あらくまさま、HANAさま、そして、BJさま。

 ほんとうにご親切にありがとうございます。
 わたくしが初心者なもので、みなさまのお答えをながめてみても、
 どういうなかみなのかがすぐにピンとこないので、、
 理解ができるまでとても時間がかかります。
 いまはあらくまさまのを試しています。
 すべて試してみます。

 ご報告します。
 （さくさく）

 BJさん！ありがとうございます！できました！

 (さっくさく)

 あらくまさまのをためしてみたら、セルがまっかっかになりました。。
 もうちょっとがんばります。

 HANAさま
 =A1=LARGE(INDEX((MATCH($A1:$K1,$A1:$K1,0)=COLUMN($A1:$K1))*$A1:$K1,),1)
 式の末尾を2、3、と変えるのでしょうか？

 (さくさく)

 はい、現在の式は間を省略して書くと
 =A1=LARGE(・・・・,1)
 と成っているので  ~~~ ここを 2,3 と変更して下さい。

 基本的には↓と一緒です。
 =LARGE($A1:$K1,1)=A1
 ここで ~~~~~~~ ごちゃごちゃやってますが。

 (HANA)

 おかしいですね。
 小生のところでは、あなたの希望する結果になるのですが？

 2行目のセル（A2からK2）を作業用セルとして
  A2セルに
   =RANK(A1,$A$1:$K$1,0)
 を入力、K2セルまで横にコピー

  「条件付書式の設定」の条件1(1)の左の設定を「数式が」にし、
 右の欄に式「=A$2=SMALL($A$2:$K$2,1) 」を入力、書式を"赤"に設定する。
   次に「追加(A)>>」ボタンを押し、条件2(2)の左の設定を「数式が」にし、
 右の欄に式「=A$2=SMALL($A$2:$K$2,1+COUNTIF($A$2:$K$2,1)) 」を入力、
 書式を"緑"に設定する。
   さらに、「追加(A)>>」ボタンを押し、条件3(3)の左の設定を「数式が」にし、
 右の欄に式「=A$2=SMALL($A$2:$K$2,1+(1+COUNTIF($A$2:$K$2,1))) 」を入力、
 書式を"黄"に設定する。
   最後に、「OK」ボタンを押し条件付書式設定作業を終了する。
   A1セルを選択しコピー、B1セルからK1セルまでを選択、「形式を選択して貼り付ける」
 で貼り付ける。
   今一度、このようにして試してください。
 (あらくま)

コメント返信：

[ 一覧(最新更新順) ]

[[20110216114755]] 『条件付書式でセルに色をつける（数が大きい順、数』（さくさく） ページの最後に飛ぶ

[[20110216114755]]　『条件付書式でセルに色をつける（数が大きい順、数』（さくさく）　ページの最後に飛ぶ