[[20170625114836]]　『特定文字が、含まれる文字に対してフラグを立てた』（ななな）　ページの最後に飛ぶ

『特定文字が、含まれる文字に対してフラグを立てたい』（ななな）

 品名　　　　　フラグ
 ああねぎ
 いいねぎ
 ううなす
 ががみ
 ああなす
 いいなす
 ううねぎ

と、いう表があります。
「ねぎ」とつく場合はフラグに「１」、なすの場合は「２」
ただし、「ががみ」の場合も「１」と表示したい場合どのように
関数を組めばできますか？
IFでは、できないのでしょうか？

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

A1セルに"ねぎ"が含まれるかどうかは
IFERROR(FIND("ねぎ",A1),0)
が > 0　か 0 かで判定できます。
あとは、単純にIF関数を入れ子にして判定していけばよいでしょう。
　
＞「ねぎ」とつく場合
＞なすの場合
＞「ががみ」の場合
と言う表現は、一致なのか、部分一致なのか不明瞭ですね。
質問は正確に書いた方がよいと思います。

（γ） 2017/06/25(日) 13:01

 特定文字は実際も3種類だけ？

 1つのセルに複数の特定文字が含まれることはないという前提で、
 品名はA列だとして、

 B2 =IF(OR(A2="ががみ",COUNTIF(A2,"*ねぎ*")),1,IF(COUNTIF(A2,"*なす*"),2,""))
 とか
 B2 =SUM(COUNTIF(A2,{"ががみ","*ねぎ*","*なす*"})*{1,1,2})
　
「ああががみ」のように文字列の中に「『ががみ』が含まれる場合」も「1」なのかどうかが曖昧です。

 ところで「ががみ」って何ですか？
（笑） 2017/06/25(日) 13:20

 ↑の補足。下の式は特定文字が含まれない場合は「0」になるので、
 表示形式で「0」を非表示にする。

 表示形式～ユーザー定義　#

 ついでに「ああががみ」のように「ががみ」が含まれる場合も「1」にするのなら、

 B2 =SUM(COUNTIF(A2,{"*ががみ*","*ねぎ*","*なす*"})*{1,1,2})
 または
 B2 =SUM(COUNTIF(A2,"*"&{"ががみ","ねぎ","なす"}&"*")*{1,1,2})

 参考まで。
（笑） 2017/06/25(日) 13:27

コメント返信：

[ 一覧(最新更新順) ]

[[20170625114836]] 『特定文字が、含まれる文字に対してフラグを立てた』（ななな） ページの最後に飛ぶ

[[20170625114836]]　『特定文字が、含まれる文字に対してフラグを立てた』（ななな）　ページの最後に飛ぶ