[[20130618131745]]　『一部の文字列を赤字かつ太字に』（スム）　ページの最後に飛ぶ

『一部の文字列を赤字かつ太字に』（スム）

Excel2003を使用しています。

Sheet1にある表の中から"日本"という文字だけを探して、

その文字だけ赤字かつ太字にしたいです。

条件付書式を使ってみましたが

セルすべての文字が変わってしまいました。

たとえば「ＡＢＣ日本ＡＢＣ」とセルにあったら"日本"のみ

赤字と太字にしたいのですが何か方法はございますでしょうか・・・

いろいろ考えてみましたが、この一部だけというのが

どうしてもできませんでした

みなさまどうぞよろしくお願いいたします。

Sub test()
Dim rng As Range, r As Range, i As Long, colInd As Integer
With ActiveSheet
Set rng = .Range("a1:z100") '範囲設定
txt = "日本" '文字
colInd = 3 '赤色
For Each r In rng
If InStr(r, txt) > 0 Then
With r.Characters(InStr(r, txt), Len(txt))
.Font.ColorIndex = colInd
.Font.FontStyle = "太字"
End With
End If
Next
End With
End Sub

A1～Z100までの範囲ないですが、
こんな感じでどうでしょうか？？

(ぬ)

 Sub test()
    Dim r As Range, ff As String, m As Object
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "日本"
        Set r = Cells.Find("日本")
        If Not r Is Nothing Then
            ff = r.Address
            Do
                For Each m In .Execute(r.Value)
                    With r.Characters(m.firstindex + 1, m.Length).Font
                        .Color = vbRed
                        .Bold = True
                    End With
                Next
                Set r = Cells.FindNext(r)
            Loop Until ff = r.Address
        End If
    End With
End Sub
(seiya)

ぬさま、seiyaさま

早速のご回答ありがとうございました！
VBAでないとできないのですね。

早速実行してみたところ思い通りにできました。
すごいですね！！

本当にありがとうございます。

（スム）

コメント返信：

[ 一覧(最新更新順) ]

[[20130618131745]] 『一部の文字列を赤字かつ太字に』（スム） ページの最後に飛ぶ

[[20130618131745]]　『一部の文字列を赤字かつ太字に』（スム）　ページの最後に飛ぶ