[[20200218164645]]　『条件が2つ合ったら抽出・表示させたい』（たすけてください）　ページの最後に飛ぶ

『条件が2つ合ったら抽出・表示させたい』（たすけてください）

あとちょっと、出来そうで出来ない･･･😢助けてください。
フィルタオプションではなく、関数でやりたいのですが

　　　　A　　　　　B　　　　 C　　　　　D　　　　　E　　　　　 F
1　　　番号　　　商品　　売上　　売上月　　仕入月　　担当者
2　　　　1　　　りんご　　100　　　2　　　　　12　　　田中
3　　　　2　　　すいか　　500　　　1　　　　　1　　　鈴木
4　　　　3　　　みかん　　200　　　2　　　　　1　　　鈴木
5　　　　4　　　りんご　　100　　　1　　　　　12　　　佐藤　　
6　　　　5　　　いちご　　400　　　2　　　　　12　　　田中
～
～
21　　売上月
22　　　　　　　　月
23
24
25　　　番号　　担当者　　売上
26
27
28
～
～

A22に2月の「2」を入力したら売上月が2のものを行26以下に表示させたい
（売上月も仕入月も同じような数字を使うためD1とD2～D6の条件が合致したらという意味です）

なので、A26～C28のセルひとつひとつに数式が入る形にしたいのですが｡｡｡

INDEXとMATCHを組み合わせになるのでしょうか？
ご教授いただきたいです。

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

 A26セル：=IFERROR(INDEX(A$1:A$6,SMALL(IF(INDEX(B$2:F$6,,MATCH(A$21,B$1:F$1,0))=A$22,ROW($2:$6),""),ROW(A1))),"")
 B26セル：=IFERROR(INDEX(F$1:F$6,SMALL(IF(INDEX(B$2:F$6,,MATCH(A$21,B$1:F$1,0))=A$22,ROW($2:$6),""),ROW(A1))),"")
 C26セル：=IFERROR(INDEX(C$1:C$6,SMALL(IF(INDEX(B$2:F$6,,MATCH(A$21,B$1:F$1,0))=A$22,ROW($2:$6),""),ROW(A1))),"")
　
（ねむねむ） 2020/02/18(火) 17:30

 どの式もShiftキーとCtrlキーを押しながらEnterキーで式を確定（確定後、式が{}で囲まれればOK）、その後下へフィルコピーしてくれ。
 A21セルに入力した項目にA22セルに入力した値があるデータを抜き出す。
（ねむねむ） 2020/02/18(火) 17:32

え！！すごいんですけど！
出来ました。ありがとうございます！
すごすぎてポカーンです(　ﾟдﾟ)

ShiftキーとCtrlキーを押しながらEnterキー
　↑
これって、なんという方式ですか？
初めて使用しました。
（たすけてください） 2020/02/19(水) 08:59

＞これって、なんという方式ですか？
ねむねむさんじゃないけど、「配列数式」というやつですね
http://office-qa.com/Excel/ex69.htm

（もこな２） 2020/02/19(水) 09:49

初めて知りました！
また一つ勉強になりました。
本当に大変感謝です。

ひとつ質問良いですか？
ROW(A1)の部分ですがフィルコピーによってこうなるのですが正解ですか？
因みに回答結果は正常に表示されます。
↓
ROW(A1)
ROW(A2)
ROW(A3)

逆に手入力で全てROW(A1)に修正すると回答結果は表示されなくなります。

（たすけてください） 2020/02/19(水) 10:26

 >ROW(A1)の部分ですがフィルコピーによってこうなるのですが正解ですか？ 
 それで正解。
 ROW(A1)→1
 ROW(A2)→2
 ROW(A3)→3
 と値を返す。
 つまり式を入力した1行目で1を、2行目で2を、3行目で3を…と1からの昇順の値を得たいためにそのようにしている。
（ねむねむ） 2020/02/19(水) 11:13

よかったです
ありがとうございました＾＾
（たすけてください） 2020/02/19(水) 11:16

コメント返信：

[ 一覧(最新更新順) ]

[[20200218164645]] 『条件が2つ合ったら抽出・表示させたい』（たすけてください） ページの最後に飛ぶ

[[20200218164645]]　『条件が2つ合ったら抽出・表示させたい』（たすけてください）　ページの最後に飛ぶ