[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『複数条件検索で表からデータを抽出するには』（まるちゃん）
初めてご質問させていただきます。
複数条件のデータ抽出でどのような式にすればいいのか
わかりません。よろしくお願いいたします。
A B C D E
1氏名 引渡日 半年点検 1年点検 2年点検
2上田
3山本
4小林
上記のような表を作成しました。
列C〜Eは引渡日から半年、1年、2年後の点検日を数式で入れています。
この表から別シートで
A B C
1【5月】
2氏名 点検年月日 点検の種類
A1に「5月（日付）」を入れると
2019.5月中に点検日が該当する名前と、点検日と点検種類（半年・1年・2年）
がでるように数式をいれたいのです。
最初のデータより抽出することはかのうでしょうか？
＜ 使用 Excel：Excel2016、使用 OS：Windows10 ＞
＞列C〜Eは引渡日から半年、1年、2年後の点検日を数式で入れています。
１．どんなデータなんですか？
書式を標準にすると見えるデータを示していただくか、
数式自体を見せていただくと明快なんですけど。
＞A1に「5月（日付）」を入れると
２．どんなデータなんですか？
シリアル値なんですか？
月初日を入れているんですか？
それとも適当な5月の日付なんですか？
３．参考情報として、全部で何人いるのか教えてください。
※なお、他の回答者からレスが付いたら、 この私の問い合わせにお答えいただく必要はありません。
（半平太） 2019/05/11(土) 12:36
1. C 半年→DATE(YEAR(B2),MONTH(B2)+6,DAY(B2))
D 1年→DATE(YEAR(B2)+1,MONTH(B2),DAY(B2))
E 2年→DATE(YEAR(C3)+2,MONTH(C3),DAY(C3))
2.日付入力します。（5/1と入力）
3.全員で116人います。
よろしくお願いいたします<(_ _)>
（まるちゃん） 2019/05/11(土) 13:44
＞ E 2年→DATE(YEAR(C3)+2,MONTH(C3),DAY(C3)) E 2年→DATE(YEAR(B2)+2,MONTH(B2),DAY(B2)) ですね？
＞3.全員で116人います。
E200までカバーすることにします。 (199人まで）
<Sheet2> (1) A3セル =IFERROR(INDEX(Sheet1!A:A,AGGREGATE(15,6,ROW($C$2:$E$200)/(Sheet1!$C$2:$E$200-DAY(Sheet1!$C$2:$E$200)+1=$A$1),ROW(A1))),"") (2) B3セル =IF(A3="","",LOOKUP(EDATE($A$1,1),INDEX(Sheet1!$C$1:$E$200,AGGREGATE(15,6,ROW($C$2:$E$200)/(Sheet1!$C$2:$E$200-DAY(Sheet1!$C$2:$E$200)+1=$A$1),ROW(A1)),0))) (3) C3セル =IF(A3="","",LOOKUP(EDATE($A$1,1),INDEX(Sheet1!$C$1:$E$200,AGGREGATE(15,6,ROW($C$2:$E$200)/(Sheet1!$C$2:$E$200-DAY(Sheet1!$C$2:$E$200)+1=$A$1),ROW(A1)),0),Sheet1!$C$1:$E$1))
必要なだけ、下にコピー。
<Sheet2 結果図> 行 ____A____ _____B_____ _____C_____ 1 2019/5/1 2 氏名 点検年月日 点検の種類 3 山本 2019/5/3 1年点検 4 中村 2019/5/30 半年点検 5 山本 2019/5/15 2年点検 6 山本 2019/5/26 半年点検
<Sheet1 サンプルデータ> 行 __A__ _____B_____ _____C_____ _____D_____ _____E_____ 1 氏名 引渡日 半年点検 1年点検 2年点検 2 上田 2018/4/5 2018/10/5 2019/4/5 2020/4/5 3 山本 2018/5/3 2018/11/3 2019/5/3 2020/5/3 4 小林 2018/3/2 2018/9/2 2019/3/2 2020/3/2 5 中村 2018/11/30 2019/5/30 2019/11/30 2020/11/30 6 山本 2017/5/15 2017/11/15 2018/5/15 2019/5/15 7 山本 2018/11/26 2019/5/26 2019/11/26 2020/11/26
（半平太） 2019/05/11(土) 15:26
ところで、Sheet2の氏名列ですが、同じ名前は出て来ないんでしょうか？
それだと少し楽になるんですが・・
（半平太） 2019/05/11(土) 15:30
（まるちゃん） 2019/05/13(月) 10:29
＞Sheet2の氏名はフルネームなので同じ名前は出てこないです！
(1) A3セル =IF(A2="","",IFERROR(INDEX(Sheet1!A:A,AGGREGATE(15,6,ROW($C$2:$E$200)/(Sheet1!$C$2:$E$200-DAY(Sheet1!$C$2:$E$200)+1=$A$1),ROW(A1))),"")) (2) B3セル =IF(A3="","",LOOKUP(EDATE($A$1,1),INDEX(Sheet1!$C$2:$E$200,MATCH(A3,Sheet1!$A$2:$A$200,0),0))) (3) C3セル =IF(A3="","",LOOKUP(EDATE($A$1,1),INDEX(Sheet1!$C$2:$E$200,MATCH(A3,Sheet1!$A$2:$A$200,0),0),Sheet1!$C$1:$E$1))
（半平太） 2019/05/13(月) 16:08
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.