[[20160215115351]]　『グラフのＸ・Ｙ軸を自動で調整したい』（あこ）　ページの最後に飛ぶ

『グラフのＸ・Ｙ軸を自動で調整したい』（あこ）

２つの散布図が存在するシートがあります。データ数は２つです。
一つ目のグラフはＸとＹ軸を自動で調整したいです。Ｘ軸は0～1の範囲、Ｙは0～5の範囲なのですが、まれに数値が1を超えてしまうことがあり、現在軸の書式設定で毎回最大値を変更しているのですが、この作業を自動でおこないたいのです。

数値を入力するセルは、データ１▲（データの表示の種類）、Ｙ軸　Ｌ64、Ｘ軸　Ｏ64
データ2●　Ｙ軸　Ｌ65　Ｘ軸　Ｏ65　です。

このセルの値が変更したら一つ目のグラフ軸が変更されてほしいのです。

またもうひとつグラフがあり、これについてはＸ軸のみ最大値を変更　Ｘ軸　▲Ｓ64　●Ｓ65

マクロ初心者でして実行の方法も理解しておりません。
手順を最初から教えていただければ幸いです。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

こういうことでしょうか

 １）グラフがあるシートの「シート見出し」を右クリック
 ２）「コードの表示」を選択
 ３）下記のマクロをコピペ　（★グラフ名は修正が必要です）
 ４）Alt+Q

 これでデータが変わると軸の最大値が自動で変化すると思います

 Private Sub Worksheet_Change(ByVal Target As Range)
    Dim cht1 As Chart, cht2 As Chart
    Dim cht1X As Range, cht1Y As Range
    Dim cht2X As Range

    Set cht1 = ChartObjects("グラフ 1").Chart   '★実際のグラフ名に修正
    Set cht1X = Range("O64:O65")
    Set cht1Y = Range("L64:L65")

    Set cht2 = ChartObjects("グラフ 2").Chart   '★実際のグラフ名に修正
    Set cht2X = Range("S64:S65")

    If Not Intersect(Target, cht1X) Is Nothing Then
        If WorksheetFunction.Max(cht1X) > 1 Then
            cht1.Axes(xlCategory).MaximumScaleIsAuto = True
        Else
            cht1.Axes(xlCategory).MaximumScale = 1
        End If
    End If

    If Not Intersect(Target, cht1Y) Is Nothing Then
        If WorksheetFunction.Max(cht1Y) > 5 Then
            cht1.Axes(xlValue).MaximumScaleIsAuto = True
        Else
            cht1.Axes(xlValue).MaximumScale = 5
        End If
    End If

    If Not Intersect(Target, cht2X) Is Nothing Then
        If WorksheetFunction.Max(cht2X) > 1 Then
            cht2.Axes(xlCategory).MaximumScaleIsAuto = True
        Else
            cht2.Axes(xlCategory).MaximumScale = 1
        End If
    End If

 End Sub

（マナ） 2016/02/15(月) 20:11

コメント返信：

[ 一覧(最新更新順) ]

[[20160215115351]] 『グラフのＸ・Ｙ軸を自動で調整したい』（あこ） ページの最後に飛ぶ

[[20160215115351]]　『グラフのＸ・Ｙ軸を自動で調整したい』（あこ）　ページの最後に飛ぶ