[[20181107104215]]　『休憩時間の計算』（事務員）　ページの最後に飛ぶ

『休憩時間の計算』（事務員）

お世話になります。

アドバイスお願いします。

休憩開始時間２２：００

Ｆ４　２２
Ｈ４　００

休憩終了時間２４：００

Ｉ４　２４
Ｋ４　００

休憩時間２時間

Ｏ４　２
Ｑ４　００

Ｏ４に　IF(I4="","",HOUR((TIME(I4,K4,0)-TIME(F4,H4,0))))
Ｑ４に　IF(K4="","",MINUTE((TIME(I4,K4,0)-TIME(F4,H4,0))))　

の式を入れているのですがエラー表示が出てしまいます。

ちなみに休憩終了時間が２４：００以外だと正しく表示されます。

よろしくお願いします。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 TIME関数は時間だけ求めるので日部分は捨てられる。
 そのため24:00は0:00となってしまうため引き算の結果がマイナスになってエラーとなっている。
 O4セル：=IF(I4="","",HOUR((I4&":"&K4)-(F4&":"&H4)))
 Q4セル：=IF(K4="","",MINUTE((I4&":"&K4)-(F4&":"&H4)))
 ではどうか？
（ねむねむ） 2018/11/07(水) 11:22

ねむねむ　様

ありがとうございます！

無事解決いたしました。
（事務員） 2018/11/07(水) 11:52

もう一つ質問させてください。

出勤時間２３：００

Ｃ５　２３
Ｅ５　００

休憩開始時間　２：００

Ｆ５　２
Ｈ５　００

休憩終了時間　３：００

Ｉ５　３
Ｋ５　００　

退勤時間９：００

Ｌ５　０９
Ｎ５　００

実労働時間　９時間

Ｒ５　９
Ｔ５　００

Ｒ５＝=IFERROR(HOUR((L5&":"&N5)-(C5&":"&E5)-((I5*1&":"&K5*1)-(F5*1&":"&H5*1))),"")
Ｔ５＝=IFERROR(MINUTE((L5&":"&N5)-(C5&":"&E5)-((I5*1&":"&K5*1)-(F5*1&":"&H5*1))),"")

と入れているのですが表示されません。

アドバイスお願いいたします。

よろしくお願いいたします。

（事務員） 2018/11/07(水) 13:39

 退勤時間が出勤時間より小さいので引き算の結果がマイナスになりエラーとなっている。
 退勤時間が出勤時間より小さい場合は退勤時間は翌日ということで1を足す。
 (日付・時刻データは1日を1、1時間を1/24とする数値で管理されている）
（ねむねむ） 2018/11/07(水) 14:00

 R5セル：=IFERROR(HOUR((L5&":"&N5)-(C5&":"&E5)+((L5&":"&N5)-(C5&":"&E5)<0)-((I5&":"&K5)-(F5&":"&H5))),"")
 T5セル：=IFERROR(MINUTE((L5&":"&N5)-(C5&":"&E5)+((L5&":"&N5)-(C5&":"&E5)<0)-((I5&":"&K5)-(F5&":"&H5))),"")
 ではどうか？
（ねむねむ） 2018/11/07(水) 14:00

 休憩時間が日をまたいでいる場合を考慮していなかった。
 R5セル：=IFERROR(HOUR((L5&":"&N5)-(C5&":"&E5)+((L5&":"&N5)-(C5&":"&E5)<0)-((I5&":"&K5)-(F5&":"&H5)+((I5&":"&K5)-(F5&":"&H5)<0))),"")
（ねむねむ） 2018/11/07(水) 14:14

 T5セル：=IFERROR(MINUTE((L5&":"&N5)-(C5&":"&E5)+((L5&":"&N5)-(C5&":"&E5)<0)-((I5&":"&K5)-(F5&":"&H5)+((I5&":"&K5)-(F5&":"&H5)<0))),"")
 としてくれ。
（ねむねむ） 2018/11/07(水) 14:15

ねむねむ　様

ありがとうございます！！
無事解決しました！
（事務員） 2018/11/07(水) 14:23

コメント返信：

[ 一覧(最新更新順) ]

[[20181107104215]] 『休憩時間の計算』（事務員） ページの最後に飛ぶ

[[20181107104215]]　『休憩時間の計算』（事務員）　ページの最後に飛ぶ