[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『countifとvlookup関数で連番をふりたい』（ベアーズ）
色々調べて関数を入れてみたのですが、#N/Aがでてしまうので、
教えていただきたく、宜しくお願いします。
A B C D
1 請求書番号 住所1 住所2 宛先
2 1 東京都 大田区 ア会社
3 1 東京都 大田区 ア会社
4 2 埼玉県 三郷市 イ会社
5 空白
6 2 埼玉県 三郷市 イ会社
上記のような表があり、請求書番号に宛先が同じならば同じ番号を
表示させ、連番をふり、空白の場合はとばすことがしたかったので、
下記の作業をしてみました。
A2に=IF(D2="","",IF(COUNTIF($D$2:D2,D2)=1,MAX($A$1:A1)+1,VLOOKUP(D2,$A$1:D1,1,0)))
を入力し、A3から下へコピーをすると、A2には「1」が返ってくるの
ですが、A3以降は#N/Aが表示されます。
上記の関数がおかしいのか、他に何かよい方法はないでしょうか。
＜ 使用 Excel：Excel2010、使用 OS：Windows7 ＞
A2 =IF(D2="","",IF(COUNTIF($D$2:D2,D2)=1,MAX($A$1:A1)+1,INDEX($A$1:A1,MATCH(D2,$D$1:D1,0))))
参考まで （笑） 2019/07/16(火) 00:19
大変助かりました！笑さんの数式を入れてみたところ、
できました。vlookup関数の検査値の範囲のことなど、
また勉強したいと思います。
ありがとうございました。
（ベアーズ） 2019/07/16(火) 08:19
=IF(D2="","",IF(COUNTIF(D$1:D1,D2),VLOOKUP(D2,IF({1,0},D$2:D2,A$2:A2),2,FALSE),MAX(A$1:A1)+1))
でも。
（ねむねむ） 2019/07/16(火) 09:21
A2 =IF(D2="","",IFERROR(INDEX(A$1:A1,MATCH(D2,D$1:D1,0)),MAX(A$1:A1)+1)) （GobGob） 2019/07/16(火) 10:45
そうか。
=IF(D2="","",IFERROR(VLOOKUP(D2,IF({1,0},D$1:D1,A$1:A1),2,FALSE),MAX(A$1:A1)+1))
でもOKか。
（ねむねむ） 2019/07/16(火) 10:48
ありがとうございます。色々な関数でできるので、大変勉強になります。
追加ですみません。B列に支部を挿入し、支部と宛先が一致したものを
同じ番号を表示させることは可能でしょうか。
連番をふって1件1件確認した所、会社名が同じでも、支部が異なること
が判明しました。
（A請求書番号 B支部 C住所1 D住所2 E宛先となります）
例えば、1支部 ア会社と2支部 ア会社がある場合、上記関数のままだと
会社名で番号をふっているので、同じ番号が表示されます。
1支部 ア会社と2支部 ア会社は会社名は同じですが、支部が異なるので
、別の番号を表示させたいです。
=IF(B2＆E2="","",・・・でやってみたのですが、だめでした。
解決したと思っていたのですが、度々で申し訳ありません
（ベアーズ） 2019/07/16(火) 18:26
A2 =IF(E2="","",IFERROR(LOOKUP(1,0/(($B$1:B1=B2)*($E$1:E1=E2)),$A$1:A1),MAX($A$1:A1)+1))
下コピー
こういうこと？ （笑） 2019/07/16(火) 19:07
ありがとうございます！！こういうことです！！
これで本当に解決しました。
（ベアーズ） 2019/07/16(火) 19:22
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.