[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『月の日割り目標金額 加算』（やまちゃん）
目標金額をその月の営業日で割り出した日割り金額を、営業日の日毎に加算させていきたいと思っています 。
その月の数字を別セルに入力すると、1日目から目標金額の列に計算結果が表示され、なおかつ定休日(水曜日)には『定休日』と出るようにしたいと思っており難航しております。
希望としては、通常の累計のように、はじめから表示させたいと思っています。
例えば、月を変えると下記の状態になるのが希望です。
目標金額 1000000
A B C 1 日付 曜日 目標金額 2 1日 火 125000 3 2日 水 定休日 4 3日 木 250000 5 4日 金 375000 6 5日 土 500000 7 6日 日 685000 8 7日 月 750000 9 8日 火 875000 10 9日 水 定休日 11 10日 木 1000000
A列、B列、C列にはそれぞれ、月を変えると自動で変換される数式を入力しています。
C列の定休日以外、目標金額をその月の営業日で割り出した日割り金額を、営業日の日毎に加算させていく事が出来ず、今は定休日以外は空白にしています。
【C列の数式】=IF(WEEKDAY(A2,2)=3,"0","")
です。
説明が分かりにくくてすみませんが、どうかアドバイスお願いします。
＜ 使用 Excel：Excel2013、使用 OS：Windows8 ＞
???さんの回答を基に別案。
C2 =IF(B32="水","定休日",D$1/(COUNT(C33:C$33)+1)) C32までコピー。
※C33セル 空白が前提。 （GobGob） 2014/05/15(木) 10:42
ご教示ありがとうございます。
?⁇様からお教え頂いた数式を入力しましたら、理想通りに
定休日を除いて、目標金額/稼働日数を加算していき、
なおかつ水曜日には定休日と出ました。
GobGob様からお教え頂いた数式を入力すると、目標金額のみ表示されました。
指定セルを変えてみたりしたのですが、
何処をどうすれば理想の計算になるのか、力及ばず分かりませんてした。
お二方にご教授頂き、本当に感謝しています。
ありがとうございました！
ただ、月を6月に変換すると31日がエラーになり、
累計も31日ある数字で終わってしまいます。
A B C D 1 日付 曜日 目標金額 目標金額 2 1日 水 定休日 1000000 3 2日 木 125000 4 3日 金 250000 5 4日 土 375000 6 5日 日 500000 7 6日 月 685000 8 7日 火 750000 9 8日 水 定休日 10 9日 木 875000 11 #VALUE!
の様になってしまいます。
30日、31日がない月は空白になる様にするには何か数字、
もしくは数式をプラスすると空白になる様に出来るのでしょうか？
度々申し訳ないのですが、再度ご教授頂けたら助かります。
どうぞよろしくお願いいたします。
（やまちゃん） 2014/05/16(金) 01:52
C2 =IF(B2="水","定休日",D$1/(COUNT(C2:C$33)+1)))
の間違いでした。
んで。さらに修正
C2 =IF(A2="","",IF(B2="水","定休日",D$2/(COUNT(C3:C$33)+1))) 下へコピー。
※33行目空欄のこと。 （GobGob） 2014/05/16(金) 09:11
まず、D2を目標金額にしているなら、E2を営業日数とします。
E2=DAY(DATE(YEAR($A$2),MONTH($A$2)+1,0))-COUNTIF($B$2:$B33,"=水")
次に、B列は現在「=TEXT(A2,"aaa")」等として曜日表示していると思われますが、
以下のように変更し、余分な月分を消します。
=IF(MONTH($A$2)=MONTH($A2),TEXT(A2,"aaa"),"")
同様に、C列の数式も変更します。
=IF(MONTH($A$2)=MONTH($A2),IF(B2="水","定休日",$D$2/$E$2*COUNTIF($B$2:$B2,"<>水")),"")
（???） 2014/05/16(金) 10:14
水曜日以外に定休日はないの？ 水曜日が祝日でも定休日？
だとして、A列にどんな数式が入っているのかわからないけど、 #VALUE! になるってことは、6月の31日のところは空白文字列「""」ですよね？
D2セルに目標金額を入力 E2セルに1日あたりの金額（下の式）
E2 =D2/COUNTIFS(B2:B32,"?",B2:B32,"<>水")
B2 =TEXT(A2,"aaa") C2 =IF(A2="","",IF(B2="水","定休日",$E$2*(COUNT($C$1:C1)+1))) B2とC2を32行目までコピー （名無しのおっさん） 2014/05/16(金) 14:51
再度ご教示ありがとうございます。
???様からお教え頂いた改良策を元に、E2に営業日数を出す数式を入れ、B列には余分な月分を消しす、
=IF(MONTH($A$2)=MONTH($A2),TEXT(A2,"aaa"),"") の数式を入力し、
C列にも同様に
=IF(MONTH($A$2)=MONTH($A2),IF(B2="水","定休日",$D$2/$E$2*COUNTIF($B$2:$B2,"<>水")),"")の関数を入れました。
しかし、31日がない月のC列最終日に『#VALUE!』と出るので、
GobGob様と、名無しのおっさん様からお教え頂いた
C2 =IF(A2="","",IF(B2="水","定休日",D$2/(COUNT(C3:C$33)+1)))
C2 =IF(A2="","",IF(B2="水","定休日",$E$2*(COUNT($C$1:C1)+1)))
の数式と???様からお教え頂いた数式を組み合わせて、
C2 =IF(A2="","",IF(B2="水","定休日",$D$2/$E$2*COUNTIF($B$2:$B2,"<>水")))と数式を入力すると、
理想通り定休日を除いて、目標金額/稼働日数を加算していき、
なおかつ水曜日には定休日と出て、31日がない月は空白になりました！
皆様に何度もご教授頂き、感謝しています。
本当にありがとうございました!!!
（やまちゃん） 2014/05/18(日) 02:15
先日お答えいただいた内容にプラスして再度ご教示いただきたくお願いに上がりました。
A B C D E F 1 日付 曜日 目標累計額 目標金額 営業日数 月 2 1日 火 125000 1000000 8 5 3 2日 水 定休日 4 3日 木 250000 5 4日 金 375000 6 5日 土 500000 7 6日 日 685000 8 7日 月 750000 9 8日 火 875000 10 9日 水 定休日 11 10日 木 1000000
の表で、不定期の休みが発生した場合に、G列に"休み"など入れると
C列が休みになり、なおかつC列の累計額も休みと定休日を除いた、目標金額/稼働日になる数式がございましたらご教示お願いします。
【A列】=DATEVALUE(F1&"/"&E1&"/1")
【B列】=IF(MONTH($A$2)=MONTH($A11),TEXT(A2,"aaa"),"")
の数式を入力しています。
度々お世話になりますが、どうぞよろしくお願いいたします。
（やまちゃん） 2014/05/19(月) 16:59
＞DATEVALUE(F1&"/"&E1&"/1")
E1セルは「営業日数」ですよね？
日付に何の関係もないと思うのですが、何か勘違いしていないですか？
（半平太） 2014/05/19(月) 22:06
ご指摘ありがとうございます。
数式を間違えて記載していまい申し訳ございません。
正しくは、
A B C D E 1 2014 年 5 月 2 日付 曜日 目標累計額 目標金額 営業日数 3 1日 火 125000 1000000 8 4 2日 水 定休日 5 3日 木 250000 6 4日 金 375000 7 5日 土 500000 8 6日 日 685000 9 7日 月 750000 10 8日 火 875000 11 9日 水 定休日 12 10日 木 1000000
【A列】=DATEVALUE(A1&"/"&C1&"/1")
【B列】=IF(MONTH($A$3)=MONTH($A3),TEXT(A3"aaa"),"")
です。
AND関数を入れたり試行錯誤しているのですが、難航しております。
度々申し訳ないのですが、再度ご教授頂けたら助かります。
どうぞよろしくお願いいたします。
（やまちゃん） 2014/05/19(月) 23:16
(1) A3セル =DATE(A$1,C$1,ROW(A1))
A30セルまでコピー
(2) A31セル =IF(EOMONTH(A$3,0)<DATE(A$1,C$1,ROW(A29)),"",DATE(A$1,C$1,ROW(A29))) A33セルまでコピー
(3) B3セル =TEXT(A3,"AAA") B33セルまでコピー
(4) C3セル =IF(A3="","",IF(B3="水","定休日",IF(G3="休み",G3,D$3/E$3*(1+COUNT(C$2:C2))))) C33セルまでコピー
(5) E3セル =COUNTIFS(B3:B33,"<>水",B3:B33,"?",G3:G33,"<>休み")
<結果図>
行 __A__ __B__ ____C____ ____D____ ____E____ _F_ ____G____ 1 2014 年 5 月 2 日付 曜日 目標金額 目標金額 営業日数 臨時休業 3 1日 木 休み 1,000,000 8 休み 4 2日 金 休み 休み 5 3日 土 125,000 6 4日 日 250,000 7 5日 月 休み 休み 8 6日 火 休み 休み 9 7日 水 定休日 10 8日 木 375,000 11 9日 金 500,000 12 10日 土 休み 休み 13 11日 日 休み 休み 14 12日 月 休み 休み 15 13日 火 休み 休み 16 14日 水 定休日 休み 17 15日 木 休み 休み 18 16日 金 625,000 19 17日 土 休み 休み 20 18日 日 休み 休み 21 19日 月 休み 休み 22 20日 火 休み 休み 23 21日 水 定休日 休み 24 22日 木 休み 休み 25 23日 金 750,000 26 24日 土 休み 休み 27 25日 日 休み 休み 28 26日 月 875,000 29 27日 火 休み 休み 30 28日 水 定休日 31 29日 木 休み 休み 32 30日 金 1,000,000 33 31日 土 休み 休み
（半平太） 2014/05/20(火) 00:14
ご教授ありがとうございました。
お教えいただいた通りに数式を入力していきましたら、
理想通りの表が完成しました。
分かりにくい説明にも関わらず、ご理解いただき、丁寧に回答いただき感謝しています。
本当にありがとうございました!!!
（やまちゃん） 2014/05/20(火) 17:08
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.