[[20170128192422]]　『AVERAGEIFの引数が多すぎますの解決方法教えてくａx（cameko）　ページの最後に飛ぶ

『AVERAGEIFの引数が多すぎますの解決方法教えてください。』（cameko）

ネット検索試みましたが、解決できず教えてください。
日々の売上げ管理で売上金額の平均値を出そうとAVERAGEで表を作成しましたが、休業日のゼロも含んでしまうため、AVERAGEIFでゼロを含まないで数式を作りましたが「引数が多すぎます」とエラーメッセージで、その解決策が解りません。教えてください。。。
最初の数式=AVERAGE(D6,D11,D16,D21,D26)
ゼロを含めない数式=AVERAGEIF(D6,D11,D16,D21,D26,"<>0")と入力すると
「この関数に対して多すぎる引数が入力されています」とメッセージが出てしまいます。
AVERAGEIFのD26のセルだけ認識してくれないようです。
１ヶ月の曜日ごとの平均売上げを出したいので５週分で５個の飛び飛びのセルが必要な条件となります。
エクセルのヘルプを読んでもよく理解できず、解決策を教えてください。
よろしくお願いいたします。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 AVERAGEIF は　あくまで　領域,条件,平均対象範囲　ですから、引数は最大３つ。
 領域は１つの指定しかできませんね。

 たとえば　=AVERAGEIF(IF(MOD(ROW(D6:D26),5)=1,D6:D26,0),"<>0")

 こんな式で、できそうですね。

（β） 2017/01/28(土) 20:09

 =AVERAGE(IF((MOD(ROW(D6:D26),5)=1)*(D6:D26>0),D6:D26))
 CtrlキーとShiftキーとEnterキーを同時押しで式を確定

 または

 =SUM(D6,D11,D16,D21,D26)/((D6>0)+(D11>0)+(D16>0)+(D21>0)+(D26>0))
 普通にEnterで確定
（bi） 2017/01/29(日) 09:55

 こんにちわ。

 >１ヶ月の曜日ごとの平均売上げを出したいので５週分で５個の飛び飛びのセルが必要な条件となります。

 D6の横とかに月曜とかの曜日を表す列は無いんですか？
 単にレイアウトを以下のようにすれば、簡単にAVERAGEIFSで求められますよ。

         D     E  F     G      H  
  5  売上   曜日     曜日  平均   
  6      0  月       月    47500  =AVERAGEIFS($D$6:D$30,E$6:E$30,G6,D$6:D$30,"<>0")
  7  40000  火       火    50000  =AVERAGEIFS($D$6:D$30,E$6:E$30,G7,D$6:D$30,"<>0")
  8  70000  水       水    58000  =AVERAGEIFS($D$6:D$30,E$6:E$30,G8,D$6:D$30,"<>0")
  9  80000  木       木    60000  =AVERAGEIFS($D$6:D$30,E$6:E$30,G9,D$6:D$30,"<>0")
 10  20000  金       金    55000  =AVERAGEIFS($D$6:D$30,E$6:E$30,G10,D$6:D$30,"<>0")
 11  90000  月                    
 12  80000  火                    
 13  60000  水                    
 14  60000  木                    
 15  30000  金                    
 16  20000  月                    
 17  20000  火                    
 18  90000  水                    
 19  50000  木                    
 20      0  金                    
 21  40000  月                    
 22  80000  火                    
 23  60000  水                    
 24  40000  木                    
 25  90000  金                    
 26  40000  月                    
 27  30000  火                    
 28  10000  水                    
 29  70000  木                    
 30  80000  金

（sy） 2017/01/29(日) 10:58

コメント返信：

[ 一覧(最新更新順) ]

[[20170128192422]] 『AVERAGEIFの引数が多すぎますの解決方法教えてくａx（cameko） ページの最後に飛ぶ

[[20170128192422]]　『AVERAGEIFの引数が多すぎますの解決方法教えてくａx（cameko）　ページの最後に飛ぶ