[[20150217231825]]　『VLOOKUPの応用？』（沙紀）　ページの最後に飛ぶ

『VLOOKUPの応用？』（沙紀）

Sheet1のA1(名前)→B1(AA)(順1～順3)でSheet2からSheet1のA4～D4までVLOOKUPで表示できるのですが、A1(年齢)→B1(20)に変更(順4～順6)してもSheet1のA4～D4に同じように表示することは可能でしょうか？よろしくお願いいたします。

順1 A1：ドロップアウトで名前～番号の名前を指定
順2 B1：ドロップアウトでAA～CCのAAを指定
順3 Sheet1のA4～D4にSheet2のA4～D4表示

順4 A1：ドロップアウトで名前～番号の年齢を指定
順5 B1：ドロップアウトで20～21の20を指定
順6 Sheet1のA4～D4にSheet2のA4～D4表示
※A1→B1は「名前の管理」で可能にしています。

Sheet1

	  A	 B	C	D
     1  名前	AA		
     1  年齢	20		
     2				
     3	名前	年齢   性別    番号
     4	 AA	 20	男      5

Sheet2

	  A	 B	 C	D
     1	名前    年齢   性別   番号
     2	 AA	 20     男	5
     3	 BB	 21	女	6
     4	 CC	 22	男	7

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 ドロップダウンのことかな？
 名前はともかく、年齢に重複はないのですか？

（Mook） 2015/02/17(火) 23:50

Mookさん

ごめんなさい。
ドロップダウンです。
年齢に重複はありません。
よろしくお願いいたします。
（沙紀） 2015/02/18(水) 00:13

 > A1：ドロップアウトで名前～番号の名前を指定

 名前～番号と書いてありますが、A1のリストから選択できるのは「名前」と「年齢」だけなんでしょうか？
「性別」も選択できるのなら絶対に重複しますよね？

 実際のデータがどんなものかわかりませんが、
 少なくともリストから選択できる項目に重複はないものだとして
 現在A1とB1に設定しているドロップダウンリストを、A1とA2に（つまり横→タテに）変更することは可能ですか？

	A	B	C	D
1	年齢　← リスト			
2	20　　← リスト		
3				
4	名前	年齢	性別	番号
5	AA	20	男	5
　
　
 可能なら

 A5: =IFERROR(DGET(Sheet2!$A$1:$D$4,A4,$A$1:$A$2),"")

 D5までコピー
　　
（JKT） 2015/02/18(水) 01:33

 どうもスマートな式がかけないですが、
 A5 =INDEX(Sheet2!$A$1:$D$100,MATCH($B$1,OFFSET(Sheet2!$A$1,0,MATCH($A$1,Sheet2!$A$1:$B$1,0)-1,100,1),0),COLUMN(A1))
 をD5までコピー。
（Mook） 2015/02/18(水) 11:50

 ■ DGET関数（データベース関数）を使う上での注意点

 文字列の検索は前方一致検索になります（Excel2002は例外らしいですが･･･）
 例えばSheet2のA列の名前に「中村沙紀」さんと「中村沙紀子」さんがいるとします。
 名前は姓だけしか入力していないのなら「森」さんと「森田」さんとかです。

 データとしては重複していませんが、「中村沙紀」で検索すると、
 前方一致検索では「中村沙紀子」も該当すると見なして、DGET関数だとエラーになります。

 もしそういうデータがあるのなら、以下のように DGET関数の条件を別セルにしてください。
　
　
	A	B	C	D	E	F
1	名前					名前
2	中村沙紀					=中村沙紀
3				
4	名前	年齢	性別	番号
5	中村沙紀	20	女	5
　
　　
 例としてF1:F2を使います。

 F1セルに　=A1
 F2セルに　="="&A2
 と入力します。

 この場合、ドロップダウンリストはタテ横どちらに並べてもかまいません。
 ただし、こちらの作業セルは必ずタテにします。

 A5: =IFERROR(DGET(Sheet2!$A$1:$D$4,A4,$F$1:$F$2),"")

 D5までコピー（条件を　$F$1:$F$2　にします）
　
　
 上記のことに留意すれば、質問の内容のことはDGET関数がうってつけだと思います（重複がなければ、ですが･･･）

 それでも一応別案を書いておけば（ドロップダウンリストはA1とB1だとして）

 A4: =INDEX(Sheet2!$A$2:$D$4,MATCH($B$1,INDEX(Sheet2!$A$2:$D$4,0,MATCH($A$1,Sheet2!$A$1:$D$1,0)),0),COLUMN(A1))

 D4までコピー
 ※エラー処理はしていません
 ※最後の COLUMN(A1) はA1セルのリストとは関係ありませんので、実際の配置がどこになっていようとも
 　そのままにしておいてください。
　
（JKT） 2015/02/18(水) 12:43

JKTさん、Mookさん
ご親切なアドバイスありがとうございます(•‾̑⌣‾̑•)
早速、試してみます(☼◡☼)

（沙紀） 2015/02/18(水) 22:00

 もう解決したのか、まだ試していないのか、その後の消息が不明ですね。

 A1のリストから選択できるのは「名前」と「年齢」だけなのか、他の項目も選択できるのか、
 そもそも実際のデータは本当にサンプルのような名簿的なものなのか、全く別のものなのか、
 ということもわかりません。

 一応書いておきますと、DGET関数の場合は、2回目の回答で書いたように、条件を別セルにしておいた方が無難です。

 また、別案ということで回答した式は　↓　に差し替えてください。

 A4: =INDEX(Sheet2!A2:A4,MATCH($B$1,INDEX(Sheet2!$A$2:$D$4,0,MATCH($A$1,Sheet2!$A$1:$D$1,0)),0))
　
（JKT） 2015/02/20(金) 13:00

コメント返信：

[ 一覧(最新更新順) ]

[[20150217231825]] 『VLOOKUPの応用？』（沙紀） ページの最後に飛ぶ

[[20150217231825]]　『VLOOKUPの応用？』（沙紀）　ページの最後に飛ぶ