[[20201223102209]]　『複数条件を満たした連番を自動で振りたい』（カカロット）　ページの最後に飛ぶ

『複数条件を満たした連番を自動で振りたい』（カカロット）

Ｂ１に日付、Ｃ１に番号とタイトルがあり、２行目からはタイトル通りのデータが並んでいます。
Ａ列にＢ列とＣ列が同じなら同じ、どちらかが異なるなら+1になる連番を自動で振り分けたいのですが可能でしょうか。
行には空欄を含みます。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 >行には空欄を含みます。
空白の場合は、どうするのか？ですが
A2セルに
=IF(B2<>C2,SUM($A$1:A1)+1,"同じ")
A1セルは空白の事
（はまちゃん） 2020/12/23(水) 10:47

 表の簡単な例を示してもらえないか？
（ねむねむ） 2020/12/23(水) 11:19

 ＞行には空欄を含みます。
 　↑ は途中が空白になるってこと？

	A	B	C
1	連番	日付	番号
2	1	12/1	123
3	1	12/1	123
4	2	12/1	345
5	3	12/2	345
6	3	12/2	345
7	4	12/2	567
8			
9	4	12/2	567
10			
11	5	12/3	123
12

 A2 =IF(COUNT(B2:C2)<2,"",MAX($A$1:A1)+(COUNTIFS($B$2:B2,B2,$C$2:C2,C2)=1))
 下コピー

 こういうこと？
（笑） 2020/12/23(水) 11:32

 補足

 同じ日付と番号の組み合わせが、他のデータを挟んで、また出てくることはない。
 つまり上の表で言うと、例えば7行目に「12/1、123」が来ることはない、ということを前提にしています。

 以上
（笑） 2020/12/23(水) 11:43

＞＞ねむねむ様
説明が下手で申し訳ありません。
（笑）様が書いてくださった表のとおりです。

＞＞（笑）様
7行目に「12/1、123」が来る場合もあるのですが、その場合どのように式を変更すればよいでしょうか。

（カカロット） 2020/12/23(水) 14:12

 7行目が「12/1、123」だったら「1」？

 A2 =IF(COUNT(B2:C2)<2,"",IF(COUNTIFS($B$2:B2,B2,$C$2:C2,C2)=1,MAX($A$1:A1)+1,LOOKUP(1,0/(($B$1:B1=B2)*($C$1:C1=C2)),$A$1:A1)))
 下コピー

 こういうこと？
（笑） 2020/12/23(水) 14:39

コメント返信：