[[20120314160425]]　『仕入先の支払予定金額を集計したい』（とし）　ページの最後に飛ぶ

『仕入先の支払予定金額を集計したい』（とし）

[それぞれ決済条件の違う（締め日、支払日、現金か手形か）仕入先の支払予定金額を集計したいのですが]（とし）[Excel2000　WIN XP]

 例えば・・・
 - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 あ社：納品日3/05 \10,000 （決済：毎月末締め、翌月末現金支払）
 い社：納品日3/07 \15,000 （決済：毎月末締め、翌々5日現金支払）
 う社：納品日3/10 \20,000 （決済：毎月20日め、当月末現金支払）
 え社：納品日3/12 \25,000 （決済：毎月20日締め、翌月末現金支払）
 お社：納品日3/15 \30,000 （決済：毎月20日締め、翌々5日現金支払）
 か社：納品日3/17 \35,000 （決済：毎月末締め、翌末手形90日支払）
 き社：納品日3/20 \40,000 （決済：毎月末締め、翌々5日手形90日支払）
 - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 ※手形条件の先は手形発効日ではなく手形が引落しされる日を把握したいと思っています※
 例えば、”か社”（毎月末締め、翌末手形90日支払）でいえば
3/17に納品してもらっているので3/末締め→4/末手形発行→7/31\35,000引落し という事です

 1件づつ手入力していけば可能なのはわかっているのですが、
 件数が毎月数千件ありまして。。。

 下のように(TESTファイルをアップさせて頂いています)のように”社名”、”決済条件”、”納品日”、”金額”は手入力します
 決済条件は左のリストからプルダウンリストで選べるようにしてあります
 この情報を入力すれば”現金支払日”、”手形引落日”に自動的に日付を表示できる関数はどのように書けばよろしいでしょうか

 https://box.yahoo.co.jp/guest/viewer?sid=box-l-vadgkyocquf44rpb2bpq6rkhxy-1001&uniqid=068dc4aa-5992-414f-9919-a1d8bac92341&viewtype=detail

 おわかりの方ご伝授願えませんでしょうか
 どうぞ宜しくお願い致します"

http://efcit.co.jp/cgi-bin1/exqalounge.cgi?print+201203/12030007.txt

 (マルチーズ)

 どこかで回答が付きましたでしょうか。。。？

 一応作ってみましたが、間違っている所が有るかも知れませんので
 ご使用前には充分検証して下さい。
	[A]	[B]	[C]	[D]                                  	[E]	[F]	
[1]	社名	納品日	金額	決済条件                             	現金支払	手形引落	
[2]	あ社	3月5日	\10,000	（毎月  末締め、翌月末 現金    支払）	12/04/30		
[3]	い社	3月7日	\15,000	（毎月  末締め、翌々5日現金    支払）	12/05/05		
[4]	う社	3月10日	\20,000	（毎月20日締め、当月末 現金    支払）	12/03/31		
[5]	え社	3月12日	\25,000	（毎月20日締め、翌月末 現金    支払）	12/04/30		
[6]	お社	3月15日	\30,000	（毎月20日締め、翌々5日現金    支払）	12/05/05		
[7]	か社	3月17日	\35,000	（毎月  末締め、翌末   手形90日支払）		12/07/31	
[8]	き社	3月20日	\40,000	（毎月  末締め、翌々5日手形90日支払）		12/08/05	
[9]							
[10]

	[G]	[H]	[I]	[J]	[K]	[L]	[M]
[1]	締	区分	月	日	期日	締め日	手形発行
[2]	E	現金	1	E	－	12/03/31	
[3]	E	現金	2	5	－	12/03/31	
[4]	20	現金	0	E	－	12/03/20	
[5]	20	現金	1	E	－	12/03/20	
[6]	20	現金	2	5	－	12/03/20	
[7]	E	手形	1	E	90	12/03/31	12/04/30
[8]	E	手形	2	5	90	12/03/31	12/05/05
[9]							
[10]

	[O]                                  	[P]	[Q]	[R]	[S]	[T]	
[1]	対応表                               						
[2]	決済条件                             	締	区分	月	日	期日	
[3]	（毎月  末締め、翌月末 現金    支払）	E	現金	1	E	－	
[4]	（毎月  末締め、翌々5日現金    支払）	E	現金	2	5	－	
[5]	（毎月20日締め、当月末 現金    支払）	20	現金	0	E	－	
[6]	（毎月20日締め、翌月末 現金    支払）	20	現金	1	E	－	
[7]	（毎月20日締め、翌々5日現金    支払）	20	現金	2	5	－	
[8]	（毎月  末締め、翌末   手形90日支払）	E	手形	1	E	90	
[9]	（毎月  末締め、翌々5日手形90日支払）	E	手形	2	5	90	
[10]

 O列以降に対応表を作成し
 G列以降を作業列に使用します。

 E2=IF(A2="","",IF(H2="現金",DATE(YEAR(L2),MONTH(L2)+I2+(J2="E"),N(J2)),""))
 F2=IF(A2="","",IF(H2="手形",DATE(YEAR(M2),MONTH(M2)+K2/30+(J2="E"),N(J2)),""))
 G2=IF($D2="","",VLOOKUP($D2,$O$2:$T$9,COLUMN(B2),FALSE))
  K列まで横にフィルドラッグ。
 L2=IF(A2="","",DATE(YEAR(B2),MONTH(B2)+(G2="E"),N(G2)))
 M2=IF(A2="","",IF(H2="現金","",DATE(YEAR(L2),MONTH(L2)+I2+(J2="E"),N(J2))))

 必要行フィルドラッグ。

 (HANA)

 YAHOO!知恵袋と教え○○でやりとり続けてるみたいだね。
 (あそこじゃマルチポスト指摘する人いないから)

 この手のろくでなしは注意受けたところはもう無視なんだろうね

http://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q1083475295

http://qa.itmedia.co.jp/qa7361879.html

 (マルチーズ)

 まぁ、どこかで続いてるんなら　良いですね。
 情報有り難う御座います。

 (HANA)

コメント返信：

[ 一覧(最新更新順) ]

[[20120314160425]] 『仕入先の支払予定金額を集計したい』（とし） ページの最後に飛ぶ

[[20120314160425]]　『仕入先の支払予定金額を集計したい』（とし）　ページの最後に飛ぶ