[[20151111141217]]　『車検満了日を日付から求めたい』（にくじゃがこ）　ページの最後に飛ぶ

『車検満了日を日付から求めたい』（にくじゃがこ）

どなたかお知恵をお貸しください。

EXCELで以下のような事がやりたいのですが上手くいきません。

自動的に車検満了日を求める式を作りたいです。

例＞

登録番号　　　300
取得日　　　　 2012/10/10
今日の日付　　2015/11/10

車検満了日は、登録番号が300だった場合は、
初年度は3年後になるので 2015/10/10
2回目目以降は2年おきなのでその次の車検は2017/10/10としたいのです。

今日の日付をみて、過去の日付にならないようにしたいです。
つまり今日の日付が2015/11/10だとすると、車検満了日には 2017/10/10と自動的に
計算されると正しいです。

複雑で、説明が下手ですみませんが宜しくお願いします。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 ＞車検満了日は、登録番号が300だった場合は、 
 ＞初年度は3年後になるので 2015/10/10

 それ(つまり300）以外の登録番号だったら、また別の年数になるんですか？

 条件は、初めに全て書き出してください。(後出ししないようにお願いします）

（半平太） 2015/11/11(水) 14:59

ありがとうございます。

条件ですが、おっしゃるとおりまだあります。
400および100であれば、すべて1年おき、800であればすべて2年おきになります。

どうぞ宜しくお願いいたします。
（にくじゃがこ） 2015/11/11(水) 15:15

 B3セル =IFERROR(LOOKUP(TODAY()-(DAY(B$2)=DAY(TODAY())),EDATE(B$2,(ROW($R$1:$R$20)*(1+OR(B$1={300,800}))+(B$1=300))*12),EDATE(B$2,(ROW($R$2:$R$21)*(1+OR(B$1={300,800}))+(B$1=300))*12)),EDATE(B$2,IF(B$1=300,36,IF(B$1=800,24,12))))
 右にコピー

 <結果図>
  行  ____A____  _____B_____  _____C_____  _____D_____  _____E_____
   1  登録番号          300          800          100          400 
   2  取得日     2012/10/10   2012/10/10   2012/10/10   2012/10/10 
   3  車検日     2017/10/10   2016/10/10   2016/10/10   2016/10/10

（半平太） 2015/11/11(水) 16:25

 車検満了て、登録日＋α年の「前日」まで。
 じゃなかったっけ？
　
（GobGob） 2015/11/11(水) 16:36

B1 = 登録番号
B2 = 取得日
B3 = 今日の日付

=IF(B1=300,DATE(YEAR(B2)+IF(DATEDIF(B2,B3,"Y")<3,3,INT((DATEDIF(B2,B3,"Y")+1)/2)*2+1),MONTH(B2),DAY(B2)),IF(B1=800,DATE(YEAR(B2)+(INT(DATEDIF(B2,B3,"Y")/2)+1)*2,MONTH(B2),DAY(B2)),IF(OR(B1=100,B1=400),DATE(YEAR(B2)+DATEDIF(B2,B3,"Y")+1,MONTH(B2),DAY(B2)),"")))

なお今日が車検満了日の場合は､次回満了日を表示する｡

（mm） 2015/11/11(水) 16:49

軽自動車は無いの？
（ａｂｃ） 2015/11/11(水) 17:03

	A	B	C	D	E	F	G	H	I
1	登録	100	200	300	400	500	600	700	800
2	取得	121010	121010	121010	121010	121010	121010	121010	121010
3	今日	151110	151110	151110	151110	151110	151110	151110	151110
4	車検日	161010	161010	171010	161010	171010	161010	171010	171010

 とりあえず。（8ナンバーはスレから。）
 1,2,4,6 ナンバー は 初回2年、次回から1年 3,5,7,8ナンバーは 初回3年、次回から2年。
 として。

 B4 =LOOKUP(B3,EDATE(B2,12*(MID(11212122,LEFT(B1),1)*ROW(A$1:A$15)+1)),EDATE(B2,12*(MID(11212122,LEFT(B1),1)*ROW(A$2:A$16)+1)))
 右へコピー。

 ※例表はyymmdd表記
　
（GobGob） 2015/11/11(水) 17:13

 ありゃ。だめだね。。。。
 見直しますわ。。。。
　
（GobGob） 2015/11/11(水) 17:19

 どのくらいの正確性を求めていますか? お遊びで

 =LOOKUP(TODAY()+365*(1+OR(B1={300,800})+AND(B1=300,TODAY()-B2<365)),((YEAR(B2)+(B1=300)+ROW(1:10)*(1+OR(B1={300,800})))&"/"&TEXT(B2,"m/d"))-1)

 当日が、車検日の前後でずれる場合があります

 10年後以降は車検は1年ごとになりませんか?
 車検日が2012/2/29の場合　どの様になればいいのでしょうか?

（AAA） 2015/11/11(水) 19:30

 「10年目以降の1年毎」は1995年に改正されて2年毎になりませんでしたっけ？
（稲葉） 2015/11/12(木) 08:40

 B4 =EDATE(B2,12*INDEX(IF(OR(LEFT(B1)*1={3,5,7,8}),{3,3,3,5,5,7,7,9,9,11,11,13,13,15,15},{2,2,3,4,5,6,7,8,9,10,11,12,13,14,15}),ROUNDUP(SUM(DATEDIF(B2,B3,{"y","yd"})*{1,0.01}),0)))
　
（GobGob） 2015/11/12(木) 16:19

コメント返信：

[ 一覧(最新更新順) ]

[[20151111141217]] 『車検満了日を日付から求めたい』（にくじゃがこ） ページの最後に飛ぶ

[[20151111141217]]　『車検満了日を日付から求めたい』（にくじゃがこ）　ページの最後に飛ぶ