[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『タイマー等で指定時間前にメッセージを出したい』（ayumi）
毎日、同じ時間(時間指定)に実施しなくてはならない作業が4つありまして、作業の忘れ防止の為、それぞれの指定した時刻の1時間前になるとメッセージ等で知らせてくれる、なにか良い方法はありませんか？
タイマーやカウントダウンで検索した所、沢山出てきまして、なにが良いのかわかりませんでした。VBAは素人なもんで。
イメージ的には、それぞれの作業のボタンか何か作っておき、それをクリックしたら、タイマーが働き、例えば、指定時間(期限)が18:10なら17:10になるとメッセージで知らせてくれる。
?@作業の指定時間09:20分 ?A作業の指定時間11:30分 ?B作業の指定時間18:10分 ?C作業の指定時間19:30分
の4回です。
説明が不十分かも知れませんが、宜しくご教授をお願い致します。
＜ 使用 Excel：Excel2010、使用 OS：Windows7 ＞
テクニックのみを考えるということであれば、仮にその時点でセルの編集中でも強制的に割り込んで メッセージを出す APIのSetTimer/KillTImer が考えられます。
ただ・・・・目的は？ 指定時刻にリマインドメッセージを出すんですよね？
そのメッセージに気づくためには、ずっと、そのPCの前にいなければいけませんね。 その時刻に中座してはいけない。コーヒーを飲みに行くこともできませんし、トイレ休憩もだめ？
そういう流れというか運用って現実的ですか？
私ならスマホのアラームをセットしておきますね。 そうすれば、PCの前から席を外しても、その時刻になれば気づかせてくれますから？
なぜ、マクロでメッセージを出したいのですか？
（β） 2017/01/24(火) 21:46
早々のご返事有難うございます。
そうですね。確かにスマホのアラーム機能で良いのかも知れません。
私の業務は作業のコントローラーとして、作業者に作業指示を出しています。
毎日３人でパソコンに向かいパソコンを見ながら作業の進捗等を管理しています。
日々膨大の作業の中で、時間指定の作業が少しあるのですが、作業者が、つい時間を忘れてしまい、時間指定の作業に送れる事象が数回あり、私達コントローラーもつい忘れる事があったので、時間になったら、作業者に、そろそろ時間だよって連絡ができるのが目的です。
どうしてもメッセージを出すことにはこだわっていません。
現在、何か対策を考えている最中に、メッセージかアラームかで知らせてくれれば、と思いました。
（ayumi） 2017/01/25(水) 00:07
PC上で何か仕掛けを準備するとして、SetTimer/KillTimerで実行予約をしておくのもありですけど Windowsのタスクスケジュールを利用するのが簡単で確実かもしれません。
『windows 指定時刻にメッセージ』あたりで検索してみてください。 いろいろでてきますが、以下の記事が VBS利用ですけどわかりやすいと思います。
http://okguide.okwave.jp/guides/60950
追伸：VBSファイルはメモ帳にコードを書いて、拡張子を .vbs にして保存して作成します。
（β） 2017/01/25(水) 06:09
まず、シートは以下のようにレイアウトしてください。
A B C D 1 開始時刻 終了時刻 待ち(分) メッセージ 2 09:20 09:30 10 3 11:30 11:40 10
A:B列は、セルの書式設定で、表示形式を [hh]:mm;@ として、常に00:00形式で表示するようにしてください。
以下のマクロは、貼る場所が3箇所ありますので、注意。
[シートモジュール]
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Target.Count <> 1 Then Exit Sub
If Target.Row < 2 Then Exit Sub
Target.Value = Format(Now, "HH:NN")
Cancel = True
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
Dim R As Range
If Target.Column <> 1 Then Exit Sub
Application.EnableEvents = False
For Each R In Target
If R.Column = 1 Then
R.Offset(0, 1).Value = DateAdd("n", R.Offset(0, 2).Value, R.Value)
End If
Next R
Application.EnableEvents = True
End Sub
[ThisWorkBook]
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Call sStopTimer
End Sub
Private Sub Workbook_Open()
dNext = Now
Call sSetTimer
End Sub
[標準モジュール] Public dNext As Date
Public Sub sSetTimer()
Dim i As Long
Dim cNow As String
cNow = Format(dNext, "HH:NN")
If Application.StatusBar <> cNow Then
Application.StatusBar = cNow
End If
dNext = dNext + TimeValue("00:00:10")
Application.OnTime dNext, "sSetTimer"
With Sheets(1)
For i = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
If .Cells(i, "A").Text <= cNow And cNow <= .Cells(i, "B").Text Then
With .Range(.Cells(i, "A"), .Cells(i, "D"))
If .Interior.Color <> RGB(255, 128, 128) Then
.Interior.Color = RGB(255, 128, 128)
End If
End With
Else
With .Range(.Cells(i, "A"), .Cells(i, "D"))
If .Interior.ColorIndex <> xlNone Then
.Interior.ColorIndex = xlNone
End If
End With
End If
Next i
End With
End Sub
Public Sub sStopTimer()
If dNext <> 0 Then
Application.OnTime dNext, "sSetTimer", , False
dNext = 0
End If
Application.StatusBar = ""
End Sub
ブックを開くか、Workbook_Openを実行すると、周期チェックを開始します。周期チェック中は、ステータスバーに時刻が表示されます。
A列を右クリックすると、現在時間を代入します。開始時刻を変更すると、待ち時間分加算した終了時刻を自動代入します。
ブックを閉じるか、sStopTimerを実行すると、チェックを止めます。
汎用的に書いたので、クッキングタイマーや充填時間待ちタイマなんかにも使用できそうですね。
（???） 2017/01/25(水) 12:21
有難うございます。
Windowsのタスクスケジュール使用の方法、初めて知りました。
実際にやってみました。なるほどです。
大変勉強になりました。
???様
ご教授有難うございます。
実際にやってみました。凄いです。
別セルに時間指定の時刻を入れて、後は、時間に引き算で待ち時間を出すことで
十分使用できます。
セルに色が着く事で、タイマーが動いている事が分かるのですが、
設定時間になったら、色が別の色に変わる事は可能でしょうか？
（ayumi） 2017/01/25(水) 21:09
目的に合いそうなフリーソフトです。■Free Alarm Clock http://www.vector.co.jp/soft/dl/winnt/personal/se505521.html
指定時刻ではありませんが、 今から６０分後にアラーム、そんな使い方をしたいなら ■ミニタイマー http://www.vector.co.jp/soft/win95/personal/se401253.html （マリオ） 2017/01/26(木) 09:20
なお、日替わり時は大小が逆転しますが、0時付近で使うことがなければ、このままで問題ないかと思います。
（???） 2017/01/26(木) 09:35
有難うございます。
フリーソフト、実際にダウンロードして試してみました。
知らせて欲しい時間を数種類設定して、「毎日」にしておけばアラームで知らせてくれて非常に便利だし、このまま使えますね。
???様
お世話になっています。そして、何度もすみません。
あまり大幅なコード変更はできませんが、別のセルにn分前の時間がでるようにして、やってみました。
しかし、その後の設定時間になると、違う色になるようなコードが分かりませんでした。
表はAをB始まりにして、Iの所に=TIME(HOUR(C2), MINUTE(C2)-10,SECOND(C2))を入れました。
これで、n分前で色は消え白になります。
下の、この部分だけ追加してもダメでした。すもませんが、もう少し詳しく、ご教授下さい。
If .Cells(i, "B").Text <= cNow And cNow <= .Cells(i, "I").Text Then
With .Range(.Cells(i, "B"), .Cells(i, "E"))
If .Interior.Color <> RGB(255, 128, 0) Then
.Interior.Color = RGB(255, 128, 0)
End If
これが現在のコードです。
[シートモジュール]
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Target.Count <> 1 Then Exit Sub
If Target.Row < 2 Then Exit Sub
Target.Value = Format(Now, "HH:NN")
Cancel = True
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
Dim R As Range
If Target.Column <> 2 Then Exit Sub
Application.EnableEvents = False
For Each R In Target
If R.Column = 2 Then
R.Offset(0, 1).Value = DateAdd("n", R.Offset(0, 2).Value, R.Value)
End If
Next R
Application.EnableEvents = True
End Sub
[This Workbook]
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Call sStopTimer
End Sub
Private Sub Workbook_Open()
dNext = Now
Call sSetTimer
End Sub
[標準モジュール]
Public dNext As Date
Public Sub sSetTimer()
Dim i As Long
Dim K As Long
Dim cNow As String
cNow = Format(dNext, "HH:NN")
If Application.StatusBar <> cNow Then
Application.StatusBar = cNow
End If
dNext = dNext + TimeValue("00:00:10")
Application.OnTime dNext, "sSetTimer"
With Sheets(1)
For i = 1 To .Cells(.Rows.Count, "B").End(xlUp).Row
If .Cells(i, "B").Text <= cNow And cNow <= .Cells(i, "I").Text Then
With .Range(.Cells(i, "B"), .Cells(i, "E"))
If .Interior.Color <> RGB(255, 128, 0) Then
.Interior.Color = RGB(255, 128, 0)
End If
For K = 1 To .Cells(.Rows.Count, "B").End(xlUp).Row
If .Cells(K, "B").Text <= cNow And cNow <= .Cells(K, "I").Text Then
With .Range(.Cells(K, "B"), .Cells(K, "E"))
If .Interior.Color <> RGB(255, 128, 128) Then
.Interior.Color = RGB(255, 128, 128)
End If
End With
Else
With .Range(.Cells(i, "B"), .Cells(i, "E"))
If .Interior.ColorIndex <> xlNone Then
.Interior.ColorIndex = xlNone
End If
End With
End If
Next i
Next K
End With
End Sub
Public Sub sStopTimer()
If dNext <> 0 Then
Application.OnTime dNext, "sSetTimer", , False
dNext = 0
End If
Application.StatusBar = ""
End Sub
（ayumi） 2017/01/26(木) 14:29
Public Sub sSetTimer()
Dim i As Long
Dim cNow As String
cNow = Format(dNext, "HH:NN")
If Application.StatusBar <> cNow Then
Application.StatusBar = cNow
End If
dNext = dNext + TimeValue("00:00:10")
Application.OnTime dNext, "sSetTimer"
With Sheets(1)
For i = 2 To .Cells(.Rows.Count, "B").End(xlUp).Row
If .Cells(i, "B").Text <= cNow And cNow <= .Cells(i, "C").Text Then
With .Range(.Cells(i, "B"), .Cells(i, "E"))
If .Interior.Color <> RGB(255, 192, 192) Then
.Interior.Color = RGB(255, 192, 192)
End If
End With
ElseIf .Cells(i, "I").Text <= cNow And cNow <= .Cells(i, "C").Text Then
With .Range(.Cells(i, "B"), .Cells(i, "E"))
If .Interior.Color <> RGB(255, 128, 128) Then
.Interior.Color = RGB(255, 128, 128)
End If
End With
Else
With .Range(.Cells(i, "B"), .Cells(i, "E"))
If .Interior.ColorIndex <> xlNone Then
.Interior.ColorIndex = xlNone
End If
End With
End If
Next i
End With
End Sub
（???） 2017/01/26(木) 15:07
ご教授有難うございました。
わかりました。ElseIfでした。
これで、問題解決しました。
これで、部分的にSHEETの保護をかかようと思いまして下記コードを
シートモジュールに入れてみましたが、エラーとなってしまいました。
良い方法をご教授願います。
Private Sub Worksheet_Activate()
If ActiveSheet.ProtectContents = False Then
Cells.Locked = True
ActiveSheet.Range("B2:B5,D2:E5,H2:H5").Locked = False
End If
End Sub
（ayumi） 2017/01/26(木) 17:41
それと、コードの内容はセルのロックを解除しているだけであり、保護は掛けていませんね。Protect と UnProtect が必要です。
また、Protect していると、人間が触れないのと同様、マクロでもロックされたセルを触れなくなりますから、マクロでは UnProtect してから処理し、終わった後に Protect し直す、という処理になります。
（???） 2017/01/26(木) 17:58
ファイル置いておきます。エクセルVBAで作成したアラーム時計です。 エクセルアラーム2.zip (ファイルは削除しました)
なぜか、WSH.Popupが、5秒後に閉じません。 下記のｺｰﾄﾞだけだと閉じるのですが…。 Application.OnTimeを使用していると、妨害を受けるのでしょうか？
Sub test1()
Dim WSH
Set WSH = CreateObject("WScript.Shell")
WSH.Popup "5秒後、自動的に閉じます", 5, "確認", vbSystemModal
Set WSH = Nothing
End Sub
（マリオ） 2017/01/26(木) 19:04
ご教授有難うございます。
実行時エラーは、下記のコードで出ないようになりました。
Private Sub Worksheet_Activate()
If ActiveSheet.ProtectContents = False Then
Cells.Locked = True
ActiveSheet.Range("B2:B5,D2:E5").Locked = False
ActiveSheet.Protect Password:="7082", UserInterfaceOnly:=True
End If
End Sub
マリオ様
有難うございました。
早速ダウンロードさせて頂きました。
使い易く、即使えそうでした。
ただ、サウンドの鳴らし方が、よくわかりませんでした。
（ayumi） 2017/01/26(木) 22:07
スレお借りします。
To マリオさん
>>下記のｺｰﾄﾞだけだと閉じるのですが…。
手元に様々な便利コードをストックしたマクロブックがありまして、自前のものもありますけど エキスパートさんたちがＨＰなどで発表されているコードも参考部品として、数多くストックしています。
その中に、一定時間のメッセージ表示をテーマにしたものがあって、マリオさんがレスされた WSH版もあります。 （確か田中さんのサイトからいただいたと記憶しています）
懐かしくなって、久々にそのストック部品を動かしましたら、５秒後に消えません。（というか、いつまでたっても消えません） Win10(64Bit)+xl2013(32Bit)です。
で、同じコードを Win7(64Bit)+xl2010(32Bit)で動かしますと、ちゃんと消えます。
マリオさんのところでは、同じWin10(64Bit)+xl2013(32Bit) で、このコードで、5秒後に消えるんですね？ 当方の実行時、セルが編集状態でもないですし、MsgBoxもアクティブですので・・不思議です。
で、Win10(64Bit)+xl2013(32Bit) でも、k窓で紹介されている方式だと、ちゃんと消えます。 k窓、現在は昔のコンテンツがばっさりと消えているんですが、以前、お願いして古いもののアーカイブを 提供してもらっています。
http://www2.aqua-r.tepm.jp/~hironobu/kvba.htm
ここの E00M087 の kTimeOutDialog関数 を MsgBox と組み合わせて処理しているコードです。
ご参考まで。
（β） 2017/01/26(木) 23:23
お世話になっています。
昨日、ダウンロードしてアラームを起動させたまま普通にExcelで仕事をしながら、試していたら、いくつかの
Excelを開いているとエラーが出ました。
エラーの内容は「msg表示が出来ません。このブックのマクロが使用できないか、マクロが無効になっている可能性があります」とでました。
何故だかよくわからないのですが、何もvbs等を使用していないExcelを開いている時は、普通にmsgが出るのに、vbsを使っているExcelを開いている時は、エラーが出るみたいです。
デバックを見ると、
Sub Alarm時刻で並び替え()
Dim fr As Integer
fr = Range("A" & Rows.Count).End(xlUp).Row
With Sheets("Sheet1").Sort
.SortFields.Clear
.SortFields.Add Key:=Range("B3"), Order:=xlAscending
.SetRange Range("A3:E" & fr)
.Header = xlNo
.Apply
End With
End Sub
上記のコードの中の、
With Sheets("Sheet1").Sort
この部分が黄色になっていました。
どうしてでしょうか？
すみません、ご教授下さい。
（ayumi） 2017/01/27(金) 20:13
>ayumi さん >ただ、サウンドの鳴らし方が、よくわかりませんでした。 Excel_Alarm.xlsがあるフォルダ内に、alarm.wavがあれば サウンド鳴りますよ。
>vbs等を使用していないExcel VBA(Visual Basic for Applications)を使用していないExcelですね VBS（Visual Basic Script）は、拡張子vbsのファイルですよ
>エラーが出るみたいです。 「ThisWorkbook」と「ActiveWorkbook」は違うので、 エラーが出る場合があります。 シートを指定していないと、ActiveWorkbookとして、扱われます。 「ThisWorkbook」はマクロを実行している拡張子（xlsまたはxlsm）のエクセルﾌﾞｯｸのことです。 「ActiveWorkbook」は、現在アクティブになっているエクセルのファイルで、 「ActiveWorkbook」が「ThisWorkbook」とイコールのときもあれば、 違うこともあります。 「ActiveWorkbook」は、拡張子が（xlsx,xls,xlsm）の エクセルファイルです。
With Sheets("Sheet1").Sort
のところは、
With ThisWorkbook.Sheets("Sheet1").Sort
であるべきでした。「sh」で表現すると、こうなります。
*****************************************************************
Sub Alarm時刻で並び替え()
Dim sh As Worksheet
Set sh = ThisWorkbook.Sheets("Sheet1")
Dim fr As Integer
fr = sh.Range("A" & Rows.Count).End(xlUp).Row
With sh.Sort
.SortFields.Clear
.SortFields.Add Key:=sh.Range("B3"), Order:=xlAscending
.SetRange sh.Range("A3:E" & fr)
.Header = xlNo
.Apply
End With
Set sh = Nothing
End Sub
*****************************************************************
>βさん >同じWin10(64Bit)+xl2013(32Bit) で、このコードで、5秒後に消えるんですね？ はい、同じコードです。 Windows8.1から、Windows10にアップグレードしました。 消えますよ。ただ、8秒ぐらい経ってからですが…。 でも、Application.OnTimeで起動させている「MSG表示」プロシージャ でのポップアップは５秒どころか、１分経っても消えません。
k窓へのリンク、ありがとうございます。 「ダイアログを指定時間で自動的に閉じる」のところですね。 たしかに、数秒後にMsgBoxダイアログが閉じますが、 それは、エクセルでの作業をしているときに限ってで、 エクセル以外、例えば、メモ帳で編集作業などしていると、 これだと、タスクバーにあるエクセルが点滅して、 MsgBoxが最前面に表示されませんでした。ん～。 なんで、表示は、WSH.Popupを使うことにしました。 VBS（拡張子vbsのファイル）でも、WSH.Popupは 表示できるので、エクセルからVBSを起動させてもいいかも…。 変数をVBSに渡すことができるか知りませんが…。 VBSを使用する場合、変数を渡せないなら、 「時間になりました」のPopupになるのかな…。
'****************************************** Dim rt& kTimeOutDialog 10000, vbOKOnly rt = MsgBox(msg, vbSystemModal, " 確認") '******************************************
>βさん、>ayumi さん Excel_Alarm_3.xlsを作成しました。ファイル置いておきます（削除しました）。
たまにシートがなくて、灰色になっているExcelが出現します。 これは、なんなんでしょうか？
（マリオ） 2017/01/27(金) 22:49
拡張子の変更を簡単に行えるフリーソフトの紹介です。 ファイル上で、右クリックするとメニューに「拡張子の変更」 のメニューが追加されます。愛用してます。
txtの拡張子をvbsに変更とか http://www.vector.co.jp/soft/winnt/util/se506827.html?ds
txtファイルに次を貼り付けた後、拡張子をvbsに変更してください。
*****************************************************************
Dim WSH
Set WSH = CreateObject("WScript.Shell")
WSH.Popup "時間になりました", 5, "確認", vbSystemModal '最前面
Set WSH = Nothing
*****************************************************************
（マリオ） 2017/01/27(金) 23:26
ご教授有難うございます。
エクセルアラーム3を使ってみました。
今日、アラームを起動させたまま、いくつかExcelファイルを開いてみましたが、マクロが入っているファイルは全部MSGが出た時にエラーが出ると思っていましたが、全部ではありませんでした。
やはり、「ThisWorkbook」と「ActiveWorkbook」の違いなのですかね？
msgは出るけど、OKを押したら、
fr = sh.Range("A" & Rows.Count).End(xlUp).Row の部分が黄色になります。
もし可能であれば、どのファイルを開いていてもいいようにActiveWorkbookに変更は可能でしょうか？
（ayumi） 2017/01/28(土) 12:47
手直し中ですが、
sh.Range("A" & Rows.Count).End(xlUp).Row
の箇所が3か所ありますが、AをBにかえてください。
sh.Range("B" & Rows.Count).End(xlUp).Row
メッセージが入ってない箇所ありますかね？
（マリオ） 2017/01/28(土) 15:58
何度もすみません。
AをBに変更して、メッセージが入ってない箇所はありません。
しかし、メッセージをOKにすると、
"Rangeメッソドは失敗しました worksheetオブジェクト"と出ます。 （ayumi） 2017/01/28(土) 16:40
>βさん ■Alarm設定時刻になったときの表示について MsgBoxやWSH.Popupによる表示に代えて、 Form2とForm3を使って交互に表示するようにしたのですが、 表示1と表示2の間の時間を、わざわざ計算しています。 （※設定時間がきたことを告げるForm表示を1と2で表現！） ******************************************* 単純に、Form2を起動させるときは、 あらかじめForm3をUnloadまたはHideさせる。 逆に、Form3を起動させるときは、 あらかじめForm2をUnloadまたはHideさせる。 で記述できないでしょうか？ 表示するとき、Form2またはForm3の残像が見えたりと、 なかなかうまくいきません。 もし、わかりましたら、教えてください。 ******************************************* Excel_Alarm_4.xlsxを作成したので、 よかったら、見てください。 sheet1に貼り付けた★次のﾎﾞﾀﾝを押すと、動作確認できます。 「動作確認 （サンプル時刻を入力してExcel_Alarm起動）」 ちなみに、時間間隔が、3秒以内だと、うまく表示されないことがあります。 4秒以上、時間間隔が空いていれば、 時間がきたことを知らせるFormが順次表示されると思います。 【動作環境：windows10(64bit),excel2013(32bit)】
>ayumiさん Excel_Alarm_4.xlsxを作成しました。 これで、エラーが出るようでしたら、教えてください。 Formを閉じると、エクセルも閉じるようにしました。 また、起動時はエクセルは最小化されています。 E列は、列の幅を「ｾﾞﾛ」にしています。
（マリオ） 2017/01/29(日) 08:56
>βさん
（マリオ） 2017/01/27(金) 22:49 のところで、
たまにシートがなくて、灰色になっているExcelが出現します。
と記述しましたが、次のようにすると、問題解決しました。
*****************************************************************
'■ThisWorkbookのBeforeCloseイベントに次を記述
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Application.DisplayAlerts = False
If Workbooks.Count = 1 Then
ThisWorkbook.Save: Application.Quit
Else
ThisWorkbook.Save: ThisWorkbook.Close
End If
Application.DisplayAlerts = True
End Sub
*****************************************************************
（マリオ） 2017/01/29(日) 09:02
ご教授有難うございます。
今、自宅のパソコンでアラーム4を試しておりまして、良く使うExcelファイルを開き、それからアラームを開いたのですが、アラームのファイルを開くと、先に開いていたファイルも一緒に少し小さくなりました。
まぁこれは、大きくするとして、アラーム時間のメッセージが、それぞれの時間でてOKをクリックしても、なにもデバックは出ません。良い感じです。
全てのアラームメッセージが出たあと、画面上にある★のついたForamを消そうと×をクリックしたら、Excelの情報回復中となり、ドキュメントの回復画面が出てしまいました。
×ではなく、最小化のチェックの部分で操作したら、何も問題ありませんでした。
因みに、自宅のPC環境はWin10ですが、Excelは2007です。会社のPCはWin7で、Excel2010の使用です。
これは、自宅PCの環境問題？なのでしょうか？
（ayumi） 2017/01/29(日) 11:51
To マリオさん
>> あれ？なんか、おかしい。Form1のTop位置とLeft位置が記録されません。 >>UseForm1の残像が、Top=0,left=0の位置に出ます。？？？
Workbook_Open の UserForm1.CheckBox2.Value = True ここで UserForm1 を参照したとたんに UserForm1 がLoadされInitializeが走り、APIにより表示されます。 特段の指定がないので 表示はモーダル。 詳しくないのですが APIによる設定で 0,0 の位置に表示されているはずです。
つまり標準モジュールの UserForm1表示 で .Show vbModeless なんてやっても Load はされていますので Initialize は走りません。単に、すでに表示されているUserForm1 をもう１回表示しているだけで WindowStateは無視されています。
（β） 2017/01/29(日) 12:18
To マリオさん
このトピ、マリオさんとayumiさんのやりとりにお任せして、βとしては、常に追いかけているわけではありません。 今読み返すと、ほかにもいくつか質問をいただいているようで・・・
ただ、マリオさんの大作というか労作、精読してはいませんので、質問に対する回答をするには ちょっとつらいものがあります。（バージョンアップされていくコードを常に追いかけなおすのはしんどい・・・）
To ayumiさん
マリオさんから素晴らしいアイデアで処理提案コードがアップされているわけですが、様々な実行環境を考えるとき かつ、ことユーザーフォームに関しては 2010までのMDIと2013以降のSDIでの扱いの違い、さらに 2016 は また、別のユーザーフォームに関する不具合もいろいろ内包しているようで、個人的には、この処理を無理やり カスタムメイドのプログラムで行うことには、いささか疑問を持っています。
もちろん、マリオさん+ayumiさんの共同作業で、素晴らしいものを作り上げていくということに 待ったをかけるわけではありませんが 私であれば、以前書きましたように
１．スマホのアラームで対応 ２．さもなければ エクセルのスケジューラで対応
こうしますね。
（β） 2017/01/29(日) 12:28
>ayumi さん
今、自宅のパソコンでアラーム4を試しておりまして、良く使うExcelファイルを開き、それからアラームを開いたの ですが、アラームのファイルを開くと、先に開いていたファイルも一緒に少し小さくなりました。
ん～。ThisWorkbookのｺｰﾄﾞ記述欄に、次のように書いているので、 マクロを実行したﾌﾞｯｸのみ最小化すると命令してるのですが…。 Windows(ThisWorkbook.Name).WindowState = xlMinimized
>これは、自宅PCの環境問題？なのでしょうか？ 私のｺｰﾄﾞのミスによる問題と思われます。PC環境とは関係ないと思われます。 PCの環境は、下記の4点が知りたいです。 (1)OSのバージョン (2)OSのビット数、 (3)エクセルのバージョン (4)エクセルのビット数
Excel2007は、32bit版のみです。 Excel2010以降は、64bit版と32bit版の2つがあります。 OSが64bitでも、エクセルが64bitとは限りません。 32bitで動くｺｰﾄﾞが、64bit版のエクセルだと動かないことがあります。
32bit版のエクセルで問題ないのに、64bit版のエクセルで問題があれば、 APIの記述による問題だと思われます。
エクセルファイル【アラーム4】では、下記の2つのAPIを利用してます。 ・Module1記述のサウンド音を再生するAPI ・UserForm1～UserForm3記述のFormを最前面に保つAPI
（マリオ） 2017/01/30(月) 05:10
OSとエクセルのバージョン及びビット数は、下記のｺｰﾄﾞで確認できます。 '■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■ Option Explicit
'こちらのサイトを参考にしました http://blog.goo.ne.jp/mumbai/e/dc90cf94fc40baebf807f1913de4fc10 http://www.wmifun.net/sample/win32_operatingsystem_f.html
Sub バージョンを確認_OS及びExcel()
'------- Excelのバージョンを確認 --------------------------------
Dim Excel_Version As String
Select Case Application.Version
Case Is > 16#: Excel_Version = "Excel 2016以降のバージョン"
Case "16.0": Excel_Version = "Excel 2016"
Case "15.0": Excel_Version = "Excel 2013"
Case "14.0": Excel_Version = "Excel 2010"
Case "12.0": Excel_Version = "Excel 2007"
Case "11.0": Excel_Version = "Excel 2003"
Case "10.0": Excel_Version = "Excel 2002"
Case "9.0": Excel_Version = "Excel 2000"
Case "8.0": Excel_Version = "Excel 97"
Case "7.0": Excel_Version = "Excel 95"
Case "5.0": Excel_Version = "Excel 5.0"
Case Else: Excel_Version = "Excel(Version？)"
End Select
'------- Excelのビット数を確認 ----------------------------------
Dim Excel_bit As String
#If VBA7 Then 'Excel2010以降なら
#If Win64 Then 'Excelのbit数が64bitなら
Excel_bit = " (64 ビット)"
#Else
Excel_bit = " (32 ビット)"
#End If
#Else 'Excel2007以前なら(64bitはない、32bitのみ)
Excel_bit = " (32 ビット)"
#End If
'------- OSのバージョンとビット数の確認 -------------------------
Dim Locator, Service, OsSet, Os
Dim OS_X As String
Set Locator = CreateObject("WbemScripting.SWbemLocator")
Set Service = Locator.ConnectServer
Set OsSet = Service.ExecQuery("Select * From Win32_OperatingSystem")
For Each Os In OsSet
OS_X = OS_X & Os.Caption & " (" & CStr(Os.OSArchitecture) & ")"
Next Os
Set Locator = Nothing: Set Service = Nothing: Set OsSet = Nothing
'------- MsgBoxでの表示 -----------------------------------------
Dim msg As String, rc As Integer, title As String
msg = Excel_Version & Excel_bit & vbCr & OS_X
title = " Excel、OSの確認"
rc = MsgBox(msg, vbOKOnly, title)
End Sub
'■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
（マリオ） 2017/01/30(月) 05:11
>βさん
Workbook_Open のとこには、
UserForm1.CheckBox2.Value = True
は記述しない方がいいですね。
最終的にForm1の位置記録は、
ThisWorkbookのWorkbook_BeforeCloseイベントには記述せずに、
Form1のQueryCloseイベント及び、Terminateに記述することにしました。
'----------------------------------------------------------------
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
Dim sh2 As Worksheet
Set sh2 = ThisWorkbook.Sheets("位置")
sh2.Range("B1").Value = Me.Top
sh2.Range("B2").Value = Me.Left
Set sh2 = Nothing
End Sub
Private Sub UserForm_Terminate()
'----------------------------------------
Application.DisplayAlerts = False
If Workbooks.Count = 1 Then
ThisWorkbook.Save: Application.Quit
Else
ThisWorkbook.Save: ThisWorkbook.Close
End If
Application.DisplayAlerts = True
'----------------------------------------
End Sub
（マリオ） 2017/01/30(月) 05:50
>βさん、ayumiさん ちなみに、私は自作したExcel_Alarmを使うことはないと思います。
１．スマホ、または携帯のアラームで対応
２．5分程度の誤差が問題とならないなら、
スマホや携帯よりも設定が容易なアナログの置き時計
（スマホや携帯が電池切れの時とか‥）
３．PC環境なら、ミニタイマー
http://www.vector.co.jp/soft/win95/personal/se401253.html
私なら、こうしますね。 指定時間も決まってないときが多い。 70分後には、出かけなきゃいけないとか
あくまで、コーディングの練習という観点から、Excel_Alarm.xlsxを見てください。 （マリオ） 2017/01/30(月) 06:10
To マリオさん
>>マクロを実行したﾌﾞｯｸのみ最小化すると命令してるのですが…。
つまみ食い程度にしか、本トピ（およびマリオさんのコード）を見ていないのですが マクロブックを最小化する目的が、マクロブックは表示させたくない、あくまでユーザーフォームのみ表示。 こういうことなら、マクロブックを非表示にしておけば、何もしなくてもいいのでは？
場合によってはマクロブックも表示させたいということであればスルー願います。
（β） 2017/01/30(月) 10:14
>βさん >マクロブックを最小化する目的が、マクロブックは表示させたくない、 >あくまでユーザーフォームのみ表示。こういうことなら、 >マクロブックを非表示にしておけば、何もしなくてもいいのでは？ はじめ、非表示にしていました。 試してみたら、非表示にしているとエラーに なる所が出てくるんです。一時的に表示し直して、また非表示でも 対応できるんですが、面倒なので、最小化にしております。 ********************************** http://d.kuku.lu/b2ac309e29 エクセルアラーム7_おまけ.zip ********************************** ↑はじめに、OnTime予約されていたら解除して、 その後、OnTime予約をするようにしました。 一度、Alarm予約したけど、【や～めた】ってことありますから。
↑こちらの（マリオ） 2017/01/30(月) 13:33に、OnTimeの解除について書きました。 （マリオ） 2017/01/30(月) 14:13
色々と、ご教示頂き有難うございました。
また、何度も修正していただき、感謝しています。
エクセルアラーム7で確認しました。時に問題なく作動しています。
因みに、会社のpcのバージョンですが、
Win7の32bit Excel2010の32bitでした。
自宅は、Win10の32bit Wxcel2007の32bitでした。
また、「おまけ」まで付けて頂き、有難うございます。
これもまた、何かに使えそうです。
マリオさま、βさま からご紹介頂いた、フリーソフトについても、使用すすか検討していきたいと
思います。
（ayumi） 2017/01/31(火) 13:32
>ayumi さん どういたしまして。Form作成の勉強になりましたよ。 それでは、また！ （マリオ） 2017/01/31(火) 14:48
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.