[[20130909192333]]　『複数検索』（素人）　ページの最後に飛ぶ

『複数検索』（素人）

 複数の名前から検索したいのですが宜しくお願いします。

 シート1

    A    B 　 C 　 D 
 1　あ
 2  い   222
 3  う   333
 4  え   444
 5  あ   111

 シート2

     A     B 　
 1　あ     0 
　
 シート1のＡ列に　あ　が2つある場合Ａ1しかVLOOKUPでは検索しない
 のですが、A5の　あ　にあるB5の 111 を検索したいのですが宜しくお願いします。

     A     B 　
 1　あ    111

 作業枠とかは使用したくないのでシート2のB1に数式でできればお願いします。

 （素人）

 >A5の　あ　にあるB5の 111 を検索したいのですが

 どの「あ」を検索するのですか？
 例
 1.二つ目の「あ」
 2.最後の「あ」
 3.B列が空白ではない「あ」
  (その場合、それが二つ以上ある場合はどの「あ」？)
 4.A1以外の最初の「あ」

 など、例題からはいろいろな条件が考えられます。
(tora)

 toraさん

 説明不足ですみません

 もし、A1が空白でA5が入っていればA5を検索（列にある空白でないセル）
 が検索出来ればと思います。
 (素人）

 =INDEX(Sheet1!B1:B10,SMALL(IF((Sheet1!A1:A10=A1)*(Sheet1!B1:B10<>""),ROW(A1:A10)),1))

 Sheet2のB1に上の式を入力して、CtrlキーとShiftキーを押しながらEnterで確定してください。
                               ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 B列が空白でない「あ」が二つ以上ある場合は、その中で一番上の「あ」の右の値を表示します。
 (tora)

 =VLOOKUP(A1,IF({1,0},IF(Sheet1!B1:B5="","",Sheet1!A1:A5),Sheet1!B1:B5),2,FALSE)
 =INDEX(Sheet1!B1:B5,MATCH(A1,IF(Sheet1!B1:B5="","",Sheet1!A1:A5),0))
 上記二つはShift+Ctrl+Enterで式を確定。

 =INDEX(Sheet1!B1:B10,MATCH(1,INDEX((Sheet1!A1:A10=A1)*(Sheet1!B1:B10<>""),0),0))
 こちらは通常通りEnterで式を確定。
 (ねむねむ)

 toraさん

 有難うございます。
 (素人）

 ねむねむさん

 有難うございます。

 Shift+Ctrl+Enterで式を確定の式と通常通りEnterで式を確定の式ですがどちらも
 同じ値がでますが、どちらを使ったらよいですか？
 あと、#N/Aのエラーを出さない方法も教えて下さい。
 (素人）

 >同じ値がでますが、どちらを使ったらよいですか？
 どちらも結果は同じなのだから好きな方。

 とにかく短いのがいいのであれば一番短いものを、Shift+Ctrl+Enterが面倒であればEnterだけの式を。

 >あと、#N/Aのエラーを出さない方法も教えて下さい。
 Excelのバージョンが2003以前の場合は
 =IF(SUMPRODUCT((Sheet1!A1:A5=A1)*(Sheet1!B1:B5<>"")),式,"無し")
 2007以降の場合は
 =IFERROR(式,"無し")

 エラーの場合に何も表示させないのであれば「"無し"」を「""」に。
 (ねむねむ)

 ねむねむさん

 有難うございます。
 =IF(○○="","",INDEX(Sheet1!B1:B10,MATCH(1,INDEX((Sheet1!A1:A10=A1)*(Sheet1!B1:B10<>""),0),0)))
 で消えました。
 お世話になりました。またわからない時は宜しくお願いします。
 （素人）

コメント返信：

[ 一覧(最新更新順) ]

[[20130909192333]] 『複数検索』（素人） ページの最後に飛ぶ

[[20130909192333]]　『複数検索』（素人）　ページの最後に飛ぶ