[[20201129141142]]　『IFとCOUNTAとVLOOKUPの組み合わせ』（laulea）　ページの最後に飛ぶ

『IFとCOUNTAとVLOOKUPの組み合わせ』（laulea）

Sheet1のA1に、
COUNTAで下記の様にVLOOKUPで検索した列の両方に日付が入力されていた場合のみ(1)の日付を、Sheet1のA1に、それ以外の場合は、空白にしたいのですが･･･。両方に入力されている場合は、正しく(1)の日付がでますが、それ以外の場合には、M33.1.0と表示されてしまいます。
どの様にしたら、空白にできますか?
VLOOKUPで、

 検索値 (1)Sheet1 D1
             範囲 DATA! A1:D20
             列  2
             検索方法 FALSE
 と
        (2)検索値 Sheet1 D1
            範囲 DATA! A1:D20
            列  4
            検索方法 FALSE

自分なりに作ってみた式です↓
初心者の為、説明がうまくできずにすみません。宜しくお願い致します。

=IF(COUNTA(VLOOKUP($D$1,DATA!$A$1:$D$20,2,FALSE),VLOOKUP($D$1,DATA!$A$1:$D$20,4,FALSE))=2,VLOOKUP($D$1,DATA!$A$1:$D$20,2,FALSE),"")

＜使用 Excel：Excel2013、使用 OS：Windows8 ＞

 VLOOKUP関数の戻り値が空白の場合0が返るので
 1)表示形式で0の場合は空白にする
 ggge.m.d;;;
 2)検索範囲の日付が入るべきセルが空白なら=""としておく
 等

（どん） 2020/11/29(日) 15:31

 COUNTA → COUNT にして
 =IF(COUNT(VLOOKUP($D$1,DATA!$A$1:$D$20,4,FALSE)&""),IFERROR((VLOOKUP($D$1,DATA!$A$1:$D$20,2,FALSE)&"")*1,""),"")
                                                ~↑~                                               ~↑~

 または「M33.1.0」（要するに「0」）を表示形式で非表示でもいいのなら

 =IF(VLOOKUP($D$1,DATA!$A$1:$D$20,4,FALSE)>0,VLOOKUP($D$1,DATA!$A$1:$D$20,2,FALSE),"")
 表示形式～ユーザー定義　ge.m.d;;　← セミコロンを2つつける

 ところで、なんのために絶対参照にしてるんですか？

 以上
（笑） 2020/11/29(日) 16:00　数式ちょっと変更 16:28

 ＞=IF(COUNT(VLOOKUP($D$1,DATA!$A$1:$D$20,4,FALSE)&""),IFERROR((VLOOKUP($D$1,DATA!$A$1:$D$20,2,FALSE)&"")*1,""),"")

 =IF(SUMIF(DATA!$A$1:$A$20,$D$1,DATA!$D$1:$D$20),IFERROR((VLOOKUP($D$1,DATA!$A$1:$D$20,2,FALSE)&"")*1,""),"")

 でも
（笑） 2020/11/29(日) 17:30

遅くなって申し訳ありません。皆さんありがとうございました!色々な方法があるのですね。勉強になります。本当にありがとうございました!!
（laulea） 2020/12/02(水) 10:41

（笑）さん DATAを入力してあるシートから個人個人の届出書類をプリントアウトするのに、ひな形を１つ作っておいて(書類の様式が度々変更になるので)、VLOOKUPで探して必要に応じて必要な人の分の書類を印刷したいと思いまして･･･この方法しか思いつきませんでした(^^;)　
色々と教えて頂き、アリがどうございました。
（laulea） 2020/12/02(水) 10:47

コメント返信：

[ 一覧(最新更新順) ]

[[20201129141142]] 『IFとCOUNTAとVLOOKUPの組み合わせ』（laulea） ページの最後に飛ぶ

[[20201129141142]]　『IFとCOUNTAとVLOOKUPの組み合わせ』（laulea）　ページの最後に飛ぶ