[[20200624110528]]　『横のデータをシートごとに分けて参照したい』（ねこんばっと）　ページの最後に飛ぶ

『横のデータをシートごとに分けて参照したい』（ねこんばっと）

日氏名シフト出勤退勤休憩氏名シフト出勤退勤休憩氏名シフト出勤退勤休憩
1 三好幸江早 7:00 16:00 1:00 田中麻央他 8:00 18:00 1:00 速水孝真休 0:00 0:00 0:00
2 三好幸江他 7:00 17:00 1:00 田中麻央他 7:00 18:00 1:00 速水孝真夜 16:30 23:59 2:00
3 三好幸江他 8:30 19:30 1:00 田中麻央早 7:00 16:00 1:00 速水孝真明 0:00 9:30 2:00
4 三好幸江他 9:00 20:00 1:00 田中麻央他 9:00 16:30 1:00 速水孝真休 0:00 0:00 0:00

上記のようなデータが縦に一か月分、横に30名程続きます。(このデータのシート名は”出勤簿まとめ”です。)

このデータを日付ごとのシートに分けて氏名順に表示させたいのです。

表示させるシート名は日付の「1」～「30」まであります。

シート「1」に

氏名　シフト　出勤退勤　休憩
三好幸江　早　7:00 16:00　1：00
田中麻央　他　8:00 18:00　1：00
速水孝真　休　0:00　0:00　　0：00

シート「2」に

氏名　シフト　出勤退勤　休憩
三好幸江　早　7:00 16:00　1：00
田中麻央　他　7:00 18:00 1:00
速水孝真　夜 16:30 23:59 2:00

シート「3」～「31」にも同様に。

どのようにすれば良いか、わからないので教えてください。
インデックス関数を試みましたがわからず、すみません・・・。

＜使用 Excel：Excel2007、使用 OS：Windows7 ＞

 各シート

 A2 =IFERROR(INDEX(INDEX(出勤簿まとめ!B:L,MATCH(-LOOKUP(1,-RIGHT(CELL("filename",A2),{1,2})),出勤簿まとめ!$A:$A),0),(ROW(A1)-1)*5+1),"")

 範囲コピー。

 ※ファイルが一度でも保存されていること。
（GobGob） 2020/06/24(水) 13:31

 A2 =IFERROR(INDEX(INDEX(出勤簿まとめ!B:L,MATCH(-LOOKUP(1,-RIGHT(CELL("filename",A2),{1,2})),出勤簿まとめ!$A:$A,0),0),(ROW(A1)-1)*5+1),"")

 に変更ｗ。
（GobGob） 2020/06/24(水) 13:34

 別案で、

       [A]           [B]        [C]	[D]	[E]
 [1]    1				
 [2]    氏名        シフト      出勤    退勤	休憩
 [3]    三好幸江     早         7:00    16:00   1:00
 [4]    田中麻央     他         8:00    18:00   1:00
 [5]    速水孝真     休         0:00     0:00   0:00

 上のレイアウトはシート「1」のものです、
 Aの1はシート名です。　A1に、

 =MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,2)

 と入力すればシート名を表示できます。

 その後、A3に

 =OFFSET(出勤簿まとめ!$A$1,$A$1,ROW(A1)*5+COLUMN(A1)-5)

 と入力して右、下方向にコピーすればこうなります。
 時間の表示、ゼロの非表示など適当な設定にしてください。

 このシート全体をコピーしてシート「2」以下にコピーしてください。

（tora） 2020/06/24(水) 13:43

早速のご回答ありがとうございます。
御指南いただいた通りにやってみて、できました！
本当にありがとうございます。

OFFSET関数が苦手でしたが、勉強になりました。
またシート名を表示させる関数もありがとうございます。
助かりました！
（ねこんばっと） 2020/06/24(水) 17:05

コメント返信：

[ 一覧(最新更新順) ]

[[20200624110528]] 『横のデータをシートごとに分けて参照したい』（ねこんばっと） ページの最後に飛ぶ

[[20200624110528]]　『横のデータをシートごとに分けて参照したい』（ねこんばっと）　ページの最後に飛ぶ