[[20120508131223]]　『値の入ったセルのみを選択するマクロ』（QAZ）　ページの最後に飛ぶ

『値の入ったセルのみを選択するマクロ』（QAZ）

 A１～A10セルに関数式が入っており、計算結果により値の数字か""の空白表示となっています。
 そこにマクロでA列で数字が出ているセル+隣のB列セルのみを選択コピーするものを作りたいのですが
 オートフィルタを使わずに作動するマクロは可能でしょうか？
 ちなみにA列の値の入ったセルは必ず上に偏り空白と数字がパラパラと虫食い状態にはなりません
 ご教示よろしくお願い致します。

 選択コピーした後のマクロの処理は何を行うのでしょうか。
 他の場所に移動するだけであれば、コピーせずに直接代入してしまった方が簡単な気がしますが、
 こんな感じのことでしょうか。
 (Mook)
 Sub QAZCopy() 
    For r = 1 To 10 
        If Cells(r + 1, "A").Value = "" Then Exit For 
    Next 
    Range("A1").Resize(r, 2).Copy 
 End Sub

 該当領域が、本当に、連続してまとまって、１つだけあるということならSample2。
 そうでもないのならSample1。

 いずれも、D:E列にコピーするサンプル。

 Sub Sample1()
    Dim myR As Range
    On Error Resume Next
    Set myR = Range("A1:A10").SpecialCells(xlCellTypeFormulas, 1)
    On Error GoTo 0
    If Not myR Is Nothing Then
        Columns("D:E").ClearContents
        myR.Copy Range("D1")
        myR.Offset(, 1).Copy Range("E1")
    Else
        MsgBox "該当のセルはありません"
    End If
 End Sub

 Sub Sample2()
    Dim myR As Range
    On Error Resume Next
    Set myR = Range("A1:A10").SpecialCells(xlCellTypeFormulas, 1)
    On Error GoTo 0
    If Not myR Is Nothing Then
        Columns("D:E").ClearContents
        myR.Resize(, 2).Copy Range("D1")
    Else
        MsgBox "該当のセルはありません"
    End If
 End Sub

 (ぶらっと)

 Mook様 ぶらっと様 
 コピー後はまたケースバイケースで別のファイルに適宜貼り付けるので
 コピーまでのマクロを必要としておりました。
 希望通りのアクションができました。ありがとうございました。
 (QAZ)

コメント返信：

[ 一覧(最新更新順) ]

[[20120508131223]] 『値の入ったセルのみを選択するマクロ』（QAZ） ページの最後に飛ぶ

[[20120508131223]]　『値の入ったセルのみを選択するマクロ』（QAZ）　ページの最後に飛ぶ