[[20150429184557]]　『隣りのセルを抜き出したいです。』（スーザン）　ページの最後に飛ぶ

『隣りのセルを抜き出したいです。』（スーザン）

 特定の文字の隣を抜き出したいです。

 B　　　　　　　C　　　　D　　　　　　　E

 月	　　　　コード	担当		G1285
 1月10日	G1284	さくら		◆さくら
 4月29日	G1285	さくら		さくら
 1月1日　	G1286	ウィステリア	
 2月23日	G1287	ウィステリア			
 3月4日　	G1288	ウィステリア			
 4月1日　	G1285　 さくら			
 2月10日	G1290	さくら			
 4月29日	G1291	さくらんぼ			
 この下にずっと続きます．．．。

 E1が「G1285」ならE2：E3には	
◆さくら
さくら

 そして4月29日（今日）なら担当の前に◆のしるし
 このようなことが出来ますか？

 下にずっと続きますのでE2：E10に数式を入れておきたいと考えております。
 いままで6こ以上になったことはありませので。

 よろしくお願いします。

＜使用 Excel：Excel2010、使用 OS：WindowsXP ＞

 とりあえず
 F2=IF(COUNTIF(B:B,$E$1)>=ROW(A1),IF(INDEX(A:A,SMALL(INDEX(SUBSTITUTE((B:B=$E$1)*1,0,10^5)*ROW(B:B),),ROW(A1)))=TODAY(),"◆","")&INDEX(C:C,SMALL(INDEX(SUBSTITUTE((B:B=$E$1)*1,0,10^5)*ROW(B:B),),ROW(A1))),"")
 を必要数だけ、F3以降にコピーでどうでしょうか。

 E列に日付を出すなら、
 E2=IF(COUNTIF(B:B,$E$1)>=ROW(A1),INDEX(A:A,SMALL(INDEX(SUBSTITUTE((B:B=$E$1)*1,0,10^5)*ROW(B:B),),ROW(A1))),"")
 で書式は日付で。
（Mook） 2015/04/29(水) 20:00

 データ数がある程度決まっているなら、列丸ごとより最大行数を指定した式の方が早そうです。
 例えば、最大 100行なら B:B を B$1:$100 へ変更。他の列も同じ範囲で。
（Mook） 2015/04/29(水) 20:04

 カバ丸、参上！

 E2　=IFERROR(INDEX(REPT("◆",$B$1:$B$100=TODAY())&$D$1:$D$100,SMALL(INDEX(($C$1:$C$100<>$E$1)*100+ROW($C$1:$C$100),0),ROW(A1))),"")

 E10までフィルコピー

 範囲を変更する場合は「100」を実際の表に合わせてくれい。
 ($C$1:$C$100<>$E$1)*100　← この「100」も忘れずに！

 参考にしてくれい。では！ε=ε=ε= ﾍ(*¨)ﾉ
　
（カバ丸） 2015/04/29(水) 20:59

Mookさん
カバ丸さん
こんばんは
ありがとうございました。
なんかとっても助かってます。
明日が楽しみです。

（スーザン） 2015/04/29(水) 23:02

コメント返信：

[ 一覧(最新更新順) ]

[[20150429184557]] 『隣りのセルを抜き出したいです。』（スーザン） ページの最後に飛ぶ

[[20150429184557]]　『隣りのセルを抜き出したいです。』（スーザン）　ページの最後に飛ぶ