[[20201027184501]]　『複数条件の関数について』（OSK）　ページの最後に飛ぶ

『複数条件の関数について』（OSK）

こんちは
よろしくお願いします。

O列　金額(数値)
Q列　日付(2020/10/20など)
R列　金融機関名（○○銀行　△△信金など）

　B　・　・　・　・　O　　・　　Q　　　R
3　　見出し行
4
5
6
・
・
35

同一シート内に
日付　　金融機関名　　金額
10/20　　○○　　　　10,000
何月何日に、金融機関と金額を表示させる関数をご教授お願いします。
金融機関の検索条件は部分一致としたい（例；*○○*　、　*△△*など）
対象は　Z列、　　AA列です

      V　　　　　Z　　　　　　AA
48
49
50
51
・
V48=IF(ROW(A1)>COUNT($AD$4:$AD$35),"",INDEX($Q$4:$Q$35,SMALL($AD$4:$AD$35,ROW(A1))))　下フィル
日付は、上記にて抽出しています。
sumifsを使うのか？な

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

補足説明
こんちは→こんにちは【訂正】
わかりにくいでしょうか？
V＝日付抽出
Z＝金融機関を抽出　○○　△△など
AA＝日付の合計を算出
要約すると同一日付に同一金融機関からいくらの合計金額になるかを抽出したいです

      V　　　　　Z　　　　　　AA
48
49
50
51
・
（OSK） 2020/10/27(火) 20:16

質問は、
日付と金融機関名と金額等の記録されたデータを日付別／金融機関別に集計をしたい
ということでよいでしょうか？

以下は上記の解釈で良ければ、の話ですが、
私なら、ピボットテーブルを使用します。
ピボットテーブルを表示したいセルを選択してからピボットテーブルを作成し、
[デザイン]タブの[レイアウト]-[レポートのレイアウト]から「表形式」を選択すると、
作りたい表が作れるのではないかと予想します。
（場合によっては、「同じデータを繰り返す／繰り返さない」の設定も必要かも）

いかがでしょうか？
（you） 2020/10/27(火) 23:30

（you）さん　ありがとうございます。
日付と金融機関名と金額等の記録されたデータを日付別／金融機関別に集計をしたい
ということでよいでしょうか？
はい、その通りです。
＞私なら、ピボットテーブルを使用します。
↑ピボットテーブルも選択の一つと思いますが
出来れば関数で出来ないものかと・・・条件が難しいですか？
よろしくお願いします。
（OSK） 2020/10/28(水) 16:21

 ちょっと確認だけ

 Q4:R35 に同じ日付で、同じ金融機関が2件以上あるんですか？
 それをV48以降で1行にまとめるってこと？

	Q	R
4	10/20	○銀行
5	10/20	○銀行

 　　　　　　↓　1行にまとめる？

	V	Z
48	10/20	○銀行

 ＞V48=IF(ROW(A1)>COUNT($AD$4:$AD$35),"",INDEX($Q$4:$Q$35,SMALL($AD$4:$AD$35,ROW(A1))))

 この式の「AD4:AD35」には何が入力されてるんですか？
 数式なら、その式を提示してください。

 ＞金融機関の検索条件は部分一致としたい
 R列の金融機関名をそのままZ列に表示すればいいんですよね？
 なんで部分一致？
 完全一致ではダメなんですか？

 以上
（笑） 2020/10/28(水) 19:34

（笑）さんに続いてしまいますが、確認です。

	Q	R        S（金額:仮）
4	10/20	○銀行   10,000
5	10/20	○銀行　 15,000
6       10/20   △銀行    8,000
7       10/21   △銀行   20,000
8       10/22   ◇銀行   10,000
9       10/22   〇銀行    5,000
10　　　10/22   ◇銀行　 10,000

というデータがあった場合の集計表は、

	V	Z　　　  AA　    
48	10/20	○銀行　 25,000
49      10/20   △銀行    8,000
50      10/21   △銀行   20,000
51      10/22   ◇銀行   20,000
52　　　10/22 　〇銀行    5,000

以上のような表を作りたいという事で良いですか？
もしそうならば、

＞V48=IF(ROW(A1)>COUNT($AD$4:$AD$35),"",INDEX($Q$4:$Q$35,SMALL($AD$4:$AD$35,ROW(A1))))　下フィル
＞日付は、上記にて抽出しています。

これで「重複しない日付」を抽出したとしても、「同じ日に取引をした金融機関」（日付が重複する）を表内に表すことができないので、ここから見直しが必要になると思います。
※（笑）さんのご指摘の通り、セル「AD4：AD35」のデータがどのようなものか判りませんので計算結果を試していません。
※ただ、重複しないリストを作る方法として紹介されていた数式に似てるなと思っているだけです。
（you） 2020/10/28(水) 23:09

（笑）さん
（you）さん
返事ありがとうございます。
いくつかの指摘を拝見して表の構成を若干見直しが必要と感じました。
やりたいことは　youさんの作成いただいた表そのものです(並びが違いますが)
以下のような配置です。

	O	Q        R（金額:仮）
4	10,000　10/20	○○
5	20,000　10/20	○○
6        5,000  10/20   △△
7       15,000　10/21   △△
8       30,000　10/22   ◇◇
9       10,000　10/22   〇○
10　　　14,000　10/22   ◇◇

というデータの集計表は、以下の通りです

	Z	AA　　　  AB　    
37	10/20	○○　 30,000
38      10/20   △△    5,000
39      10/21   △△   15,000
40      10/22   ◇◇   44,000
41　　　10/22 　〇○   10,000
続く
上記の場合の　Z37【Z列】、　AA37【AA列】、　AB37【AB列】の
数式をよろしくお願いします。
 ＞＞V48=IF(ROW(A1)>COUNT($AD$4:$AD$35),"",INDEX($Q$4:$Q$35,SMALL($AD$4:$AD$35,ROW(A1)))) 
＞ この式の「AD4:AD35」には何が入力されてるんですか？
＞ 数式なら、その式を提示してください
　=IF(COUNTIF($Q$4:Q4,Q4)=1,ROW(A1),"")　下ﾌｨﾙ
　上記から日付を抽出したのですが、何か意味なさそう？

＞＞金融機関の検索条件は部分一致としたい
＞ R列の金融機関名をそのままZ列に表示すればいいんですよね？
＞なんで部分一致？
＞完全一致ではダメなんですか？
表中に金融機関名のほかに、メモ程度の文言が書かれていたため
部分一致がいいのかなと思い書き込みましたが、現在少し見直し
金融機関名のみ　○○　△△　◇◇とし、【R列】S列にメモとしましたので
完全一致でOKです。
この返答で理解できますでしょうか？

（OSK） 2020/10/29(木) 05:32

 AD列の式を変更します。COUNTIF → COUNTIFS に

 AD4 =IF(COUNTIFS($Q$4:Q4,Q4,$R$4:R4,R4)=1,ROW(),"")
 AD35まで下コピー
 ※ROW(A1) ではなく ROW()

 Z37 =IFERROR(INDEX(Q:Q,SMALL($AD$4:$AD$35,ROW(A1))),"")
 右のAA37にコピー
 Z37の表示形式を「日付」に

 AB37 =IF(Z37="","",SUMIFS($O$4:$O$35,$Q$4:$Q$35,Z37,$R$4:$R$35,AA37))

 Z37:AB37 を下コピー

 以上
（笑） 2020/10/29(木) 11:17

（笑）さん
ありがとうございます。
バッチリです。(^^)
ちなみに日付ですが、昇順　小→大は出来ないですよね？
書込順に抽出しているようなので・・・

（OSK） 2020/10/29(木) 15:18

 日付昇順
 AD列の式を変更します。

 AD4 =IF(COUNTIFS($Q$4:Q4,Q4,$R$4:R4,R4)=1,Q4+ROW()/100,"")
 表示形式「標準」or「日付」
 AD35まで下コピー

 Z37 =IFERROR(INT(SMALL($AD$4:$AD$35,ROW(A1))),"")
 表示形式「日付」

 AA37 =IF(Z37="","",INDEX(R:R,MOD(SMALL($AD$4:$AD$35,ROW(A1)),1)*100))

 Z37とAA37を下コピー

 AB37 は前回と同じ SUMIFS

 検証してません
（笑） 2020/10/29(木) 17:07

（笑）さん
ありがとうございました。
できました　感謝です。<(_ _)>
また、行き詰まったときにはよろしくお願いします。
（OSK） 2020/10/29(木) 17:48

コメント返信：

[ 一覧(最新更新順) ]

[[20201027184501]] 『複数条件の関数について』（OSK） ページの最後に飛ぶ

[[20201027184501]]　『複数条件の関数について』（OSK）　ページの最後に飛ぶ