[[20160630141226]]　『エクセルテンプレート「学生向け課題計画表」につ』（ＴＫＬ）　ページの最後に飛ぶ

『エクセルテンプレート「学生向け課題計画表」について』（ＴＫＬ）

Excel2013を使用しています。

その中に「学生向け課題計画表」というテンプレートがあります。
「週単位で表示」シート内に、「課題」シートで入力した情報を
表示させたいのですが同じ期日の課題が複数ある場合、
どのような関数を使えば表示させることができますか。

初期状態では
=IF(LEN(D14)=0,"",IF(COUNTIF(課題[期日],DATE(WkYear,WkMonthNum,D14))>0,"課題の期限です!",""))
といった関数が入っており、「課題の期限です！」としか表示されません。
15行目から29行目まで「課題」シートの課題名を表示させたいです。

下らない質問とは存じますが、ご教示ください。
よろしくお願いいたします。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 レイアウトとサンプルデータを示すことは出来ませんか？

 ※ 課題名は、課題１、課題２、・・・、なんてーので構わないです。

（半平太） 2016/06/30(木) 15:57

コメントいただき、ありがとうございます。

シート名「課題」
　　　Ａ　　　　　　　　　Ｂ
１　課題 1 　　2016年 5月29日
２　課題 2 　　2016年 5月29日
３　課題 3 　　2016年 5月31日
４　課題 4 　　2016年 5月31日
５　課題 5 　　2016年 5月31日

シート名「週単位で表示」
　　　　　Ｂ　　　Ｃ　　　　Ｄ
14　　　29日　　　30日　　 31日
15　　課題１　　　　　　　課題３
16　　課題２　　　　　　　課題４
17　　　　　　　　　　　　課題５
18
19
20
21
22
23
24
25
26
27
28
29

レイアウトとしてはこのような形で、
同日、複数ある予定でも14～15行目に表示されるようになればと考えています。
複数条件の区別ができず困っています。

（ＴＫＬ） 2016/06/30(木) 16:10

 専門家さんから通常数式での回答があると思いますし、なんとなくピボットのようなものでも
 できるのかもしれませんが、馬鹿の一つ覚えで。

 週単位で表示 シートの　B15 に

 =IF(B$14="","",IFERROR(INDEX(課題!$A$1:$A$1000,SMALL(IF(課題!$B$1:B$1000=B$14,ROW(A$1:A$1000)),ROW(A1))),""))

 これを　Ctrl/SHift/Enter で配列数式として入力して、下に、右に　フィルコピー　とか。

（β） 2016/06/30(木) 16:27

 ↑　週単位で表示 シート　の　14行目の日付は　【日付型】であることが前提です。

（β） 2016/06/30(木) 16:29

コメントありがとうございます。
14行目の日付は【標準】で、
=INDEX(WkMonthView,WkWeek,COLUMN(B$1))という形で日付が変動するものです。

（ＴＫＬ） 2016/06/30(木) 16:44

 B15セル =IF(LEN(B$14)=0,"",IFERROR(INDEX(課題[課題],AGGREGATE(15,6,ROW(課題[期日])/(課題[期日]=DATE(WkYear,WkMonthNum,B$14)),ROW($Z1))-1),""))

 その数式を右へ、下へフィルコピー。

 ＜週単位で表示＞シート結果図
  行  ___B___  _C_  ___D___  _E_
   1

  14      29    30      31      
  15  課題 1        課題 3      
  16  課題 2        課題 4      
  17                課題 5      
  18                            
  19

 <課題＞シート　テーブルサンプル
 行  ___A___  ____B____
  1  課題     期日     
  2  課題 1   2016/5/29
  3  課題 2   2016/5/29
  4  課題 3   2016/5/31
  5  課題 4   2016/5/31
  6  課題 5   2016/5/31
  7                    
（半平太） 2016/06/30(木) 16:55

皆様ありがとうございます。
無事に表示することができました。

本当にありがとうございました。
（ＴＫＬ） 2016/06/30(木) 17:43

コメント返信：

[ 一覧(最新更新順) ]

[[20160630141226]] 『エクセルテンプレート「学生向け課題計画表」につ』（ＴＫＬ） ページの最後に飛ぶ

[[20160630141226]]　『エクセルテンプレート「学生向け課題計画表」につ』（ＴＫＬ）　ページの最後に飛ぶ