[[20181227093729]]　『日数の集計』（はな）　ページの最後に飛ぶ

『日数の集計』（はな）

A列に日にち（重複日もある）、B列に金額が、1月から12月まで入力してある。
1月分から12月分までの各月の21日から20日までの日にちのカウント（重複を除く）、金額の合計（重複の日にちも合計）をしたいです。

1月から12月の集計表は、下記の様に表示したい

    A    B 　C　　　　M　　　N
1 　　 1月　2月　　　12月　合計
2　日数
3　金額

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

 もう少し具体的に表の形を示してみてくれないか？
 説明と表の例とで異なっているように見えるが。
 >各月の21日から20日
 これは当月21日から翌月20日までということか？
 また、
 >日にちのカウント
 これは単純な経過日数なのか表で出現している日数なのか（後者だとは思うが）
（ねむねむ） 2018/12/27(木) 10:15

 Sheet1		
 	A	B
	日付	金額
 1	1/1	50
 2	1/1	100
 3	1/2	150
 4	1/20	200
 5	1/21	250
 6	1/30	300
 7	2/2	350
 8	2/20	400
 9	2/20	450
 10	2/28	500
 11	3/20	550

 Sheet2							
 	A	B	C	D	…	M	N
 1		1月	2月	3月	…	12月	合計
 2	日数						
 3	金額

 Sheet2の1行目は2018/1/21、2018/2/21…と入力して表示形式で m"月"
 Sheet2のB2:=SUMPRODUCT((Sheet1!$A$2:$A$1001>=B1)*(Sheet1!$A$2:$A$1001<=EDATE(B1,1)-1)/COUNTIFS(Sheet1!$A$2:$A$1001,Sheet1!$A$2:$A$1001&""))
 Sheet2のB3:=SUMIFS(Sheet1!$B:$B,Sheet1!$A:$A,">="&B1,Sheet1!$A:$A,"<="&EDATE(B1,1)-1)

 それぞれを右方向にコピー
 …ということなのかな？
（bi） 2018/12/27(木) 11:17

 すまない。
 日にちの表と集計表は別物だったか。
（ねむねむ） 2018/12/27(木) 11:20

 例えば2018年1月なら、期間は　2017/12/21～2018/1/20　で合ってますか？

 1年分の期間が　2017/12/21～2018/12/20　だとして

 ■集計表
 B1に　2018/1/20　を入力
 C1 =EDATE(B1,1)　　M1までコピー
 B1:M1の表示形式～ユーザー定義　m"月"

 B2 =COUNT(0/FREQUENCY(IF((Sheet1!$A$2:$A$100>EDATE(B1,-1))*(Sheet1!$A$2:$A$100<=B1),Sheet1!$A$2:$A$100),Sheet1!$A$2:$A$100))

 Ctrl＋Shift＋Enter で確定し、右にコピー

 B3 =SUMIFS(Sheet1!$B:$B,Sheet1!$A:$A,">"&EDATE(B1,-1),Sheet1!$A:$A,"<="&B1)

 普通にEnterだけで確定し、右にコピー

 参考まで
（笑） 2018/12/27(木) 11:46

 (笑)さんと同様に 1行目設定。

 B2 =SUMPRODUCT((COUNTIF(Sheet1!$A:$A,ROW(INDEX(A:A,EDATE(B1,-1)+1):INDEX(A:A,B1)))>0)*1)

 ※B3は(笑)さんと一緒で。
（GobGob） 2018/12/27(木) 12:29

ありがとうございました。
皆様のご教示により思った通りの集計表が出来ました。

（はな） 2018/12/27(木) 13:08

コメント返信：

[ 一覧(最新更新順) ]

[[20181227093729]] 『日数の集計』（はな） ページの最後に飛ぶ

[[20181227093729]]　『日数の集計』（はな）　ページの最後に飛ぶ