[[20210420142419]]　『特定の文字があると別の文字に変換する数式の追加』（ツー）　ページの最後に飛ぶ

『特定の文字があると別の文字に変換する数式の追加』（ツー）

=SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0),"｜",""),"＝","") この数式に｢〇｣の文字があると｢－｣を書き込む数式を追加する方法はどの様にすれば宜しいですか？

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

適当です。

 =IF(FIND("〇",SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0),"｜",""),"＝",""))>0,"－",SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0),"｜",""),"＝",""))
（余計なお世話） 2021/04/20(火) 14:35

 具体例を出して説明できませんか？
 〇を－に置き換えればいいのなら SUBSTITUTE を追加するだけですけど･･･

 =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0),"｜",""),"＝",""),"〇","－")

 ところで、〇は丸印ではなく漢数字のゼロ（二〇二一のゼロ）ですけど、それで合ってますか？

 以上
（笑） 2021/04/20(火) 15:00

 余計なお世話さんの方の場合はFIND関数で検索文字がない場合、0を返すのではなく
 エラーになるのと文字置き換え後に検索する必要はないことから
 =IF(ISERROR(FIND("〇",VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0))),SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0),"｜",""),"＝",""),"－")
 になるかと。
（ねむねむ） 2021/04/20(火) 15:07

あっ、解決しました（笑）
初歩的なミスですね。
皆さんありがとうございました！
エクセルを良くご存じの方々が多くレスが早いことにビックリしています。

（ツー） 2021/04/20(火) 15:12

ねむねむ様

ご指摘ありがとうございます。

質問者さんへ

同じような質問をされているかたがいるようなので、助けてあげたらいかがですか。
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q12242009072
（余計なお世話） 2021/04/20(火) 15:38

もう一つ質問させてください。
VLOOKUP($B3,Sheet1!$B:$N,COLUMN()-1,0)の所で、Sheet1のB3～B30とE3～N30までに範囲を変更する場合はどの様にすれば宜しいですか？

（ツー） 2021/04/20(火) 18:29

またまた適当です。

 =VLOOKUP($B3,Sheet1!$B3:$N30,COLUMN()-1+3,0)
（余計なお世話） 2021/04/20(火) 18:35

コメントありがとうございます。
C3～C30とD3～D30は範囲に入れたく無いです。
書き方が下手で申し訳ないです。
（ツー） 2021/04/20(火) 18:44

範囲に入れたくないとはどういう意味ですか？

この数式はどこの列に入れて使うのでしょうか。

（余計なお世話） 2021/04/20(火) 18:48

 式を入れるのが「C列」からなら
 =VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN()+1,0)

 または、どの列からでも
 =VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN(D3),0)

 こういうこと？
（笑） 2021/04/20(火) 19:09

Sheet2のC3に入れている数式で今はSheet1の$B:$Nの範囲から抽出しますが
sheet1のC列とD列は抽出範囲から除外したいです。
（ツー） 2021/04/20(火) 19:14

 ＞=VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN()+1,0)
 ＞=VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN(D3),0)

 　　↑ ではダメだったってこと？

 どうなったのか、具体的に説明してください。
 こちらでは E列からN列 の値が返ってますけど？

 ついでに言っておくと ↓ でもいいかも
 =INDEX(Sheet1!E$3:E$30,MATCH($B3,Sheet1!$B$3:$B$30,0))

 以上
（笑） 2021/04/20(火) 19:47

無事に解決しました、ありがとうございました。
（ツー） 2021/04/20(火) 20:15

すいません、最後にもう一点ほど質問させてください。
sheet2のC3に
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN(D3),0) ,"｜",""),"＝",""),"〇","－")
の関数式が入力されています。
sheet2のB3が空白の時は｢#N/A｣と表示されます。この#N/Aを表示させない方法はありますか？
（ツー） 2021/04/22(木) 17:24

懲りずに適当です。

 =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(IFERROR(VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN(D3),0),"｜＝"),"｜",""),"＝",""),"〇","－")
（余計なお世話） 2021/04/22(木) 17:57

 ＞sheet2のB3が空白の時

 空白時の #N/A だけに対応できればいいのなら
 ↓ で十分（ムダな VLOOKUP を実行しなくて済みます）

 =IF($B3="","",SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(VLOOKUP($B3,Sheet1!$B$3:$N$30,COLUMN(D3),0),"｜",""),"＝",""),"〇","－"))

 B3が空白ではないのに出る#N/A（B3の値が Sheet1のB列にない場合）も含めるのなら
 IFERROR を使う

 以上
（笑） 2021/04/22(木) 18:07

コメント返信：

[ 一覧(最新更新順) ]

[[20210420142419]] 『特定の文字があると別の文字に変換する数式の追加』（ツー） ページの最後に飛ぶ

[[20210420142419]]　『特定の文字があると別の文字に変換する数式の追加』（ツー）　ページの最後に飛ぶ