[[20191126115429]]　『労働日数（第2、第4金曜日休みの場合）』（しずく）　ページの最後に飛ぶ

『労働日数（第2、第4金曜日休みの場合）』（しずく）

 いつも助かっています。
 今回は、労働日数の出し方がわからないので
 教えてください。

 今使っている関数は、毎週決まった曜日が休みの
 社員さんなので
 =NETWORKDAYS.INTL(V2,X2,"0100011",$AA$2:$AA$54)
 ↑
 （これは、毎週火曜日休み+会社は土日休み）

 この関数で労働日数をだしています。
 これもこちらで教えていただきました。

 今回の社員さんは、第2、第4金曜日と通常の土日がお休みになります。
 この場合、関数で労働日数をだすのは、無理がありますか？
 まったくおもいつかず困っています。

 教えてください。

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

 単純に特別休暇等を祭日に加えれば良いんじゃないかなぁーと？
（BJ） 2019/11/26(火) 12:28

月間でしたら、全週金曜日出勤のNETWORKDAYS.INTLから、
8～14日の金曜日だけ出勤のNETWORKDAYS.INTLと
22～28日の金曜日だけ出勤のNETWORKDAYS.INTLを引く。

（べん） 2019/11/26(火) 12:39

 祝日リストから第2金曜日または第4金曜日に該当する祝日を除外して
 =NETWORKDAYS(V2,X2,$AA$2:$AA$54)-2
（bi） 2019/11/26(火) 13:32　修正13:39

 祭日表は毎週決まった曜日が休みの人と隔週で休みがある人で共通のものを使っているのだろうか、
 それぞれ別のものになっているのだろうか？
（ねむねむ） 2019/11/26(火) 13:51

 みなさんありがとうございます
 最初の質問がわかりにくくてすみません
 祝日表は、共通のものを使っています。

 	A	B	C	D
 1	1月	12/11	1/10	14
 2	2月	1/11	2/10	16
 3	3月	2/11	3/10	15
 4	4月	3/11	4/10	18
 5	5月	4/11	5/10	13
 6	6月	5/11	6/10	18

 D列に、=NETWORKDAYS.INTL(B1,C1,"0100011",$AA$2:$AA$54)
 この計算式が入っています。　　　　　　　　↑これは会社祝日表です
 Dに労働日数が計算されています。
 この人のお休みは、「毎週火曜日、土日、会社祝日表」です

 今回労働日数を計算したい人の休みは、「第2、第4金曜日、土日、会社祝日表」です
 毎週金曜日休みならいいのですが、第2、第4だけなので変則で
 エクセルで計算できるのかと悩んでいます。

 すみません　わかりにくくて

（しずく） 2019/11/26(火) 13:59

締日が10日限定なら

初日～14日（○）
15日から21日（◇）
22日から28日（○）
28日の翌日から7日後（◇）
28日の8日後から10日まで（○）
と、週ごとにNETWORKDAYS.INTL計算するという方法もあります。
（○は金曜休み、◇は金曜出勤）

（べん） 2019/11/26(火) 15:27

 ＞28日の8日後から10日まで（○）
 ＞（○は金曜休み）

 ＞4	4月	3/11	4/10	18
 の場合

 2019/3/28(木曜）の８日後、つまり4/5(第一金曜日）から10日まで（○）
　　　　　　　　　　　　　　　　　↑
　　　　　　　　　　　　　　　　 出動日じゃないですか？
（半平太） 2019/11/27(水) 12:50

＞祝日表は、共通のものを使っています。
手間にはなるのかもしれませんが、BJさんのアイデアのように、隔週休みの人用の祝日表を別途作っちゃうのが簡単じゃないですかね

 (1) AA2:AA54 を　コピーして　AC2にリンク貼り付け

 (2) AB56 に　2019/1/1　と入力
     AB57はブランク
     AB58 に　2019/2/1
     AB59はブランク

 (3) AB56:AB59を選択して、必要な分だけ下方向へフィルコピー

 (4) AC56に　=AB56+(7-FIND(TEXT(AB56,"aaa"),"土日月火水木金"))+7　と入力
     AC57に　=AB56+(7-FIND(TEXT(AB56,"aaa"),"土日月火水木金"))+21　と入力

 (5) AC56:AC57を選択して、(3)に合わせて下方向へフィルコピー

こうすると、AC列に会社祝日＋第2、第4金曜日のリストが出来ますから、

 =NETWORKDAYS.INTL(B1,C1,"0000011",$AC$2:$AC$100)

該当する人はD列の数式の休日リスト部分を↑みたいに（行は適当に変えて下さい）したら対応出来そうな気がします。

ちなみに、(4)の数式は↓のような考え方をしています。

 (1)各月の1日の曜日が、土曜日から数えて何番目かを確認
 (2)(1)に何日足せば第１金曜日になるかを求め、第１金曜日の日付を特定
 (3)(2)で特定した日付（第１金曜日）に、７を足すと第２金曜日（の日付）に、21を足すと第４金曜日（の日付）になる

（もこな２） 2019/11/28(木) 14:18

半平太さん

チェック漏れでした。
指摘ありがとうございます。

2019/11/26(火) 15:27は無しでお願いします。
（べん） 2019/11/28(木) 15:54

 以下一案。

 ＞D列に、=NETWORKDAYS.INTL(B1,C1,"0100011",$AA$2:$AA$54)
    ↓
   D1セル =NETWORKDAYS(B1,C1,IF({1,0},$AA$2:$AA$54,SMALL(EOMONTH(B1,ROW($A$1:$A$32)-2)-WEEKDAY(EOMONTH(B1,ROW($A$1:$A$32)-2)-4,3)+7*{2,4},ROW($A$1:$A$53))))

 上記数式は、独特の方法で入力する(これ重要）
　　　　　　　　　↓
 ShiftキーとCtrlキーを押しながらEnterキー押下で入力確定（式全体が{}で囲まれて見える）

 その後下方へコピー

（半平太） 2019/11/28(木) 17:25

コメント返信：

[ 一覧(最新更新順) ]

[[20191126115429]] 『労働日数（第2、第4金曜日休みの場合）』（しずく） ページの最後に飛ぶ

[[20191126115429]]　『労働日数（第2、第4金曜日休みの場合）』（しずく）　ページの最後に飛ぶ