[[20180217175622]]　『複数ある行の折り返し設定のうち個別の折り返しを』（初心者9371）　ページの最後に飛ぶ

『複数ある行の折り返し設定のうち個別の折り返しを解除したい』（初心者9371）

１つのｼｰﾄ上に複数の折り返しが設定してあります
すべての折り返しを一度に解除することは
Sub 全折り込み解除()
　　ActiveSheet.Outline.ShowLevels RowLevels:=2
End Sub
Sub 全折り込み()

    ActiveSheet.Outline.ShowLevels RowLevels:=1
End Sub
で可能なのですが
個別の折り返しをﾏｸﾛで行いたいと考えました
画面左の＋－のﾎﾞﾀﾝで可能なのですが
長い行の折り返し箇所もありそこまで画面を
スクロールする必要があり、何とかﾏｸﾛで出来ないかと
考えました
可能でしょうか
可能ならどういう構文になるのでしょうか
宜しくお願いします。

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

もう少し、具体例を使って説明されるとよいです。
というわけで、何をしたいか、理解できていませんが、
↓とかは、参考になりますか？
http://vbabeginner.net/%E3%82%B0%E3%83%AB%E3%83%BC%E3%83%97%E5%8C%96%E3%81%AE%E8%A1%A8%E7%A4%BA%E3%81%A8%E9%9D%9E%E8%A1%A8%E7%A4%BA/

それとも、希望の位置にスクロールできればよいのでしょうか。

（マナ） 2018/02/18(日) 11:54

マナさん
有難うございます。

何をしたいか、理解できていませんが、説明がへたですみません
下記で説明用の簡易メモ的なものを作っています

	Ａ	Ｂ	Ｃ
1	説明１	これは説明１の内容です	
2		説明１の内容	
3		説明１の内容	
4		説明１の内容	
5		説明１の内容	
6	説明２	これは説明２の内容です	
7		説明２の内容	
8		説明２の内容	
9		説明２の内容	
10		説明２の内容	
11		説明２の内容	
12		説明２の内容	
13		説明２の内容	
14		説明２の内容	
15		説明２の内容	
16		説明２の内容	
17		説明２の内容	
18		説明２の内容	
19		説明２の内容	
20		説明２の内容	
21　　　説明３	これは説明３の内容です			
22		説明３の内容	
23		説明３の内容	
24		説明３の内容	
25		説明３の内容	
26		説明３の内容

ずっと下までみていかないとＡ列の何についての説明かがわかりません
そこで折り返し機能をつかい
ＡＢＣ
1 説明１これは説明１の内容です
6 説明２これは説明２の内容です
21 説明３これは説明３の内容です
　としました
画面左の折り返しのﾎﾞﾀﾝ　＋　-ボタンで各項目の折り返し・折り返し解除を
出来るようにしました
例えば、説明２の折り返しをする場合、ボタンを探すのに画面をスクロール
しないといけない場合があります
こうしたﾎﾞﾀﾝ操作になれていないメンバー（私もそうですが）使いかたに不便
との声があり
ＡＢ　Ｃ　　　　　　　　　　　Ｄ　　　Ｅ
1 説明１これは説明１の内容です　　開く　　閉じる
6 説明２これは説明２の内容です　　開く　　閉じる
21 説明３これは説明３の内容です　　開く　　閉じる
として、例えば　Ｄ６セルの開くと説明２の折り返しが開くように
したいと考えました
教えて頂いたサイトに個別の折り返し、折り返し解除は出来ないと
ありましので、ここでの質問の内容については理解できました
有難うございました。

（初心者9371） 2018/02/18(日) 13:28

得意じゃないので代替案でもよければ

シートに１行目にCombobox を用意して
ウィンドウ枠固定で、１行目を常時表示
Combobox 選択によって、スクロールさせます。

シートモジュールに以下をコピペしてください。

 Option Explicit

 Private Sub ComboBox1_Change()
    If ComboBox1.ListIndex = -1 Then Exit Sub
    Application.Goto Cells(ComboBox1.Value, 1), True

 End Sub

 Private Sub Worksheet_Activate()
    Dim c As Range

    With ComboBox1
        .ColumnCount = 3
        .BoundColumn = 3
        .ColumnWidths = "50;400;0"  '★幅調整は必要
        .Clear
        For Each c In Columns(1).SpecialCells(xlCellTypeConstants)
            .AddItem c.Value
            .List(.ListCount - 1, 1) = c.Offset(, 1).Value
            .List(.ListCount - 1, 2) = c.Row
        Next
    End With

 End Sub

（マナ） 2018/02/18(日) 15:00

 ＞例えば、説明２の折り返しをする場合、ボタンを探すのに画面をスクロール 
 ＞しないといけない場合があります

 私には依然としてよく分からないです。

 EXCELの行や列を折りたたむ「グループ化」をマスターしよう
http://h1r0-style.net/excelvba/howto-group-rows-and-columns
 　↑
 そのページの「上の行をたたみ込む方法」に書かれている通り、

 　［集計行または列の位置］ダイアログの
 　　　□詳細データの下

 のチェックを外せば、マイナスボタンは一番上に在るんですから
 下にスクロールをする必要なんて無いと思うんですけど？

（半平太） 2018/02/18(日) 15:30

 　↑
 ＞すると、今度は上にスクロールするのが面倒と言うことなんですか？

（半平太） 2018/02/18(日) 15:33

もう見てないようですが、折り返しでは無く、詳細行の表示／非表示ですね。
マナさんの紹介ページの応用です。
A1セルから連続して提示のようなデータで、"説明ｎ"に対し１つ以上の"説明ｎの内容"があるとして、
・A列のグループ化しないセル（例："説明１"）でダブルクリック（一番最初に実行してください）すると
その詳細行が表示されます。
・A列のグループ化するセル（空白セルのどのセルでも良い）でダブルクリックすると
全ての詳細行が非表示になります。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

    Dim r As Range
    Dim rd As Range
    Dim rng As Range

    Application.ScreenUpdating = False
    Set rng = Range("A1").CurrentRegion.Columns("A")
    If Not Intersect(Target, rng) Is Nothing Then
        Cancel = True
        Me.Outline.ShowLevels rowlevels:=2
        If Target.Value = "" Then
            Me.Outline.ShowLevels rowlevels:=1
            Application.Goto Range("A1"), True   '不要なら削除してください
            Exit Sub
        Else
            Set rng = rng.SpecialCells(xlCellTypeBlanks)
            On Error Resume Next
            For Each r In rng.Areas
                r.EntireRow.Ungroup
            Next
            On Error GoTo 0
            For Each r In rng.Areas
                If Intersect(Target.Offset(1), r) Is Nothing Then
                    r.EntireRow.Group
                Else
                    Set rd = r
                End If
            Next
            Me.Outline.ShowLevels rowlevels:=1
            rd.EntireRow.Group
            Application.Goto Target, True   '不要なら削除してください
        End If
    End If
End Sub

（kazuo） 2018/02/19(月) 09:05

コメント返信：

[ 一覧(最新更新順) ]

[[20180217175622]] 『複数ある行の折り返し設定のうち個別の折り返しを』（初心者9371） ページの最後に飛ぶ

[[20180217175622]]　『複数ある行の折り返し設定のうち個別の折り返しを』（初心者9371）　ページの最後に飛ぶ