[[20120504150835]]　『表示について』（GYY）　ページの最後に飛ぶ

『表示について』（GYY）

 列，行，オートフィルタを全表示させたいのですが、
 エラーになるときがあるので、教えていただけないでしょうか？

 Sub TEST()

 Cells.Select
 Selection.EntireColumn.Hidden = False　’列全表示にしたい
 Selection.EntireRow.Hidden = False　　 ’行全表示にしたい
 ActiveSheet.ShowAllData　　　　　　　　’オートフィルタ全表示にしたい
 Range("A1").Select

 End Sub

 Sheet1を開いたとき上記内容で起動できるのですが、
 オートフィルタで何か選択していない場合だと、エラーになってしまいます。
 オートフィルタで何か選択していない場合もあるため、
 フィルタをかけている状態でもかけてない状態でも、
 結果として全表示（列，行，オートフィルタ）することはできますか？

 また、そのようにしたいシートは、Sheet1,2,3,4,5と５シート分あるのですが、
 まとめて全表示することはできるのでしょうか？

 宜しくお願いします。

 ＞ActiveSheet.ShowAllData　　　　　　　　’オートフィルタ全表示にしたい

 この部分で引っかかるということであれば、
 フィルタで非表示になっている行があるかどうか判断して
 分岐すればいいのではないですか？

 If ActiveSheet.FilterMode = True Then　　　　'非表示行がある場合
     ActiveSheet.ShowAllData                  'オートフィルタ全表示にしたい
 End If

 ＞ また、そのようにしたいシートは、Sheet1,2,3,4,5と５シート分あるのですが、
 ＞ まとめて全表示することはできるのでしょうか？
 私は出来るかどうか分からないですが、
 ループで１シートずつ処理したっていいのではないですか？

 (半平太) 2012/05/04 17:37

 半平太様
 ありがとうございます。
 オートフィルタで非表示行がある場合、全表示する
 教えていただき大変助かりました。
 ありがとうございます。

 同じシート内で、計算の繰り返し（ループ）はしたことがあるのですが、
 シートを越えてループをしたことがないのですが、
 そのようなことは可能なのでしょうか？
 初心者なもので、、すみません。。

 (GYY)

 横から失礼

 アップされたコードがやろうとしていることをそのまま各シートに適用

 Sub Sample()
    Dim i As Long
    For i = 1 To 5
        With Sheets("Sheet" & i)
            .Columns.Hidden = False
            .Rows.Hidden = False
            If .AutoFilterMode Then
                If .FilterMode Then .ShowAllData
            End If
        End With
    Next
 End Sub

 (ぶらっと)

 ぶらっと様
 ご回答いただき本当にありがとうございます。
 教えていただいた内容にて作動できたのですが、、
 大変申し訳ないのですが、シート名が〔営業部〕〔管理部〕〔業務部〕〔システム部〕〔製造部〕
 だった場合、どう応用したらいいのでしょうか？
 重ね重ねすみません。。
 お付き合いいただきたく宜しくお願い致します。
 (GYY)

 たとえば

 Sub Sample2()
    Dim shn As Variant

    For Each shn In Array("営業部", "管理部", "業務部", "システム部", "製造部")
        With Sheets(shn)
            .Columns.Hidden = False
            .Rows.Hidden = False
            If .AutoFilterMode Then
                If .FilterMode Then .ShowAllData
            End If
        End With
    Next
 End Sub

 (ぶらっと)

 ぶらっと様
 夜分遅くにも関わらず、大変ありがとうございました。
 助かりました。
 (GYY)

コメント返信：

[ 一覧(最新更新順) ]

[[20120504150835]] 『表示について』（GYY） ページの最後に飛ぶ

[[20120504150835]]　『表示について』（GYY）　ページの最後に飛ぶ