[[20191011225135]]　『行の合計をするには？？』（やす）　ページの最後に飛ぶ

『行の合計をするには？？』（やす）

下のもあった内容ににているのですが、
A列にりんご、みかん、バナナと複数あり、
行では1日、2日、3日、、、31日と日付があり、
それぞれ収穫した個数が記載されています。

りんごが4日～7日の収穫数
バナナが5日～17日の収穫数
を合計するには
Vlookup（4日）＋vlookup（5日）＋、、、
といった方法しかありませんでしょうか？

教えていただけるとありがたいです。

＜使用 Excel：Excel2016、使用 OS：unknown ＞

 >A列にりんご、みかん、バナナと複数

 りんごが複数あったりすることはあるんですか？
（コナミ） 2019/10/11(金) 23:06

いえ、ありません。
ですが、例えば
A1 　　B1 C1　D1
りんご　2 5 合計値
のようにりんごが2日～5日までの
収穫合計が出るようにもできたらしたいです。
（やす） 2019/10/11(金) 23:16

 セル番地が分かるように表を提示してください。

 B1:AF1 に日付ってこと？
 1）その日付はシリアル値ですか？
  　シリアル値ではないのなら、文字列なのか、単なる1～31の数値なのか、何ですか？

 2）品名は何種類あるんですか？
  　つまりA2セルからだとして、何行目までの表なんですか？

 3）収穫数はどこに（どのセルに）出すんですか？　同じシート？　別シート？

 とりあえず以上です
（笑） 2019/10/11(金) 23:27　追記 23:33

1) 1日、2日、、、とありシリアル値ではなさそうです。
　　文字列かと思われます。
2) 品名は細かくて250個あります。
（やす） 2019/10/11(金) 23:43

ちょっと強引ですがこんな関数はいかがでしょうか。

表がA3～AF252、
A1:品名
B1:合計する初日
C1:合計する最終日
としています。

=SUM(INDIRECT(ADDRESS(MATCH($A$1,$A$3:$A$252,0)+2,$B$1+1)&":"&ADDRESS(MATCH($A$1,$A$3:$A$252,0)+2,$C$1+1)))
（黄色い循環参照） 2019/10/12(土) 00:21

 ＞シリアル値ではなさそうです。 
 ＞文字列かと思われます。

 表示形式を見てくださいよ。どうなってるんですか？
　
「1日」という文字列なら「1～31」の数値に変更してください。
 B1セル「1」 ～BF1セル「31」ということ。オートフィルでできます。
「1日」と表示させたいのなら、表示形式～ユーザー定義　0"日"

	A	B	C	D
1		開始	終了	合計
2	りんご	4	7	
3	バナナ	5	17	
4

 元表が Sheet1 だとして

 D2 =IF(COUNTA(A2:C2)<3,"",SUMIFS(INDEX(Sheet1!$B$2:$BF$300,MATCH(A2,Sheet1!$A$2:$A$300,0),0),Sheet1!$B$1:$BF$1,">="&B2,Sheet1!$B$1:$BF$1,"<="&C2))

 下コピー

 参考まで
（笑） 2019/10/12(土) 00:32

スゴい、、、
やってみたところ、
C1に入力した数字よりも1少ない日数で
合計されるのですが、この修正は
どうすればいいでしょうか？
表示形式は標準でした。すいません。
（やす） 2019/10/12(土) 01:01

 ↓ でもいいかも

 D2 =IF(COUNTA(A2:C2)<3,"",SUM(INDEX(Sheet1!$B$2:$AF$300,MATCH(A2,Sheet1!$A$2:$A$300,0),B2):INDEX(Sheet1!$B$2:$AF$300,MATCH(A2,Sheet1!$A$2:$A$300,0),C2)))

 E2セルにでも
 =IF(A2="","",MATCH(A2,Sheet1!$A$2:$A$300,0))
 と入れておいてもいいのなら

 D2 =IF(COUNTA(A2:C2)<3,"",SUM(INDEX(Sheet1!$B$2:$AF$300,E2,B2):INDEX(Sheet1!$B$2:$AF$300,E2,C2)))

 参考まで
（笑） 2019/10/12(土) 01:07

やすさん

私も笑さんもB列を1日～AF列を31日としているので、これがずれていると合算対象のセルがずれてしまいます。
計算対象のセルが合っていない場合はこの点を確認してください。
（黄色い循環参照） 2019/10/12(土) 01:24

黄色い循環参照さん
笑さん

ありがとうございました。
お二人のように使いこなせるように頑張ります(^_^)ﾉ
（やす） 2019/10/12(土) 01:29

さらに質問させていただきます。
抽出するシートをシート1
データが入力されているシートをシート2と
したときには
黄色い循環参照さんのような関数のどこを変えればよいのでしょうか？？
いろいろ試したのですが、出来ませんでしたので
教えていただきたいです。

宜しくお願いします。
（やす） 2019/10/21(月) 00:08

=SUM(INDIRECT("シート2!"ADDRESS(MATCH($A$1,シート2!$A$2:$A$251,0)+1,$B$1+1)&":"&ADDRESS(MATCH($A$1,シート2!$A$2:$A$251,0)+1,$C$1+1)))

表がシート2のA2～AF251、
シート1の
A1:品名
B1:合計する初日
C1:合計する最終日
とした場合です。
（黄色い循環参照） 2019/10/21(月) 01:21

この場合、INDIRECTとADDRESSの間の"sheet1"!
のところでエラーがでてしまいます。
何か解消のやり方があるのでしょうか？
（やす） 2019/10/21(月) 01:31

失礼しました、sheet2です。
（やす） 2019/10/21(月) 01:33

すみません。「＆」が抜けていました。
このようにしてください。

 =SUM(INDIRECT("シート2!"&ADDRESS(MATCH($A$1,シート2!$A$2:$A$251,0)+1,$B$1+1)&":"&ADDRESS(MATCH($A$1,シート2!$A$2:$A$251,0)+1,$C$1+1)))

（黄色い循環参照） 2019/10/21(月) 02:40

ありがとうございました！
（やす） 2019/10/21(月) 06:33

コメント返信：

[ 一覧(最新更新順) ]

[[20191011225135]] 『行の合計をするには？？』（やす） ページの最後に飛ぶ

[[20191011225135]]　『行の合計をするには？？』（やす）　ページの最後に飛ぶ