[[20130416085821]]　『料金表から複数条件内の区間の料金を抽出』（笹）　ページの最後に飛ぶ

『料金表から複数条件内の区間の料金を抽出』（笹）

おはようございます。

今回、以下のような表から、出発が福島、到着が山形、重量が６の料金（この場合250円）を抽出したい時、どのように関数を入れるとよろしいでしょうか？

　　Ａ　　　　Ｂ　　　　Ｃ　　　　Ｄ　　　Ｅ　　　

 1　　　　　出発　　　　到着　　　重量　　料金
 2　8/25　　滋賀　　　　京都　　　4　　　　200
 3　8/30　　福島　　　　山形　　　6　　　　250
 4　9/12　　沖縄　　　　大分　　　8　　　　600
 5　9/28　　福島　　　　山形　　　2　　　　150

表は６００行ほどありますので、条件に該当するものが複数ある場合は、ひとつだけ抽出するものとします。

もしよければ、ご教授願います

 こんな感じ。
 =SUMPRODUCT((B2:B5="福島")*(C2:C5="山形")*(D2:D5=6),E2:E5)
 BJ

 >条件に該当するものが複数ある場合は、ひとつだけ抽出するものとします。
 であれば1例として表の上のほうにあるものを持ってくるとして
 =INDEX(E$2:E$5,MATCH(1,INDEX((B$2:B$5="福島")*(C$2:C$5="山形")*(D$2:D$5=6),0),0))
 (ねむねむ)

BJさん

おはようございます。ご回答くださいましてありがとうございます

出していただいた関数式を利用させていただいたのですが･･･

なんだかすごく大きい数字になったのですが、どうしたら良いでしょうか･･･（´・×・｀）

（笹）

 すみません。
 >条件に該当するものが複数ある場合
 これ全く考えてませんでした。

 >なんだかすごく大きい数字になったのですが
 複数あった場合、
 出発が福島、到着が山形、重量が６　の条件があったものを足しこんじゃうから。
 使えない数式ですみませんでした。

 ねむねむさんのindexを使ってください。
 BJ

ねむねむさん

おはようございます。ご回答下さいまして、ありがとうございます。

出していただいた関数式を利用させていただいたのですが･･･エラーになってしまいます

もしかすると私の表の書き方などが悪いのでしょうか･･･

（笹）

BJさん

なるほどです･･･

私の書き方も悪いですよね･･･ごめんなさい（´・・｀）

ご協力感謝いたします！

（笹）

 なんというエラーなのかを書いて。
 BJ氏の式で大きな値が出る(0ではない)のであればエラーにはならないと思うのだが。
 (ねむねむ)

 あと、Excelのバージョンも書いておいてほしい。
 (ねむねむ)

ねむねむさん

Excelは2003を使用しております。

#N/Aと表示されております

（笹）

 #N/Aということは条件に該当するものがない場合だが、BJ氏の式を使った場合(条件は同じにして)の結果は？
 (ねむねむ)

ねむねむさん

1575000という数値がでました。

ちなみに、該当数は４８件でした。

あと、関数式に絶対参照を用いています

 実際に入力している式を書いてもらえないか？
 (ねむねむ)

ねむねむさん

■BJさんの式■
　=SUMPRODUCT((B2:B5="福島")*(C2:C5="山形")*(D2:D5=6),E2:E5)

　　　　↓　　　↓　　　↓　　　↓　　　↓　　　↓

　=SUMPRODUCT(($C$3:$C$644=H20)*($D$3:$D$644=J20)*($E$3:$E$644=K20),$F$3:$F$644)

■ねむねむさんの式■
　=INDEX(E$2:E$5,MATCH(1,INDEX((B$2:B$5="福島")*(C$2:C$5="山形")*(D$2:D$5=6),0),0))

　　　　↓　　　↓　　　↓　　　↓　　　↓　　　↓

　=INDEX($F$3:$F$644,MATCH(1,INDEX(($C3:$C644=H20)*($D$3:$D$644=J20)*($F$3:$F$644=K20),0),0))
　

（笹）
　　　　　　　

 割り込み失礼
　
=INDEX($F$3:$F$644,MATCH(1,INDEX(($C3:$C644=H20)*($D$3:$D$644=J20)*($F$3:$F$644=K20),0),0)) 
↓
=INDEX($F$3:$F$644,MATCH(1,INDEX(($C3:$C644=H20)*($D$3:$D$644=J20)*($E$3:$E$644=K20),0),0)) 
　
かな？
（みやほりん）

みやほりんさん

･･･あ、ほんとだ･･･

ちゃんと出てくれました！

ごめんなさい、ありがとうございます！

ねむねむさん、たくさんご迷惑かけてしまって申し訳ありません･･･

回答してくださった皆様、本当にありがとうございます！

コメント返信：

[ 一覧(最新更新順) ]

[[20130416085821]] 『料金表から複数条件内の区間の料金を抽出』（笹） ページの最後に飛ぶ

[[20130416085821]]　『料金表から複数条件内の区間の料金を抽出』（笹）　ページの最後に飛ぶ