[[20140315195133]]　『SUMIFをSUBTOTALの要領で表示部分のみ計算したい』（SUB）　ページの最後に飛ぶ

『SUMIFをSUBTOTALの要領で表示部分のみ計算したい』（SUB）

こんばんは、お世話になります。

SUMIFですと総合計が計算できますが、
非表示部分は計算せずにSUBTOTALの要領で計算したいのですが
うまくできません。
以下の式を非表示部分は計算せずに、表示部分のみ計算したいのですが
=SUMIF(E:E,AX2,AS:AS)
わかる方、ご教授お願い致します。
よろしくお願い致します。

＜使用アプリ：2000、使用 OS：WindowsXP ＞

 オートフィルタを使わず自分で任意の行を非表示にしているのですか？
（se_9） 2014/03/16(日) 14:51

 フィルタでなく「表示・非表示」っすね？

 Excel2000なら SUBTOTAL 100番台は使えないですね
 列単位ならCELL関数を使えば出来そうだけど行単位ならちょいややこしいっす。

 例として。

	A	B	C
1	項目	15	作業列
2	A	1	13.5
3	B	2	13.5
4	C	3	13.5
5	A	1	13.5
6	B	2	13.5
7	C	3	13.5
8	A	1	13.5
9	B	2	13.5

 C列作業列、B1に合計

 C2セルで名前定義

 名前：高さ
 範囲：=GET.CELL(17,Sheet1!A2)+NOW()*0

 C2セルに =高さ

 B1 =SUMIF(C:C,">0",B:B)

 これで行の表示・非表示範囲の合計処理。
　
（GobGob） 2014/03/17(月) 11:11

se_9様
お世話になります。
遅くなりすみません。
オートフィルタを使って非表示にしていす。
よろしくお願い致します。
（SUB） 2014/03/18(火) 12:39

 GobGobさんへのお礼もちゃんと書きましょう。

 たとえば

 	E	AS	AX
 1	項目	数量	
 2	a	5	
 3	a	5	
 4	a	15	
 5	b	5	
 6	b	5	
 7	b	10

 のような表で、AS列で数量が5のものを抽出すると

 	E	AS	AX
 1	項目	数量	
 2	a	5	
 3	a	5	
 5	b	5	
 6	b	5

 となりますが、aの数量の合計だけ出したいということですよね？
 現在検索条件がAX2セルに入っているようですが、オートフィルターを使用するため
 AX1セルに検索条件を入れてAX2セルに =SUBTOTAL(3,E2)
 下にフィルコピー
 AY1セルに =SUMPRODUCT((E2:E1000=AX1)*(AX2:AX1000=1)*AS2:AS1000)

 でどうでしょうか？
（se_9） 2014/03/18(火) 13:19

 データの具体例がないんで、よくわかんないけど、、

 どこか作業列に　=IF(SUBTOTAL(9,AS2),AS2,"")　と入れておいて
 普通に SUMIF で集計。
　　
　
 参考までに作業列を使わない場合、検索値がAX1だとして。

 =SUMPRODUCT((E2:E100=AX1)*SUBTOTAL(9,INDIRECT("AS"&ROW(AS2:AS100))))
　
　
【追記】
 作業列の式は　=SUBTOTAL(9,AS2)　だけでもいいかもしんないけど、
 IFをかませないとフィルタに不具合が出るかもしれないんで（出ないかもしれないけど）
 つけておきました。
　
（名無しのおっさん） 2014/03/18(火) 14:16　追記14:43

se_9 様
GobGob 様
名無しのおっさん様

大変ありがとうございます。
名無しのおっさん様・se_9様の方法でいずれも出来ました！

GobGob様の方法は、私には難しいです。
ありがとうございます。

今後ともよろしくお願いいたします。
（SUB） 2014/03/23(日) 21:43

コメント返信：

[ 一覧(最新更新順) ]

[[20140315195133]] 『SUMIFをSUBTOTALの要領で表示部分のみ計算したい』（SUB） ページの最後に飛ぶ

[[20140315195133]]　『SUMIFをSUBTOTALの要領で表示部分のみ計算したい』（SUB）　ページの最後に飛ぶ