[[20110730005043]]　『合計表示と非表示の方法』（ぺり）　ページの最後に飛ぶ

『合計表示と非表示の方法』（ぺり）　　[エクセルのバージョン]Excel2007

新規で作表したいのですが初心者なので教えて下さい。

 質問①　右の方は、入り数とその個数が数種類あり入り数ごとの個数合計を表示したいときどのようにすればいいのでしょう？
 質問②　下記の表は予め左に総数を入力して除数の関数で計算できるようにしているのですが総数を入れない時は空白にしたいのですがどうすればできますか？

 総数　　　　　入り数　　　個数　　　入り数　　　個数
 155　　　　　　20　　ｘ　7　　　　　　　　15　　ｘ　　1
 130　　　　　　20　　ｘ　6　　　　　　　　10　　ｘ　　1
 170　　　　　　20　　ｘ　8　　　　　　　　10　　ｘ　　1
 　  
    合計　　　　20　ｘ　21　　　　　　　　10　　ｘ　　2
　　　　　　　　　　　　　　　　　　　    15　　ｘ　　1

 合計の所の入り数が、事前に入力されているのか
 それともこの部分も数式で求めるのか
 に依って、難易度は変わってきそうに思います。

 事前に入力が有って、個数を求めるだけで良い場合
 質問(1)に関しては　SUMIF関数で出来ると思います。

 質問(2)の方は。。。。どこを空白にしたいのでしょう？
 個数の所の話なら、
 　=IF(総数のセル="","",個数計算の式)
 に変更でどうでしょう。

 この式を入れた場合、値が表示されない部分は
 見えませんが文字が返されているので
 四則演算時は注意して下さい。

 (HANA)

 右と左の表は別々の表かと思いましたが
 一つの表なんですね。。。

 例えば、最大入数が20で、それ以降は5刻みと言う事なら
 こんな感じで　計算出来るかもしれません。
 	[A]	[B]	[C]	[D]	[E]	[F]	[G]	[H]	[I]
[1]	総数		入数		個数		入数		個数
[2]	155		20	×	7		15	×	1
[3]	130		20	×	6		10	×	1
[4]	170		20	×	8		10	×	1
[5]									
[6]		合計	20	×	21		10	×	2
[7]							15	×	1
[8]									
[9]									
[10]

 C2=IF(A2>=16,20,"")
 D2=IF(C2="","","×")
 E2=IF(C2="","",IF(A2<=20,1,INT(A2/C2)))

 G2=IF(OR(A2="",PRODUCT(C2,E2)>=A2),"",CEILING(A2-PRODUCT(C2,E2),5))
 H2=IF(G2="","","×")
 I2=IF(G2="","",1)

 C6=IF(COUNT(C2:C5),20,"")
 D6=IF(C6="","","×")
 E6=IF(C6="","",SUM(E2:E5))

 G6=MIN(G2:G5)
 G7=IF(G6="","",IF(G6=MAX($G$2:$G$5),"",SMALL($G$2:$G$5,COUNTIF($G$2:$G$5,"<="&G6)+1)))
 H6=IF(G6="","","×")
 I6=IF(G6="","",SUMIF($G$2:$G$5,G6,$I$2:$I$5))

 (HANA)

(HANA)さん、丁寧なご回答ありがとうございます。質問の説明不足ですみません。

 おっしゃる通り上表は一つの表です。
 表左の[C][D]は初めから固定で[A]により[E]だけもとめます。
 表右[H][I]は初めから固定で[A]により[G]だけもとめます。
 関数はIFではなくQUOTIENTとMODで作っています。表左は最大入数が20で固定されているので
 合計は20ｘ○の１種類で出せますが、表右は表左の単なる余り数なので5刻みとかの法則では
 ありません。[A]によっては数種類の○[G]ｘ合計数で表さなければいけなくてその方法が
 わかりません・・

 また質問②のどこを空欄にしたいか？ですが[A]を入力しないとき表左右とも数式が入って
 いるので「0」で表示がでますよね。そうなると表が見にくくなるので[A]を入力しないときは
 各[C][D][E]と[G][H][I]全て何も表示しないようにできないでしょうか？
 よろしくお願いします。

 C列は20で固定で　G列が余りと言う事なら

 C2=IF(A2>=20,20,"")
 D2=IF(C2="","","×")
 E2=IF(C2="","",INT(A2/C2))

 G2=IF(A2="","",IF(MOD(A2,20)=0,"",MOD(A2,20)))
 H2=IF(G2="","","×")
 I2=IF(G2="","",1)

 C6=IF(COUNT(C2:C5),20,"")
 D6=IF(C6="","","×")
 E6=IF(C6="","",SUM(E2:E5))

 G6=MIN(G2:G5)
 G7=IF(G6="","",IF(G6=MAX($G$2:$G$5),"",SMALL($G$2:$G$5,COUNTIF($G$2:$G$5,"<="&G6)+1)))
 H6=IF(G6="","","×")
 I6=IF(G6="","",SUMIF($G$2:$G$5,G6,$I$2:$I$5))

 でやってみて下さい。
 　　G2セルは MOD関数を使ってみました。

 (HANA)

 (HANA)さん ありがとうございました。
 仕事の都合ですぐに出来ないのですが教えて頂いた内容で一度作成します。
 詳しく教えて頂いて本当にありがとうございました。

コメント返信：

[ 一覧(最新更新順) ]

[[20110730005043]] 『合計表示と非表示の方法』（ぺり） ページの最後に飛ぶ

[[20110730005043]]　『合計表示と非表示の方法』（ぺり）　ページの最後に飛ぶ