[[20121017103344]]　『横方向に複数合計』（ジム吉）　ページの最後に飛ぶ

『横方向に複数合計』（ジム吉）

ｴｸｾﾙバージョン　EXCEL2007 SP3　OSバージョン　WindowsXP

初めて質問させてもらいます。まず下記のような表があります。

　　A　　　　B　　　 C　　　D　　　E　　　　　F　　　・・・・・・
1　日付　金額　日付　金額　　日付　　　金額　　
2 H20.4.1 5000 H20.5.1 40000 　H20.6.1 　 800
3 H21.4.1 5000 H21.5.1 50000 　H21.6.1 　　900
4 H22.4.1 5000 H22.5.1 30000 　H22.6.1 　　700
5 H23.4.1 5000 H23.5.1 20000 　H23.6.1 　　200

このように横方向に50列ぐらいあり、最終列に日付の条件で抽出して金額のみの
合計を数式で入力したいのですが、単純にSUMとIFで何回も繰り返す以外に何か
数式はありませんでしょうか？
数式例　=SUM(IF(A2>DATE(2008,4,20),B5,0),IF(C2>DATE(2008,4,20),D5,0),････････
何かいい数式があれば教えていただけませんか？
よろしくお願いします。

 =SUMPRODUCT((A2:AW500>"2008/4/20"*1)*B2:AX500*MOD(COLUMN(A2:AW500),2))

 (GobGob)

すいません、日付の条件というのが2つありまして。
例2008/4/20から2012/10/10まで
説明不足でした、すいません。　　　(ジム吉)

 =SUMPRODUCT((A2:AW500>"2008/4/19"*1)*(A2:AW500<"2012/10/11"*1)*B2:AX500*MOD(COLUMN(A2:AW500),2))

 (GobGob)

たびたびすいません。
GodGodさんの数式を当方の表にて参照先を変えて
試してみたのですが、エラー値「＃N/A」が表示されます。

=SUMPRODUCT((L9:Q9>ﾃﾞｰﾀ!$K$7*1),(L9:Q9<ﾃﾞｰﾀ!$K$9*1)*M9:P9*MOD(COLUMN(L9:Q9),2))

と6列分で試してみたのですが、どこかおかしい点はありますか？
ﾃﾞｰﾀ!K7とK9には日付が入力されています。
考える頭が無くバカでごめんなさい。　　(ジム吉)

 あー！ 行単位だったんですか・・・勘違い。

 んで、数式のおかしいところだけど、考え方はOKっす。範囲がおかしいです。

 L9:Q9 → 6列分。
 M9:P9 → 4列分。

 列数が違うね。 M9:P9 → M9:R9

 あと、MOD関数の中のCOLUMNはスタート列が偶数なら COLUMN(範囲)-1 とするか
 範囲をずらしてちょ。

 (GobGob)

ほんとにすいません。
先ほどの回答をもとに

=SUMPRODUCT((L9:Q9>ﾃﾞｰﾀ!$K$7*1)*(L9:Q9<ﾃﾞｰﾀ!$K$9*1)*M9:R9*MOD(COLUMN(L9:Q9)-1,2))

としてみたんですがセルR8にこれを入力すると9列目の合計はでましたが
肝心のR9に入力すると循環参照がでてしまいます。
これは単純にR列が循環参照になっているのでしょうか？
ご指導願います。　　　　　　　　　　（ジム吉）

 6列分て、L列からQ列までちゃいますの？
 なんでR列なんか出てくるんでしょうね。
 範囲がR列までで、数式を入れるのもR列て
 そら循環参照になりますわなあ。

 ＞ﾃﾞｰﾀ!$K$7*1
 K7は日付データ（シリアル値）でしょ？
「*1」なんてせんでよろしいよ。
 せなアカンのは日付に変換可能な文字列データの場合。

 それと、開始日が2008/4/20、終了日が2012/10/10やとして
 データシートのK7とK9にはいつの日付を入れてます？
 その数式やと、2008/4/19 と 2012/10/11？

 ストレートに 2008/4/20 と 2012/10/10 にした方がわかりやすいと思いません？
 もちろん数式の比較演算子を変更せなあきませんけどね。　
　
　
 ﾃﾞｰﾀ!$K$7に期間の開始日当日、ﾃﾞｰﾀ!$K$9に終了日当日やとして

 =SUMPRODUCT((L9:P9>=ﾃﾞｰﾀ!$K$7)*(L9:P9<=ﾃﾞｰﾀ!$K$9)*MOD(COLUMN(M9:Q9),2),M9:Q9)

 日付はL列から始まって、最後はP列
 金額はM列から始まって、最後はQ列

 比較演算子を変えてますから、注意してください。
 L9:P9>=ﾃﾞｰﾀ!$K$7　と　L9:P9<=ﾃﾞｰﾀ!$K$9
 　　 ~~　　　　　　　　　　~~
 奇数列か偶数列かより、見出しを使った方がええと思いますよ。
 見出しが8行目やとすると

 =SUMPRODUCT((L9:P9>=ﾃﾞｰﾀ!$K$7)*(L9:P9<=ﾃﾞｰﾀ!$K$9)*($M$8:$Q$8="金額"),M9:Q9)
　
 ややこしいでしょ？
 日付と金額の行を別にするか、列を分けてタテに入力していったら
 集計も簡単にできるのを承知の上で、あえてこういうレイアウトにしてるんですよね？
 特に理由がないんやったら、そっから見直した方がええですよ。
　 
 （よみびとしらず）

よみびとしらずさん、ありがとうございます。
無事にできました。レイアウトに関しては計算云々のレイアウトでは無く、作り直したほうが早いのは承知
でしたが、レイアウトを変えられない事情がありましたので質問させていただきました。
何はともあれ、解決できたのでよかったです。　　（ジム吉）

コメント返信：

[ 一覧(最新更新順) ]

[[20121017103344]] 『横方向に複数合計』（ジム吉） ページの最後に飛ぶ

[[20121017103344]]　『横方向に複数合計』（ジム吉）　ページの最後に飛ぶ