[[20210523170435]]　『条件付き書式』（ｔｋ）　ページの最後に飛ぶ

『条件付き書式』（ｔｋ）

すみません、教えてください。

　　Ａ　Ｂ　Ｃ　Ｄ　Ｅ
１　Ａ　Ａ　Ｃ　　　色　・・・１
２　Ａ　Ｃ　Ｃ　　　色　・・・２
３　Ｃ　Ａ　Ａ　　　色　・・・３
４　Ｃ　Ｃ　Ａ　　　色　・・・４
５　Ｃ　Ａ　Ｃ　　　色　・・・５
６　Ｂ　Ａ　Ｃ　　　　　・・・６
７　Ａ　Ｂ　Ｂ　　　　　・・・７

・・・のように１～５のパターンだけＥ列のセルに色づけしたいです。
方法を教えて下さい。
よろしくお願いします。

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

 エラー処理入ってないけど、こんな感じで良いんじゃないですかね？
 =MATCH(A1&B1&C1,{"AAC","ACC","CAA","CCA","CAC","BAC","ABB"},0)
（Jog） 2021/05/23(日) 17:40

 ああ、5パターンだけだったのね。
 7パターンでやっちゃった。

（Jog） 2021/05/23(日) 17:42

大変申し訳ありませんでした。説明不足でした。

Ａ列、Ｂ列、Ｃ列のセルを横並びで見て、ＡＡＣ、ＡＣＡ、ＡＣＣ、ＣＣＡ、ＣＡＣ、ＣＡＡの
いずれかのパターンに該当したときのみＥ列のセルを色づけしたいと考えています。
そうすると、この場合１～５が該当することになります。
それ以外は色なしのセルです。

ちなみに、書式ルールの編集で「数式を使用して、書式設定セルを決定」を選択し、
数式をコピペしたところ、「条件　条件付き書式には、参照演算子（ＯＲ演算子、ＡＮＤ演算子、
範囲演算子など）および配列定数は使用できません。」とメッセージがでました。

何度もすみません。お忙しい中、どうぞ宜しくお願いします。

（ｔｋ） 2021/05/23(日) 18:18

余り難しく考えずに、
=AND($A1="A",$B1="A",$C1="C")
だとか
=$A1 & $B1 & $C1 ="AAC"
のような条件と書式のセットを
５つ書いたらいいんじゃないですか？

（γ） 2021/05/23(日) 18:49

どうして新しくスレッドを建てる必要があるんですか？

（γ） 2021/05/23(日) 18:52

A,AC,""でもマッチする後者よりも、前者のほうが正確は正確でしょうね。
必ず1セルに1文字が満たされていれば問題ないですけど。

（γ） 2021/05/23(日) 19:12

ああ、すべて同じ色なんですか。それなら、

 =OR(AND($A1="A",$B1="A",$C1="C"),
     AND($A1="A",$B1="C",$C1="C"),
     AND($A1="C",$B1="A",$C1="A"),
     AND($A1="C",$B1="C",$C1="A"),
     AND($A1="C",$B1="A",$C1="C"))
ですな。
（γ） 2021/05/23(日) 19:36

 ＞ＡＡＣ、ＡＣＡ、ＡＣＣ、ＣＣＡ、ＣＡＣ、ＣＡＡ
 全部で6パターンあるってこと？

 そのすべてのパターンをどこかのセルに書き出しておく。
 例えば、F1:F6だとして

	F
1	AAC
2	ACA
3	ACC
4	CCA
5	CAC
6	CAA

 条件付き書式の数式
 =COUNTIF($F$1:$F$6,A1&B1&C1)

 実際も全角なら全角にしてください。

 以上
（笑） 2021/05/23(日) 19:52

ＡＣＡは表の中には出で来ないんですけど。

（ななし） 2021/05/23(日) 20:34

表は一例なんでしょう。
本文に書かれている6パターンが正解なんでしょうね。
私は、殆ど読み飛ばす癖があるので、間違えましたが。

（γ） 2021/05/23(日) 20:50

ところで、
「条件　条件付き書式には、参照演算子（ＯＲ演算子、ＡＮＤ演算子、
範囲演算子など）および配列定数は使用できません。」
というメッセージが納得いかないですね。（変な言い分ですけど。）

そもそも、参照演算子のOR演算子とかAND演算子って、
どんなものを指しているんでしょう。
範囲演算子がダメって、ほんとですか？

どなたか、お分かりのかた、いらっしゃったらご教示ください。
（尋ねる先が違うのは承知していますが。）

（γ） 2021/05/23(日) 21:42

(余談続きで失礼）
Google検索したら、英語では、こう表示されるみたいですね。
"You may not use reference operators (such as unions, intersections, and ranges)
or array constants for Conditional Formatting criteria."
全然違うやん。

・カンマ演算子　（これがunionsに相当し、）
・スペースによる共通演算子（intersections)に相当し、
これらがダメと言っているらしい。
ある種の誤訳じゃないだろうか。
（カンマ演算子を OR演算子、スペース演算子をAND演算子と呼ぶのであれば正しいが、
　浅学の私は余り聞いたことがなかったな。一般的なんだろうか。）

（γ） 2021/05/23(日) 21:58

 集合の考え方からするとあり得そうな気もします。

 Operatorを「演算子」と定番の訳にしようとするから、いきおいそうなるので、
 AND参照子、OR参照子と言えばよかった気もします。

 ただ、３つしかないはずなので、「・・など」は要らない。あと何が・・と不安になる。

（半平太） 2021/05/23(日) 23:30

 コメント頂き、ありがとうございました。そうかもしれませんねえ。
 "など"も気になります、たしかに。

 論理演算子としてのAND,ORは、正確には、AND関数、OR関数なのですね。
 なお、
 Excel2010のヘルプを検索すると、「AND演算子」とか「OR演算子」という言葉はヒットしませんね。
 また、ヘルプの「エラー値 #NULL! を修正する」の項には、以下の記述があります。
 | ・正しい参照演算子が使用されていることを確認します。
 |     ・連続したセル範囲を参照する場合は、範囲の先頭のセル参照と末尾のセル参照の間を
 |       コロン (:) で区切ります。たとえば、SUM(A1:A10) はセル A1 からセル A10 を含む
 |       範囲を参照します。 
 |     ・共通部分がない 2 つの範囲を参照する場合は、複数の範囲を表す参照演算子である
 |       コンマ (,) を使用します。たとえば、数式で 2 つの範囲の合計を求める場合は、
 |       SUM(A1:A10,C1:C10) のように、2 つの範囲がコンマで区切られていることを確認します。 
 | ・範囲に共通部分が含まれるようにセル参照を変更します。共通部分とは、ワークシートの
 |   複数の範囲のデータが交差する場所のことです。たとえば、=CELL("address",(A1:A5 A3:C3)) 
 |   という数式には共通する範囲が含まれています。この例では、CELL 関数は 2 つの範囲の
 |   共通部分のセル番地 (A3) を返します。

 どこにも、AND演算子とか、OR演算子といった言葉は出てきませんね。
 私見では、
    "和集合や積集合を示す参照演算子"（分かりにくければ、（, やスペース）を追記）  
 とかいった言い方が、英語にも近く、良かったのではないかと思います。

 # いったい、何の話をしていたんでしょうか。余談はここまでですかね。（スレ主さん失礼）
 # もし蘊蓄をお持ちのかたは、是非ご教示ください。

（γ） 2021/05/24(月) 08:08

コメント返信：

[ 一覧(最新更新順) ]

[[20210523170435]] 『条件付き書式』（ｔｋ） ページの最後に飛ぶ

[[20210523170435]]　『条件付き書式』（ｔｋ）　ページの最後に飛ぶ