[[20200901163358]]　『SUMIFSで条件数を可変させたい』（mild）　ページの最後に飛ぶ

『SUMIFSで条件数を可変させたい』（mild）

＝SUMIFS（合計対象範囲, 条件範囲1, 条件1, 条件範囲2, 条件2, 条件範囲3, 条件3）

上記の様に、最大3条件に対応出来るようなSUMIFS関数を使用しています。

条件1、条件2、条件3　の全てに条件が入っていれば上手くいきますが、
何れかの条件が空白の場合が集計されなくてゼロになります。

なって欲しいのは、条件の入力があるものだけで絞り込んで集計する。
入力が無い条件は無視する。

例1：条件1と条件3のみ入力があったら条件1と条件3のみで集計し条件2は無視する。
例2：条件3のみ入力があったら条件3のみで集計し、条件1と条件2は無視する。

＜使用 Excel：Office365、使用 OS：Windows10 ＞

条件が空白だった場合は「*」に置き換えるような式にしてみては？
（条件が無い列は無視、ではなくて、全件対象にする）
（???） 2020/09/01(火) 17:05

ありがとうございます。

ワイルドカードは文字には使えると思いますが
今回は数字ですので使えないようです。
（mild） 2020/09/01(火) 17:36

 >最大3条件に対応出来るようなSUMIFS関数を使用しています。 
 >条件1、条件2、条件3　の全てに条件が入っていれば上手くいきますが

 結局使えてないんですよね。
 もったいぶらずに、ちゃんとした条件書いたらどうですか。

（Why） 2020/09/01(火) 19:47

 >今回は数字ですので使えないようです。
どういうこと?

（EXC） 2020/09/01(火) 20:07

=Sum(If((条件1)*(条件2)*(条件3),合計範囲,0))
で、適切に条件を設定すればできると思います。

すでに指摘がある通りですが、クリティカルな解決が欲しいようなら
質問を具体的にしてください。
（DS） 2020/09/01(火) 20:15

 元表には、どの列にどんな数値が入力されていて
 どんな条件で合計するのか、わかるように説明してください。

 テキトーな回答でいいのなら･･･

 条件セルが空白の場合、条件を
 ">0"　　　　← 0より大きい
 とか
 "<"&10^16　 ←正の数、負の数に関係なくすべての数値
 とかにする

 以上
（笑） 2020/09/01(火) 20:20

サンプル作成しました。

	A	B	C	D
1	A       B        C     金額
2	719 	1	リンゴ	100 
3	719 	2	みかん	200 
4	719 	1	ぶどう	150 
5	724 	2	リンゴ	50 
6	728 	1	みかん	40 
7	728 	1	リンゴ	250 
8	719 	1	リンゴ	120 
9	790 	2	ぶどう	80 
10				
11	719	1	リンゴ	220

D12=SUMIFS(D2:D9,A2:A9,A11,B2:B9,B11,C2:C9,C11)

11行に3条件を入力した場合は上手くいきますが
3条件の内、1つでも空白だと集計できません。

（mild） 2020/09/01(火) 22:14

 ↓ でできませんか？
 =SUMIFS(D2:D9,A2:A9,IF(A11="",">0",A11),B2:B9,IF(B11="",">0",B11),C2:C9,IF(C11="","*",C11))

 以上
（笑） 2020/09/01(火) 22:37

 DSUM 関数の方がいいかも･･･

 A10:C11 を ↓ のようにする

	A	B	C	
10	A	B	C	← 1行目の見出し
11	719		リンゴ

 D12 =DSUM(A1:D9,D1,A10:C11)

 参考まで
（笑） 2020/09/01(火) 22:47　変更 22:54

(笑)さん、両方出来ました。ありがとうございます。

DSUMの方が、データが空白の場合の置換もワイルドカードも使わなくていいので計算式が簡単でいいですね。しかし困った事もあります。条件が数字の場合は問題無いのですが、テキストの場合、先頭からの部分一致でも抽出して集計されてしまいます。ここは完全一致で抽出して欲しいです。因みにSUMIFSはテキストは部分一致でなくて完全一致で抽出します。一長一短ですね。DSUMの方がシンプルですのでこちらを使いたいです。
テキスト抽出の場合、先頭一致でなくて完全一致に出来たら完璧ですが、、、、、、、？

（mild） 2020/09/02(水) 00:24

 条件を入力する際に
 ="=あいうえお"
 のようにセルに「=あいうえお」と表示されるように入力すると完全一致で検索する。
（ねむねむ） 2020/09/02(水) 09:22

 あ、セルの表示形式を文字列にしてから「=あいうえお」と入力する、あるいは「'=あいうえお」と入力する、でも。
（ねむねむ） 2020/09/02(水) 09:25

 >完全一致に出来たら完璧ですが、、、、、、、？
 ドロップダウンリストを使用するとか?

（asd） 2020/09/02(水) 10:34

 完全一致にするために、頭にいちいちイコールをつけるのはメンドーと思うなら
 手入力する条件と、数式の条件範囲を別にするとか･･･

 もちろん2か所に入力するということではありません。

 別シートでもどこでもいいですが、例えば同じシートの F1:H2 だとして
 ↓ のようにする。

	F	G	H	
1	A	B	C	←A1:C1の見出しを入力
2

 F2 =IF(A11="",">0",A11)
 G2 =IF(B11="",">0",B11)　　← F2の式をコピー
 H2 =IF(C11="","","="&C11)

 合計の式：=DSUM(A1:D9,D1,F1:H2)
                          ~~~~~
 条件は A11:C11 に入力
 C11には「リンゴ」とだけ入力すれば完全一致検索になります。

 以上、参考まで
（笑） 2020/09/02(水) 11:19

ここ数日パソコンに触れませんで返事が遅くなって申し訳ありません。
(笑)さんはじめ沢山の方にご教示頂きありがとうございました。
全て内容を拝見し確認し、了解致しました。心よりお礼申し上げます。
（mild） 2020/09/09(水) 11:31

コメント返信：

[ 一覧(最新更新順) ]

[[20200901163358]] 『SUMIFSで条件数を可変させたい』（mild） ページの最後に飛ぶ

[[20200901163358]]　『SUMIFSで条件数を可変させたい』（mild）　ページの最後に飛ぶ