[[20120821211343]]　『計算式について』（なな）　ページの最後に飛ぶ

『計算式について』（なな）

下記の様な表が「シート２」下段にまだまだあります。
「シート1」にバナナと入力すれば自動的にタイ、その下に沖縄を表示させたいのですが
上手く出来ません。
VLOOKUPで横並びなら何ら問題なく出来ますが、バナナと入力すれば縦に一回で2行を表示させたいので、計算式を教えて下さい。
又、どの様な表が一番良いのか教えて頂ければありがたいです。宜しくお願いします。
尚、種類によっては1行、2行～4行等もあります。

ＡＢ
バナナタイ

	沖縄
みかん	和歌山
	長野
	愛媛
りんご	青森
苺	千葉
	徳島
	宮崎
	長崎

 Sheet2 に上記の表があって
 Sheet1 の A1 に品名を入れるとすると

 B1=IF(IFERROR(MATCH($A$1,Sheet2!A:A),"N/F")<>"N/F",INDEX(Sheet2!B:B,MATCH($A$1,Sheet2!A:A)),"")
 B2=IF(AND(B1<>"",INDEX(Sheet2!A:A,MATCH($A$1,Sheet2!A:A)+ROW(A1))="",INDEX(Sheet2!B:B,MATCH($A$1,Sheet2!A:A)+ROW(A1))<>""),INDEX(Sheet2!B:B,MATCH($A$1,Sheet2!A:A)+ROW(A1)),"")
 として、B2 をB3以降最大データ数だけコピー
 でどうでしょうか。
 (Mook)

 B1 =IF(COUNTIF(Sheet2!A:A,A1),VLOOKUP(A1,Sheet2!A:B,2,FALSE)&"","")
 B2 =IF(B1="","",IF(INDEX(Sheet2!A:A,MATCH(A$1,Sheet2!A:A,0)+ROW(A1))="",INDEX(Sheet2!B:B,MATCH(A$1,Sheet2!A:A,0)+ROW(A1))&"",""))

 B2を下へコピー。

 (GobGob)

 うーん、シンプルに書けるものですね。
 やっぱり関数は使いこなせていない・・・。
 (Mook)

 ＞どの様な表が一番良いのか教えて頂ければありがたいです。

 下のようにA列を全部埋めることです。

 　　　A　　　　B
1　　バナナ　　タイ
2　　バナナ　　沖縄
3　　みかん　　和歌山
4　　みかん　　長野
5　　みかん　　愛媛

 Sheet1のB1
 =IF(COUNTIF(Sheet2!A:A,$A$1)<ROW(A1),"",INDEX(Sheet2!B:B,MATCH($A$1,Sheet2!A:A,0)+ROW(A1)-1))
 下にフィルコピー
　
　
 なおSheet2のA2から下を選択して条件付き書式を設定
 数式を　=A2=A1　にしてフォント色を白にしておけば、品名は先頭のセルにしか表示されません。

 （よみびとしらず）

(Mook)様、(GobGob)様、（よみびとしらず）様
出来ました。有難うございます。
色々な計算式で表時可能ですね。
さすがと云う他ありません。
全てを試し自身の参考にしたいと思います。
　　　　　　　　　　　　　　　　　　　　　　　　（なな）

コメント返信：

[ 一覧(最新更新順) ]

[[20120821211343]] 『計算式について』（なな） ページの最後に飛ぶ

[[20120821211343]]　『計算式について』（なな）　ページの最後に飛ぶ