[[20110708173935]]　『今回のデータから前のデータを引く数式を教えてく』（初心者）　ページの最後に飛ぶ

『今回のデータから前のデータを引く数式を教えてください』（初心者）

 Ａ列に数値データと空白が不規則に入っています。
 Ａ列に二つ目以降のデータが有る場合に、その横のＢ列に、
 Ａ列の今回のデータからＡ列の前回のデータを引き、1を加える数式を教えてください。

  　　　　Ａ列　　　Ｂ列
　1        5
  2      
  3
  4
  5       15         11
  6
  7       18          4
  8
  9
 10
 11
 12       30         13

 宜しく御願いします。    （初心者）

 B2セルへ
 =IF(A2="","",A2-INDEX(A$1:A1,INDEX(MAX((A$1:A1<>"")*ROW($1:1)),),)+1)
 とし、下へコピーしてみて下さい。

 (Jera)

 こんな事でもいいかな

 =IF(A2="","",A2-LOOKUP(10^10,A$1:A1)+1)

 例題のように、A列が必ず増加している場合
 =IF(A2="","",A2-MAX(A$1:A1)+1)

 A1にはデータがあるとして
 B2:=IF(COUNT(A2),A2-$A$1-SUM($B$1:B1)+COUNT($A$1:A1),"")　　(NB)

 (Jera) さん、　(NB)　さん

 出来ました。有難うございました。
 皆試してみました。
 色々なやりかたがあるのですね。
 今後の為に大いに勉強させていただきました。
 感謝、感謝

 （初心者）

 (Jera) さん、　(NB)　さん

 すみません。
 仮のデータでは出来ましたといいましたが、
 実際のデータはＪ２１から下にデータが入っています。
 数式をＫ２２以降に入れたいのです。

 A1をJ1,B2をK2等に変更していろいろやってみましたが上手くいきません。
 どのように変更すれば宜しいでしょうか。

 いろいろ変更してみまして(NB)さん　の数式ではなんとか出来ました。
 有難うございました。

 （初心者）

 (Jera) さん、　(NB)　さん

 再々　すみません。
 質問が少し間違っていました。

 実際のデータはＫ２１から下にデータが入っています。
 数式をＪ２２以降に入れたいのです。
 （初心者）

 =IF(K21="","",K22-INDEX(K$21:K21,INDEX(MAX((K$21:K21<>"")*ROW($1:1)),),)+1)
 =IF(K21="","",K22-INDEX(K:K,INDEX(MAX((K$21:K21<>"")*ROW($21:21)),),)+1)

 =IF(K22="","",K22-LOOKUP(10^10,K$21:K21)+1)

 =IF(K22="","",K22-MAX(K$21:K21)+1)

 =IF(COUNT(K22),K22-$K$21-SUM($J$21:J21)+COUNT($K$21:K21),"")

 (Jera) さん、　(NB)　さん
 早速ご教示下され有難うございます。
 １行目と２行目の数式は何故か正しく表示されないのですが、
 ３,４,５行目の数式はどれも希望通りの答えが出ます。
 これらを使用させていただきます。
 ご手数おかけしました。
 今後とも宜しく御願いします。

 （初心者）

 解決したようですので、もう見ないかもしれませんが

 >１行目と２行目の数式は何故か正しく表示されないのですが

 最初の部分の　K21　→　K22　の間違いでは?

 =IF(K22="","",K22-INDEX(K$21:K21,INDEX(MAX((K$21:K21<>"")*ROW($1:1)),),)+1)
 =IF(K22="","",K22-INDEX(K:K,INDEX(MAX((K$21:K21<>"")*ROW($21:21)),),)+1)

 このくらいの間違いは　自分で訂正できるようになりましょう

  (Jera) さん、　(NB)　さん

 すみません。
 １行目と２行目の数式 正しく出来ました。
 数式が難しく、つい甘えてしまい注意力が足りませんでした。
 以後気をつけます。
 （初心者）

 To,初心者さんへ

 JeraさんとNBさんの書き込みは
 （おそらく）名前が書いてあるものだけです。

 以下、何人おられるのか分かりませんが、名前を書かない方へ。

 ご存じかとは思いますが、最後にニックネームを書くのが
 この掲示板のルールに成っています。
 色々な問題も発生しますので、書き込みをする場合は
 ニックネームを記入して下さい。

 (HANA)

コメント返信：

[ 一覧(最新更新順) ]

[[20110708173935]] 『今回のデータから前のデータを引く数式を教えてく』（初心者） ページの最後に飛ぶ

[[20110708173935]]　『今回のデータから前のデータを引く数式を教えてく』（初心者）　ページの最後に飛ぶ