[[20110328094708]]　『SUMPRODUCTとSUBTOTALの組み合わせ方』（ペイ）　ページの最後に飛ぶ

『SUMPRODUCTとSUBTOTALの組み合わせ方』（ペイ）

Excelの勉強を始めたばかりで、困っています。

　　B列　　　　　　　　　　D列

 　　営業課店所　　　　　　お客様
 8行　東京2部1課　　　　　　　あ
 9　　東京2部2課　　　　　　　い
 10　東京3部1課　　　　　　　う
 11　東京3部2課　　　　　　　え
 12　東京3部2課　　　　　　　え
 13　東京4部1課　　　　　　　お
 14　東京4部2課　　　　　　　お

このような場合で、B列にオートフィルタをかけ、D列に表示されたお客様数の合計を表示させたいと考えています。

 ex）東京3部2課でフィルタをかけた場合に、1と表示させたい。
 ※同じお客様がいくつ出てきても、1とカウントして合計させたい。

ちなみに、SUMPRODUCT(1/COUNTIF(D8:D14,D8:D14))でD列全体の合計は求められるのはわかったのですが、B列でフィルタをかけてもフィルタをかける前の全体の数値が表示されます。

うまく表示をさせる為にはどのような方法があるのでしょうか？
アドバイス宜しくお願い致します。

 ヘルプで　SUBTOTAL　を調べてみてください。
 BJ

 ----

 >BJさん
 ありがとうございました。
 SUBTOTALとSUMPRODUCTの組み合わせ方がどうしてもわかりません。
 教えて頂けますでしょうか。
 宜しくお願いします。

 E8=SUBTOTAL(103,D8) 　　E14までフィルダウン
 =SUMPRODUCT(1/COUNTIF(D8:D14,D8:D14)*(E8:E14))
 (Gray)

 E列を作業列に使うならE8セルに
 =--ISERROR(INDEX(MATCH(B8&D8,B$7:B7&D$7:D7,0),))
 これを下までコピーして、どこか適当なセルに
 =SUBTOTAL(9,E8:E14)
 とすれば良いと思います。

 (Jera)

 ----

 >Grayさん、Jeraさん
 ありがとうございます。
 試してみます。

 こんな感じでどうでしょうか。
 =SUMPRODUCT((SUBTOTAL(3,INDIRECT("B"&ROW(8:14))))*(MATCH(B8:B14&"_"&D8:D14,B8:B14&"_"&D8:D14,0)=ROW(1:7)))
 (ROUGE)

 ----

 >ROUGEさん
 ありがとうございました。
 作業列なしで、やりたいことができました。
 助かりました！

コメント返信：

[ 一覧(最新更新順) ]

[[20110328094708]] 『SUMPRODUCTとSUBTOTALの組み合わせ方』（ペイ） ページの最後に飛ぶ

[[20110328094708]]　『SUMPRODUCTとSUBTOTALの組み合わせ方』（ペイ）　ページの最後に飛ぶ