[[20150110151246]]　『商品列の入れ替え』（配送係）　ページの最後に飛ぶ

『商品列の入れ替え』（配送係）

	C列	D列	E列	F列	G列	H列	I列	J列	K列	L列
4行目	玉葱	ちぢみホウレン草	秋馬鈴薯	長芋	スナックエンド	キャベツ	トマト.	白  才	ペテトマト	蓮  根
5行目	ぶなしめじ	安納芋	味平南瓜	カット野菜	甘藷	サニーレタス	サワ―キャベツ	レタス	白葱	輸入アスパラ
6行目	舞茸	こだわり小松菜	グリーンリーフ	大  根	長茄子.	ほうれん草	くりゆたか南瓜	ミニ葱	ピーマン	黄金生姜
7行目	ブロツコリー	セルリー	ナメコ	黄爵馬鈴薯	小松菜	えりんぎ	胡瓜	人参	生椎茸（菌床）	赤美味ミニトマト
8行目	エノキ	カリフラワー	九条ねぎ	生椎茸（原木）	里芋	ミディートマト	水菜	金時甘藷	ブラウンマッシュ	マッシュル―ム
デコボコで見づらいのですがお願いします。
C列４行目からL列８行目まで商品名が並んでいます。
一列毎の商品の並びは変えずに入れ替えたいのですができるでしょうか?

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 どういう順番に並べ替えたいかの説明がありませんが、作業シートで一回行列入れ替えてから
 並べ替えて、再度、行列入れ替えではできないでしょうか。

http://shikaku.biglobe.ne.jp/pc_technic/excel/03_1.html

（Mook） 2015/01/10(土) 15:21

 VBA
　
 InputBoxが出現したら、全列の相対参照値（この場合C列が 1 D列が　2...)　を
 希望する順番にコンマで区切って入力。
 例：
 1,2,4,5,3,7,6,8,9,10,11

 Sub test()
    Dim x
    x = Split(InputBox("相対列順の入力" & vbLf & "例: 3,2,1,4,5"), ",")
    With Range("c4:l8")
        If UBound(x) <> .Columns.Count - 1 Then
            MsgBox "列数と入力値が合いません"
        Else
            .Value = Application.Index(.Value, Evaluate("row(1:" & .Rows.Count & ")"), x)
        End If
    End With
End Sub

（seiya） 2015/01/10(土) 15:45

 チョイ修正；参照列の説明 16:21

Mook様
事例が違っております。
seiya様
使い方が今ひとつ理解できません。
わたしの質問の仕方が悪いのでしょうか?
事例ではC列のC4からC8に以下の品名が入っています。
玉葱
ぶなしめじ
舞茸
ブロツコリー
エノキ
この商品がD列からL列のどこかに移動して他の商品列も移動させたいのです。
（配送係） 2015/01/10(土) 18:14

 入れ替え前と、入れ替え後の表を詳しく表示してもらえませんか？
（seiya） 2015/01/10(土) 18:51

 横から失礼します。

 「事例が違っております。」・・あまりにも【木で鼻をくくったような】レスですねぇ・・
 しかも、「事例はあってますよ！」

 以下の操作の場所については、実際に操作可能な領域に変更してください。

 １．C3:C8を選択して Ctrl/c
 ２．O1を選択して、形式を選択して貼り付け　の　行列を入れ替える　をチェックして実行
 ３．N1～N10　に　それぞれのデータの表示希望順を 1　～ 10 でいれる。
 ４．N1:S10 を選択して　N列で並び替え
 ５．並び替えられた O1:S10 を選択して Ctrl/c
 ６．C3 を選択して、形式を選択して貼り付け　の　行列を入れ替える　をチェックして実行

（β） 2015/01/10(土) 18:54

http://blog.livedoor.jp/itlifehack/archives/7217982.html

 とかでいいんじゃないですか。
（コナミ） 2015/01/10(土) 19:03

 2013なら以下の手順でも。

 １．C3:L3 に希望表示順をいれる
 ２．C3:L8 を選択して並び替え
 　　１）ユーザ設定の並び替え
 　　２）オプション
 　　３）列単位を選ぶ
 　　４）並び替え画面で、最優先されるキー　を　行3 にして実行

（β） 2015/01/10(土) 19:13

Mook様
失礼しました。

コナミ様
まさにコレです。

手作業でやるしか手はないということでしょうか。
（配送係） 2015/01/11(日) 18:06

 いや、βさんが列方向の並べ替えの手順を
 書いてくれてますよ。
 まずは書かれている通りにやってみては如何でしょうか？
（コナミ） 2015/01/11(日) 20:48

 こんばんは

 このような事でしょうか？

 標準モジュールに貼り付けてください。

 Const v As Long = 12
 Const 入れ替え順 As String = ",1,2,5,3,9,7,8,12,10,6,4,11"

 Sub 列の入れ替え()
   Application.ScreenUpdating = False
    Cells.Replace vbLf, ":"

    Dim 列(v) As Range
    Dim C入れ替え As Variant
    Dim i As Long

    For i = 1 To v
        Set 列(i) = Columns(i)
    Next

    C入れ替え = Split(入れ替え順, ",")

    For i = 1 To v
        If 列(C入れ替え(i)).Column <> i Then
           列(C入れ替え(i)).Cut
           Columns(i).Insert xlShiftToRight
        End If
    Next

 End Sub

（Ｇ999） 2015/01/13(火) 02:33

 3行目に並びの順番を数値で入力。

 B4～L8選択して列単位で昇順並び替え。
　
（GobGob） 2015/01/13(火) 07:55

β様　GobGob様
お礼が遅くなりすみませんでした。
このやり方で仕事をやっています。
ありがとうございました。
Ｇ999様
マクロなので便利ですが、私には改良できないので。。。。
Range("C3:L8")と並べ替えの範囲が指定出来ると嬉しいのですが。

（配送係） 2015/01/14(水) 21:24

 VBA処理案アップしましたが、いったん削除します。

（β） 2015/01/15(木) 07:59

 再掲します。
 実際のデータ領域の１行上に列希望順を 1 から入力しておき、その希望順行も含めて　★印の領域を既定してください。
 かなり手抜きをしていますし、また、たとえば 1,2,3 まで指定、そのほかは、現在の列順ということもできますが
 とりあえずは　すべての列の希望順をいれて試してみてください。

 Sub Test()
    Dim dic As Object
    Dim j As Long
    Dim Target As Range

    Set dic = CreateObject("Scripting.Dictionary")

    Set Target = Range("C3:L8")     '★

    For j = 1 To Target.Columns.Count
        dic(j) = ""
    Next

    For j = 1 To Target.Columns.Count
        dic(Target.Cells(1, j).Value) = Application.Transpose(Target.Columns(j).Value)
    Next

    Target.Value = Application.Transpose(dic.items)

 End Sub

（β） 2015/01/15(木) 08:40

 手抜きをしていた列希望順入力のチェックを加え、あわせて　希望順が指定されていない列については
 希望順指定の列の後ろに、現行列順でセットする部分を追加。ご参考まで。

 Sub Test2()
    Dim dic As Object
    Dim j As Long
    Dim Target As Range
    Dim x As Long
    Dim y As Long
    Dim z As Long
    Dim erFlag As Boolean
    Dim adr As String

    Set Target = Range("C3:L8")     '★

    '希望順行のチェック
    adr = Target.Rows(1).Address
    x = WorksheetFunction.CountA(Target.Rows(1))
    y = WorksheetFunction.CountBlank(Target.Rows(1))
    If x + y <> Target.Columns.Count Then erFlag = True
    If WorksheetFunction.Min(Target.Rows(1)) <> 1 Then erFlag = True
    If WorksheetFunction.Max(Target.Rows(1)) > x Then erFlag = True
    z = Evaluate("=SUM(IF(FREQUENCY(" & adr & "," & adr & ")>0,1))")
    If z <> x Then erFlag = True

    If erFlag Then
        MsgBox "希望順の指定が正しくありません"
        Exit Sub
    End If

    Set dic = CreateObject("Scripting.Dictionary")

    For j = 1 To Target.Columns.Count
        dic(j) = ""
    Next

    For j = 1 To Target.Columns.Count
        If Len(Target.Cells(1, j).Value) > 0 Then
            dic(Target.Cells(1, j).Value) = Application.Transpose(Target.Columns(j).Value)
        Else
            x = x + 1
            dic(x) = Application.Transpose(Target.Columns(j).Value)
        End If
    Next

    Target.Value = Application.Transpose(dic.items)

 End Sub

（β） 2015/01/15(木) 09:21

 結局最初のコードでいいんじゃないの？

   Sub test()
    Dim x
    x = Split(InputBox("相対列順の入力" & vbLf & "例: 3,2,1,4,5", , "3,1,2,4,5,6,7,8,9,10"), ",")
    With Range("c4:l8")
        If UBound(x) <> .Columns.Count - 1 Then
            MsgBox "列数と入力値が合いません"
        Else
            .Value = Application.Index(.Value, Evaluate("row(1:" & .Rows.Count & ")"), x)
        End If
    End With
End Sub
（seiya） 2015/01/15(木) 09:51

コメント返信：

[ 一覧(最新更新順) ]

[[20150110151246]] 『商品列の入れ替え』（配送係） ページの最後に飛ぶ

[[20150110151246]]　『商品列の入れ替え』（配送係）　ページの最後に飛ぶ