[[20130111185722]]　『初歩的で失礼します。』（歩）　ページの最後に飛ぶ

『初歩的で失礼します。』（歩）

 A列に職員の名前　B列から日付となっている勤務表があります。
 　　　 1　 2　 3　 4 　5   6 
 山田　早　遅　早　早　日　日　
 岡部　遅　日　日　日　遅　早
 鈴木　日　早　遅　遅　早　遅
 別のシートのA1のセルに日付を入れるとB1に早番
　　　　　　B2のセルに日付を入れるとB2に日勤
　　　　　　C1のセルに日付を入れるとC2に遅番
 が出てくるようにしたいと考えております。
 この時の関数って何になりますか？
 たたまにに早番が2人、日勤が2人、遅番が2人になる時があり大変困惑をしております。

 Excel2010です。

 どなたかご教授くださいますようよろしくお願いいたします。

 >別のシートのA1のセルに日付を入れるとB1に早番

 どんな日付を入れても早番？

 >B2のセルに日付を入れるとB2に日勤

 他は○１のセルに入力-->○2のセルに表示　となっているけど、ここだけは両方 2 ？

 どうも、何をどこに入れるとどこに何を表示というルールがわからない。
 D5 のセルに日付を入れるとどうなるの？

 (ぶらっと)

 ぶらっとさんも書いておられますが、ちょっと表示のルールがわかりません。
　
 >A1のセルに日付を入れるとB1に早番 
 >B2のセルに日付を入れるとB2に日勤 
 >C1のセルに日付を入れるとC2に遅番 
これだと次のレイアウトになりますが？？？
  　__A__ __B__ __C__
1 　1/9  早番    1/11 
2　　　　1/10 　遅番           
　　　 　↑
　　　　　ここは日付を入れるセルと同じセルに表示？

 それとも、次のようなレイアウトですか？
 A1のセルに日付を入れるとA2に早番 
 B1のセルに日付を入れるとB2に日勤 
 C1のセルに日付を入れるとC2に遅番

 　__A__ __B__ __C__
1  1/9   1/10 　1/11 
2　早番　日勤　遅番

 であれば、
A2に　=IF(A1="","","早番")　
B2に　=IF(B1="","","日勤")
C2に　=IF(C1="","","遅番")
とか　？？？

 (usamiyu)

 質問ついでに、
 シートはいくつあるのですか？
 どのシートの A1,B2,C1 に日付を入れると、誰の日付のところに結果が出るのですか？
 名前とシートを関係付けるものは何でしょうか。
 (Mook)

ご返答ありがとうございます。

上手な質問ができなくて申し訳ございません。
説明が下手でご迷惑をおかけてすいません。

正確にはシートは５つあります。

シート１が顧客管理表。
シート２が職員勤務表。
シート３が顧客の来客時間表。
シート４が３週間分の予定表。
シート５が本日の予定。

シートの１から３に入力をするとシート４とシート５の予定表にその時に来る顧客の名前、その時間、その時の早、日、遅の担当職員
が出るようにしたいのですがなかなかうまくいきません。

シート５の本日の予定には
　　　
早番　 ○　
日勤　 ○
遅番　 ○

となっているセルがあり○のところに担当職員名が来るようにしたいのです。

なのでその日の日付をもとに勤務表から職員名を割り出すような関数がありましたらよろしくお願いいたします。

うまく伝わるといいのですが。

（歩）

 ・その5つのシートが、この質問にどう関係してくるのかが不明
 ・それぞれのデータが、具体的にどのセルに入っているのかが不明
 ・日付というのがシリアル値なのか、単なる 1 から 31 の数値なのかが不明

 一応参考まで

 《Sheet2》
	A	B	C	D	E	F	G
1		1	2	3	4	5	6
2	山田	早	遅	早	早	日	日
3	岡部	遅	日	日	日	遅	早
4	鈴木	日	早	遅	遅	早	遅
5	安倍		遅	早			日

 《Sheet5》
	A	B	C
1		6　←B1セル日付　
2	早番	岡部	
3	日勤	山田	安倍
4	遅番	鈴木

 B2: =IFERROR(INDEX(Sheet2!$A:$A,SMALL(IF(INDEX(Sheet2!$B$2:$K$10,0,MATCH($B$1,Sheet2!$B$1:$K$1,0))=LEFT($A2),ROW($A$2:$A$10)),COLUMN(A1))),"")

 Ctrl＋Shift＋Enterで確定し、右・下フィルコピー

 日付が単なる数値で、連番になってるのであれば、もう少し簡単になる

 （よみびとしらず）

 ↑ のレイアウトで、作業列の使用可やったら

 Sheet2の表がどの列まで続いてるのかわかりませんけど
 仮にK列までやとして

 Sheet2
 L2: =INDEX(B2:K2,MATCH(Sheet5!$B$1,$B$1:$K$1,0))&""
 M2: =IF(L2="","",L2&COUNTIF($L$2:L2,L2))

 両方とも下にフィルコピー

 Sheet5
 B2: =IFERROR(INDEX(Sheet2!$A$2:$A$10,MATCH(LEFT($A2)&COLUMN(A1),Sheet2!$M$2:$M$10,0)),"")

 普通にEnterだけで確定し、右・下フィルコピー

 （よみびとしらず）

コメント返信：

[ 一覧(最新更新順) ]

[[20130111185722]] 『初歩的で失礼します。』（歩） ページの最後に飛ぶ

[[20130111185722]]　『初歩的で失礼します。』（歩）　ページの最後に飛ぶ