[[20211124160740]] 『FILTER関数が使えない場合』(お茶) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『FILTER関数が使えない場合』(お茶)

 sheet1のAコース以外をsheet2にFILTERしてます
 FILTER関数が使えないPCで何かよい方法はありませんか?

 sheet1
 A列 番号
 B列 コース名
 C列 名前

 sheet2
 A列 コース名
 B列 名前

 sheet1のB列とC列は別シートから式でとんでて
 答えがない時はゼロになってます

 sheet2の式は
 =FILTER(sheet1!B16:C40,sheet1!F16:F40,sheet1!B16:B40<>"あかさ")

< 使用 Excel:Excel2019、使用 OS:Windows10 >


 FILTER関数のsheet1!F16:F40が謎だが。

 Sheet2の開始セルに
 =IFERROR(INDEX(Sheet1!B:B,AGGREGATE(15,6,ROW($6:$40)/((Sheet1!$C$6:$C$40<>"あかさ")*(Sheet1!$B$6:$B$40<>"")),ROW(A1))),"")
 と入力して横及び下へフィルコピーではどうだろうか?

(ねむねむ) 2021/11/24(水) 16:40


 >答えがない時はゼロになってます 
 空白ではなく「0」になってるってこと?

 あと、ついでに言っておくと
 ・16行目から
 ・コース名はB列
 ですよね。

 =IFERROR(INDEX(Sheet1!B:B,AGGREGATE(15,6,ROW($B$16:$B$40)/((Sheet1!$B$16:$B$40<>"あかさ")*(Sheet1!$B$16:$B$40<>0)),ROW(A1))),"")
                                                                    ~~~~~~~~~~~                              ~~~~~
 右・下コピー

 ■もひとつ、ついでに言っておくと・・・
 >sheet1のB列とC列は別シートから式でとんでて
 >答えがない時はゼロになってます

 別シートが空白の場合に「0」になるということで
 戻り値が数値ではなく「文字列」なら
 数式の最後に &"" をつけると「0」にはなりません。

 例えば =Sheet3!A2 のような式なら =Sheet3!A2&"" とする。
                                             ~~~~~
 これだったら、上のINDEXの式も
 (Sheet1!$B$16:$B$40<>0)) → (Sheet1!$B$16:$B$40<>"") に変更
                                                ~~~~~~
 ■さらについでに・・・
 ↓ に回答を追加したので見てください。
[[20211124153106]]『SUMIFの使い方』(お茶)

 以上
(笑) 2021/11/24(水) 18:34 追記 18:39

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.