[[20170119151755]]　『オートフィルタ　文字列　カウント』（yuu）　ページの最後に飛ぶ

『オートフィルタ　文字列　カウント』（yuu）

 　　Ａ　　　Ｂ　　　Ｃ　　　Ｄ　　　Ｅ
 １　
 ２　地域　　　　　　　　　　　　　　企業名
 ３　ア　　　　　　　　　　　　　　　α会社
 ４　ア　　　　　　　　　　　　　　　α会社
 ５　ア　　　　　　　　　　　　　　　β会社
 ６　イ　　　　　　　　　　　　　　　σ会社
 ７　イ　　　　　　　　　　　　　　　σ会社
 ８　ウ　　　　　　　　　　　　　　　γ会社
 ９
 ・
 ・
 ・

 といった形であり、E1に
 =SUMPRODUCT((E3:E250<>"")/COUNTIF(E3:E250,E3:E250&""))
 という関数を入れて企業数をカウントしています。
 オートフィルタで地域を指定して表示されているだけの企業数をカウントさせるためにはどのようにすればよいのでしょうか？

＜使用 Excel：unknown、使用 OS：unknown ＞

 =SUMPRODUCT(SUBTOTAL(3,INDIRECT("A"&ROW(3:250)))*((E3:E250<>"")/COUNTIF(E3:E250,E3:E250&"")))
 でいかが？
（bi） 2017/01/19(木) 15:40

 これ、一つの企業が複数の地域に存在することはあるのだろうか？
（ねむねむ） 2017/01/19(木) 15:50

 ねむねむさんの懸案に対応。

 =COUNT(INDEX(0/(MATCH(REPT(E3:E250&"",SUBTOTAL(3,INDIRECT("E"&ROW(E3:E250)))),E3:E250,0)=ROW(A1:A248)),0))
　
（GobGob） 2017/01/19(木) 16:08

 おー。不十分ｗ。

 上記回答は却下でｗ。
　
（GobGob） 2017/01/19(木) 16:13

 一応こんなのを考えてみた。

 =COUNT(0/FREQUENCY(IFERROR(MATCH(E3:E250,IF(SUBTOTAL(3,INDIRECT("E"&ROW(3:250))),E3:E250,""),0),""),ROW(1:250)))
 ShiftキーとCtrlキーを押しながらEnterキーで式を確定（確定後、式が{}で囲まれればOK）
 なお、最後の
 ROW(1:250)
 部分は必ず1からとしてくれ。
（ねむねむ） 2017/01/19(木) 16:15

 =COUNT(INDEX(0/(MATCH(E3:E250,INDEX(REPT(E3:E250,SUBTOTAL(3,INDIRECT("E"&ROW(E3:E250)))),0),0)*SUBTOTAL(3,INDIRECT("E"&ROW(E3:E250)))=ROW(A1:A298)),0))

 ※ダラダラ案ｗ
　
（GobGob） 2017/01/19(木) 16:22

 みなさん、素早いご指導ありがとうございます。
 非常に助かりました。ありがとうございます。
（yuu） 2017/01/19(木) 17:18

コメント返信：

[ 一覧(最新更新順) ]

[[20170119151755]] 『オートフィルタ 文字列 カウント』（yuu） ページの最後に飛ぶ

[[20170119151755]]　『オートフィルタ　文字列　カウント』（yuu）　ページの最後に飛ぶ