[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『同じ条件(2点)の複数の対象者をリストとして表示させる関数』(nkn)
お目に留めていただきありがとうございます。
指定の時間帯に出席する人が複数人おり、
また所属ごとに表示されるように作成したいと考えております。
以下で記載している【シート名:「グループ割」】へ【シート名:「対象者リスト」】の
I列で入力した「時間」と「所属」を条件に「氏名」が表示されるように出来ないでしょうか。
また「氏名」は複数人いるため昇順で表示されるようにできればと思っております。
【シート名:「対象者リスト」】※元シート(組み込む関数なし)
A B C D E F G H I 1 出席 書類 性別 ID番号 氏名 所属 参加日 時間 ―――――――――――――――――――――――――――――― 2 1 〇 〇 女 123 田中 ABC 1/15 10:00 3 2 〇 × 男 456 伊藤 DEF 1/15 10:00 4 3 × × 女 789 吉田 GHI 1/15 10:00 5 4 〇 〇 男 101 川元 ABC 1/15 10:00 6 5 〇 〇 女 121 山田 GHI 1/15 10:15 7 8 〇 〇 女 314 伏見 DEF 1/15 10:00 8 9 〇 〇 男 156 井上 GHI 1/15 10:00 9 10 〇 〇 女 171 町田 ABC 1/15 10:15
・時間のデータ型は「時刻」表示となっております。
【シート名:「グループ割」】※こちらのシートに関数を組み込みたいです。
「対象者リスト」のシートを元に以下のように
表示されるように関数を組み込みたいと思っております。
※10:00の時間に出席する人を所属ごとに結果が表示される。
ABCという所属の人はB列に表示、DEFの所属の人はC列に表示、GHIの所属の人はD列に表示
また複数人(所属での参加者が最大10名)出席するのでVLOOKUPの関数では難しいのではないかと思いました。
A B C D 1 ABC DEF GHI ―――――――――――――――――――――――――― 2 田中 伊藤 吉田 3 川元 伏見 井上 4 10:00 〇〇 〇〇 5 〇〇 6 〇〇 7 〇〇 8★合計12名 〇〇 9 10 11 ★=COUNT(A2:D10) 〇=他参加者氏名を省略してます
・時間のデータ型は「時刻」表示となっております。
・10:00〜12:30まで作成してます。
・A2:A6とA7:A10はセルを結合して中央揃えにしてます。
全般的にレイアウトの説明が不明瞭で申し訳ございませんが
ご教示いただけますと幸いです。
宜しくお願い致します。
< 使用 Excel:Excel2016、使用 OS:Windows10 >
>また「氏名」は複数人いるため昇順で表示されるようにできればと思っております。 「昇順」とは何の昇順? もしかして上に詰めて表示のこと?
対象者リストのB列(出席)は関係ないんですか? そこが×になっていても抽出するってこと?(F3セルの吉田さんのように)
昇順というのが上に詰めて表示のことなら
1)対象者リストのB列は関係ない
B2 =IFERROR(INDEX(対象者リスト!$F:$F,AGGREGATE(15,6,ROW($F$2:$F$100)/((対象者リスト!$G$2:$G$100=B$1)*(対象者リスト!$I$2:$I$100=$A$2)),ROW(A1))),"")
2)対象者リストのB列も関係ある
B2 =IFERROR(INDEX(対象者リスト!$F:$F,AGGREGATE(15,6,ROW($F$2:$F$100)/((対象者リスト!$B$2:$B$100="〇")*(対象者リスト!$G$2:$G$100=B$1)*(対象者リスト!$I$2:$I$100=$A$2)),ROW(A1))),"")
右・下コピー ※実際の表は配置が違っていても、ROW(A1)の「A1」を変更しないように ※対象者リストは最大100行目までとしています。実情に合わせて下さい ※対象者リストのB列、×に対応するのは普通は○(丸印)です。例示では 〇(漢数字のゼロ)になっていますが、あえてそうしてるんですか?
>=COUNT(A2:D10) これは参加人数を出すための式? だったら COUNT ではできません。COUNTA でも無理(数式の結果なので)
=COUNTIF(B2:D10,"?*") としてください。、
以上 (笑) 2020/12/09(水) 19:47
早々にお目に留めていただき誠にありがとうございます。
ご連絡が遅くなり申し訳ございません。
>「昇順」とは何の昇順?
もしかして上に詰めて表示のこと? ・申し訳ございません、上に詰めて表示のことでございました。
>対象者リストのB列(出席)は関係ないんですか?
そこが×になっていても抽出するってこと?(F3セルの吉田さんのように)
B列の「出席」は出席後の管理をするためだけですので今回のリストには不要な項目となります。
ややこしい項目があり申し訳ございません。
またご教示いただきました下記関数で無事に作成ができました。
本当にありがとうございます。
1)対象者リストのB列は関係ない
B2 =IFERROR(INDEX(対象者リスト!$F:$F,AGGREGATE(15,6,ROW($F$2:$F$100)/((対象者リスト!$G$2:$G$100=B$1)*(対象者リスト!$I$2:$I$100=$A$2)),ROW(A1))),"")
>=COUNT(A2:D10) これは参加人数を出すための式? だったら COUNT ではできません。COUNTA でも無理(数式の結果なので)
=COUNTIF(B2:D10,"?*") としてください。、
こちらについてもご教示いただきありがとうございます。
無事に合計人数も反映されました。
宜しくお願い致します。
(nkn) 2020/12/10(木) 11:41
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.