[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『勤務時間の集計』（ゆう）
勤務時間の集計について教えてください（初心者です）。 過去ログの２０１１年２月２日の「勤務時間の集計（関数）について」（ゆみ）さんを参考にさせていただきだいだいは解決したのですが、深夜残業のとりかたが少し違うので分かりません。
・出社、退社、を入力するとＨ～Ｌに集計できるようにしたい。
・普通勤務は5：00～22：00。
・深夜時間は22：00～29：00。
・出社、退社時間はバラバラ。
・勤務時間が８時間を超えると残業あつかい。
※始業が深夜時間帯で８時間以上勤務の時は、早出残業のように考え、深夜時間の方が残業になる。（←※のところがわかりません。）
Ｆ Ｇ Ｈ Ｉ Ｊ Ｋ Ｌ
開始時間 終了時間 総勤務時間 普通勤務 普通残業 深夜勤務 深夜残業
(例１) 8：00 18：00 10：00 8：00 2：00 (例２) 12：00 23：00 11：00 8：00 2：00 1：00 (例３) 23：00 38：00 15：00 8：00 1：00 6：00 (例４) 0：00 12：00 12：00 7：00 1：00 4：00 (例５) 3：00 13：00 10：00 8：00 2：00
(例３)～(例５)ができないです。 よろしくお願いします。 （エクセルは２００３です）
(1) H3セル =G3-F3
(2) I3セル =MAX(0,MAX(0,MIN("22:00",$G3)-MAX("5:00",$F3))+MAX(0,MIN("46:00",$G3)-"29:00")-J3)
(3) J3セル =MAX(0,MAX(0,H3-"8:00")-L3)
(4) K3セル =MAX(0,H3-I3-J3-L3)
(5) L3セル =MIN(MAX(0,H3-"8:00"),MAX(0,MIN("5:00",$G3)-$F3)+MAX(0,MIN("29:00",$G3)-MAX("22:00",$F3))+MAX(0,$G3-"46:00"))
行 ____F____ ____G____ _____H_____ ____I____ ____J____ ____K____ ____L____ 1 開始時間 終了時間 総勤務時間 普通勤務 普通残業 深夜勤務 深夜残業 2 3 8:00 18:00 10:00 8:00 2:00 4 12:00 23:00 11:00 8:00 2:00 1:00 5 23:00 38:00 15:00 8:00 1:00 6:00 6 0:00 12:00 12:00 7:00 1:00 4:00 7 3:00 13:00 10:00 8:00 2:00 8 23:30 47:00 23:30 8:00 9:00 6:30
ゼロ時間のセルを空白に見せるのは、セルの書式(表示形式)でユーザー定義を以下に設定して対応してください。
↓
[>0.0003][h]:mm;[>=0]"";-0;@
(半平太) 2011/03/22 09:37
早速の御教示ありがとうございました！ 感謝、感謝ですm(_ _)m (ゆう)
申し訳ありませんが、再度質問です。
①自分で作成してみたのですが、開始時間と終了時間を入力していないと「普通勤務」に34：00が 表示されたままになってしまいました。時間を入力すると計算結果は合います。 ②１か月間の集計をするので、２行目以降にコピーするとエラーが出てしまいました。 ③本当は休憩時間をとります。自分で休憩時間を含んだ式を作るつもりだったのですが、挫折しました。 「勤務時間の集計（関数）について」（ゆみ）さんと同じく、「普通休憩」は「普通勤務」から、「深夜休憩」は「深夜勤務」から引きます。どのように式を作ったらいいのでしょうか？
教えていただけないでしょうか？よろしくお願いします。
（ゆう）
> ①自分で作成してみたのですが、開始時間と終了時間を入力していないと >「普通勤務」に34：00が 表示されたままになってしまいました。 どうして"34:00"になるのかは分かりませんが、 兎に角、終了時刻を入れるまでは0にする、と云うことでしたら こんな対応もあります。 ↓ =IF(G3,今までの数式,0)
> ②１か月間の集計をするので、２行目以降にコピーするとエラーが出てしまいました。 この部分は、全く分かりません。
> ③本当は休憩時間をとります。 あれれ、そうでしたか。 「就業規則がすごく簡単な会社だなぁ」とは思っていましたけども。。
>「勤務時間の集計（関数）について」（ゆみ）さんと同じく、 >「普通休憩」は「普通勤務」から、「深夜休憩」は「深夜勤務」から引きます。 あれれ、そこまで一緒ですか？ いっその事、そっちのデータを前提にした方が早くないですか？
※※ 翌日にまたがる勤務は、46:00(翌日の22:00) までとします。※※
(1) H7セル =IF(E7,IF(OR(D7="",E7=""),0,E7-D7-F7-G7),0) (2) I7セル =IF(E7,MAX(0,MIN(H7,J$5))-K7,0) (3) J7セル =IF(E7,MAX(0,H7-I7-K7-L7),0) (4) K7セル =IF(E7,MAX(0,MIN($I$5,MIN(E7,D7+J$5+F7+G7))-$D7)+MAX(0,MIN($K$6,MIN(E7,D7+J$5+F7+G7))-MAX($K$5,$D7)-G7),0) (5) L7セル =IF(E7,MAX(0,MAX(0,MIN($I$5,E7)-$D7)+MAX(0,MIN($K$6,E7)-MAX($K$5,$D7)-G7)-K7),0)
行 ____D____ ____E____ ____F____ ____G____ _____H_____ ____I____ ____J____ ____K____ ____L____ 4 開始時間 終了時間 休憩時間 深夜休憩 総勤務時間 普通勤務 普通残業 深夜勤務 深夜残業 5 5:00 7:30 22:00 6 22:00 29:00 7 9:15 19:35 1:00 9:20 7:30 1:50 8 1:00 15:05 14:05 3:30 6:35 4:00 9 18:30 23:20 4:50 3:30 1:20
(半平太) 2011/03/27 21:06
早速の御教示本当にありがとうございます。 そして、私の説明不足申し訳ありませんでした。同じことをするにもいろいろな式の作り方があるんですね。。。 まだまだ勉強不足で、式が暗号のように見えますががんばります！
もう少しおききしたいことがあるのですが(少し違うタイプの集計表)、 とにかくこの集計表を完成させてから質問しようと思います。 申し訳なく、そして図々しいですがどうかその時もよろしくお願い致しますm(_ _)m （ゆう）
ありゃ、機械的にやり過ぎました。(^^ゞ
> (1) H7セル =IF(E7,IF(OR(D7="",E7=""),0,E7-D7-F7-G7),0)
(1) H7セル =IF(OR(D7="",E7=""),0,E7-D7-F7-G7)
>式が暗号のように見えますががんばります！
頑張んない方がいいです。 私も１週間経ったら、どう云う意味だったか分かんなくなります。
今回もしょうがないので、１から考えた結果、前回と全然別になっただけです。
いずれにしても、項目相互に補完関係がありますので、 何を先に算出するかで、それ以外の項目の算式も変わってきます。
(半平太) 2011/03/28 00:00
度々申し訳ありません(><)私が時間を空けて質問してしまうのでよくないのですが、 深夜残業の計算方法が「ゆみ」さんとは少し違うので、3/27に御教示いただいた式 では答えが違ってきてしまいます(;_;)
（例）1：00～15：05
普通勤務 8：00
普通残業 2：05
深夜残業 4：00
と答えが出るようにしたいです。（８時間をこえると残業です）
※深夜時間帯が始業で、普通時間帯を経過して深夜時間帯で終業するようなことは ないです。(長くても１６時間勤務。)
（例）23：00～46：00 ということはないです。
本当に度々申し訳ないのですが、御教示いただけますでしょうか？ ご面倒だと思いますが、どうかよろしくお願いいたしますm(_ _)m （ゆう）
「普通休憩」と「深夜休憩」の記入があるサンプル図（希望する結果も記載されているもの）をご提示ください。
(半平太) 2011/03/28 23:16
Ｃ Ｄ Ｅ Ｆ Ｇ Ｈ Ｉ Ｊ Ｋ Ｌ
開始時間 終了時間 昼休憩 普通休憩 深夜休憩 総勤務時間 普通勤務 普通残業 深夜勤務 深夜残業
8：00 18：00 1：00 9：00 8：00 1：00 12：00 23：00 1：00 0:30 9:30 8：00 0：30 1：00 23：00 38：00 0:30 0:30 14：00 8：00 0：30 5：30 0：00 12：00 0:30 11：30 6：30 1：30 3：30 3：00 13：00 0:30 9：30 7：30 0:30 1：30
昼休憩と普通休憩は普通勤務から引きます。 深夜休憩は深夜勤務から引きます。 ８時間をこえたら残業になります。
どうしても完成させたいので、よろしくお願いいたしますm(_ _)m (ゆう)
１．計算内容を分かり易くするために、普通勤務全体と深夜勤務全体を出す事にしました。 目障りであれば、後でその列(NとO)を非表示にしてください。
もしくは、ご自分で数式を統合して、不要化してみてください。
(後で何が何だか分からなくなってもいいなら、私が不要化しますけども)
２．ついでに計算式を立てた順序も「各タイトルの頭」に番号を振って置きます。
数式
↓
(1) H3セル =IF(D3,D3-C3-E3-F3-G3,0)
(2) I3セル =IF(D3,MIN(N3,"8:00"),0)
(3) J3セル =IF(D3,MAX(0,N3-I3),0)
(4) K3セル =IF(D3,MAX(0,MIN("8:00"-I3,O3)),0)
(5) L3セル =IF(D3,MAX(0,O3-K3),0)
(6) N3セル =IF(D3,MAX(0,MIN("22:00",D3)-MAX("5:00",C3))+MAX(0,D3-"29:00")-E3-F3,0)
(7) O3セル =IF(D3,MAX(0,H3-N3),0)
<結果図> 行 ____C____ ____D____ ___E___ ____F____ ____G____ _____H_____ ____I____ ____J____ ____K____ ____L____ _M_ ____N____ ____O____ 1 開始時間 終了時間 昼休憩 普通休憩 深夜休憩 1総勤務時間 3普通勤務 4普通残業 6深夜勤務 7深夜残業 2普通全体 5深夜全体 2 3 8:00 18:00 1:00 9:00 8:00 1:00 0:00 0:00 9:00 0:00 4 12:00 23:00 1:00 0:30 9:30 8:00 0:30 0:00 1:00 8:30 1:00 5 23:00 38:00 0:30 0:30 14:00 8:00 0:30 0:00 5:30 8:30 5:30 6 0:00 12:00 0:30 11:30 6:30 0:00 1:30 3:30 6:30 5:00 7 3:00 13:00 0:30 9:30 7:30 0:00 0:30 1:30 7:30 2:00 8 1:00 15:05 14:05 8:00 2:05 0:00 4:00 10:05 4:00
(半平太) 2011/03/29 00:38
できました！！！ありがとうございましたm(_ _)m うれしくて飛び上がってしまいそうでした(^^)/ 半平太様、丁寧に教えてくださり本当にありがとうございました。 また、近いうちお世話になるかもしれませんが、よろしくお願いいたします。 (ゆう)
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.